check_http_health

#!/usr/bin/env perl

# check_http_health - Check health of a HTTP endpoint (HAProxy behaviour)
#
# Copyright (c) 2016 Amadeus Germany GmbH
#
# SPDX-License-Identifier: MIT
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.
#
use strict;
use warnings;

use autodie;
use LWP::UserAgent;
use HTTP::Request;

### START PLUGIN LOADER
sub load_module {
	my $module;
	eval "require $_" and $module = $_ and last for @_;
	$module->import();
	return $module;
}

my $plugin_module;
BEGIN {
	$plugin_module = load_module('Monitoring::Plugin', 'Nagios::Plugin', 'Nagios::Monitoring::Plugin');
}
### END PLUGIN LOADER

my ($plugin, $version) = ('check_http_health', '1.0.0');

my $np = $plugin_module->new(
	usage => "Usage: %s [ -v|--verbose ] ",
	version => $version,
	plugin => $plugin,
	blurb => 'Check health of a HTTP endpoint (HAProxy behaviour)',
	license => 'MIT',
);

$np->add_arg(
	spec => 'url|u=s',
	help => 'URL to check',
	required => 1,
);

$np->getopts;

my $ua = LWP::UserAgent->new;
$ua->agent(sprintf("%s/%s", $plugin, $version));
my $req = HTTP::Request->new(GET => $np->opts->url);
my $res = $ua->request($req);

if ($res->code == 500) {
	$np->nagios_exit(CRITICAL, $res->content);
} elsif ($res->is_error()) {
	$np->nagios_exit(UNKNOWN, sprintf("%s: %s", $res->code, $res->content));
} else {
	$np->nagios_exit(OK, undef);
}