build.gradle

buildscript {
    repositories {
        maven { url = 'https://files.minecraftforge.net/maven' }
        jcenter()
        mavenCentral()
        maven {url='https://repo.spongepowered.org/repository/maven-public'}
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.0.1', changing: true
        classpath 'org.spongepowered:mixingradle:0.7-SNAPSHOT'
    }
}

plugins {
    id 'com.matthewprenger.cursegradle' version '1.2.0'
    id 'de.undercouch.download' version '3.3.0'
//    id 'com.wynprice.cursemaven' version '2.1.1'
    id 'idea'
}

apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'eclipse'

group = 'de.teamlapen.werewolves' // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = 'Werewolves'

java.toolchain.languageVersion = JavaLanguageVersion.of(8)

ext.mod_version="Test"
ext.type="test"

sourceSets {
    main {
        resources {
            srcDirs += 'src/generated/resources'
            exclude '.cache'
        }
    }
}

apply from: 'gradle/versioning.gradle'
apply from: 'gradle/forge.gradle'
apply from: 'gradle/artifacts.gradle'
apply from: 'gradle/maven.gradle'
apply from: 'gradle/curse.gradle'


idea {
    module {
        for (String excludeDirName in ["run", "out", "logs", "gradle"]) {
            File excludeDir = new File(projectDir, excludeDirName)
            excludeDirs.add(excludeDir)
        }
        downloadJavadoc = true
        downloadSources = true
    }
}