-
Notifications
You must be signed in to change notification settings - Fork 0
/
PLAY.Z80
2271 lines (2089 loc) · 43.8 KB
/
PLAY.Z80
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;===============================================================================
; PLAY PT2/PT3/MYM sound files
;===============================================================================
;
; Play Tune for CP/M
; Designed for RC2014 YM/AY Sound Card created by Ed Brindley
; Plain CP/M version based on RomWBW "Tune"
; Ported by Andrzej Borsuk <red@szsz.pl>
;
; CPU speed and IO ports are hardcoded
;
;
; Original RomWBW Tune Player
; Author: Wayne Warthen (wwarthen@gmail.com)
;
; This application is basically just a RomWBW wrapper for the
; Universal PT2 and PT3 player by S.V.Bulba and the MYM player
; by Marq/Lieves!Tuore. See comments below.
;_______________________________________________________________________________
;
; Usage:
; PLAY <filename>
;
; <filename> of sound file to load and play
; Filename extension determines file type (.PT2, .PT3, or .MYM)
;
; Notes:
; - Supports AY-3-8910, YM2149, etc.
; - Plays PT2, PT3, or MYM format files. File extension (.PT2, .PT3, or .MYM)
; determines file type.
; - Max Z80 CPU clock is about 8MHz or sound chip will not handle speed.
; - Higher CPU clock speeds are possible on Z180 because extra I/O
; wait states are added during I/O to sound chip.
; - Uses hardware timer support on systems that support a timer. Otherwise,
; a delay loop calibrated to CPU speed is used.
; - Delay loop is calibrated to CPU speed, but it does not compensate for
; time variations in each quark loop resulting from data decompression.
; An average quark processing time is assumed in each loop.
; - Most sound files originally targeted MSX or ZX Spectrum which used
; 1.7897725 MHz and 1.773400 MHz respectively for the PSG clock. For best
; sound playback, PSG should be run at approx. this clock rate.
;_______________________________________________________________________________
;
; Change Log:
; 2018-01-26 [WBW] Initial release
; 2018-01-28 [WBW] Added support for MYM sound files
; 2019-11-21 [WBW] Added table-driven configuration
; 2020-02-11 [WBW] Made hardware config & detection more flexible
; 2020-03-29 [WBW] Fix error in Z180 I/O W/S bracketing
; 2020-08-07 [CPM] No crossassembler needed (SLR Assembler)
; 2020-08-07 [CPM] Butchered HBIOS calls and related code
; 2020-08-08 [CPM] Rewriten message printing and unused code elimination
; 2020-08-08 [CPM] Display tune description (PT3)
; 2020-08-08 [CPM] CPU speed, and IO ports configuration bellow
;_______________________________________________________________________________
;
; ToDo:
; *) Proper memory allocation (HEAPEND)
;_______________________________________________________________________________
;
;===============================================================================
; CONFIG
;===============================================================================
CPU_KHZ EQU 7372 ; CPU speed in KHz
IO_RSEL EQU 00D8h ; Register selection port
IO_RDAT EQU 00D0h ; Register data port
HEAPEND EQU 00A000h ; End of heap storage
;
;===============================================================================
; Main program
;===============================================================================
;
RESTART EQU 000000h ; CP/M restart vector
BDOS EQU 000005h ; BDOS invocation vector
;
FCB EQU 005Ch ; Location of default FCB
;
TYPPT2 EQU 1 ; FILTYP value for PT2 sound file
TYPPT3 EQU 2 ; FILTYP value for PT3 sound file
TYPMYM EQU 3 ; FILTYP value for MYM sound file
;
;
ORG 000100h
;
LD DE,MSGBAN ; Point to banner message
CALL PRTSTR ; Print message
;
SETDLY:
; CPU speed / compute quark delay factor
LD HL, CPU_KHZ/2 ; Do it, CPU speed in KHz / 2
LD (QDLY),HL ; Save result as quark delay factor
;
; Clear heap storage
LD HL,HEAP ; Point to heap start
XOR A ; A := zero
LD (HEAP),A ; Clear first byte of heap
LD DE,HEAP+1 ; Set dest to next byte
LD BC,HEAPEND-HEAP-1 ; Size of heap except first byte
LDIR ; Propagate zero to rest of heap
;
; Check sound filename (must be *.PT2, *.PT3, or *.MYM)
LD A,(FCB+1) ; Get first char of filename
CP ' ' ; Compare to blank
JP Z,ERRCMD ; If so, missing filename
LD A,(FCB+9) ; If the filetype
CP ' ' ; is blanks
JR NZ,HASEXT ; then assume
LD A,'P' ; type PT3.
LD (FCB+9),A
LD A,'T' ; Fill in
LD (FCB+10),A ; the file
LD A,'3' ; extension
LD (FCB+11),A ; and the
LD C,TYPPT3 ; file type
JR _SET
HASEXT LD A,(FCB+9) ; Extension char 1
CP 'P' ; Check for 'P'
JP NZ,CHKMYM ; If not, check for MYM extension
LD A,(FCB+10) ; Extension char 2
CP 'T' ; Check for 'T'
JP NZ,ERRNAM ; If not, bad file extension
LD A,(FCB+11) ; Extension char 3
LD C,TYPPT2 ; Assume PT2 file type
CP '2' ; Check for '2'
JR Z,_SET ; If so, commit file type value
LD C,TYPPT3 ; Assume PT3 file type
CP '3' ; Check for '3'
JR Z,_SET ; If so, commit file type value
JP ERRNAM ; Anything else is a bad file extension
CHKMYM LD A,(FCB+9) ; Extension char 1
CP 'M' ; Check for 'M'
JP NZ,ERRNAM ; If not, bad file extension
LD A,(FCB+10) ; Extension char 2
CP 'Y' ; Check for 'Y'
JP NZ,ERRNAM ; If not, bad file extension
LD A,(FCB+11) ; Extension char 3
LD C,TYPMYM ; Assume MYM file type
CP 'M' ; Check for 'M'
JR Z,_SET ; If so, commit file type value
JP ERRNAM ; Anything else is a bad file extension
_SET LD A,C ; Get file type value
LD (FILTYP),A ; Save file type value
;
; Load sound file
_LD0 LD C,15 ; CPM Open File function
LD DE,FCB ; FCB
CALL BDOS ; Do it
INC A ; Test for error 00FFh
JP Z,ERRFIL ; Handle file error
;
LD A,(FILTYP) ; Get file type
LD HL,MDLADDR ; Assume load address
LD (DMA),HL ; ... for PTx files
CP TYPMYM ; MYM file?
JR NZ,_LD ; If not, all set
LD HL,rows ; Otherwise, load address
LD (DMA),HL ; ... for MYM files
;
_LD LD HL,(DMA) ; Get load address
PUSH HL ; Save it
LD DE,128 ; Bump by size of
ADD HL,DE ; ... one record
LD (DMA),HL ; Save for next loop
LD A,HEAPEND >> 8 ; A := page limit for load
CP H ; Check to see if limit hit
JP Z,ERRSIZ ; Handle size error
POP DE ; Restore current DMA to DE
LD C,26 ; CPM Set DMA function
CALL BDOS ; Read next 128 bytes
;
LD C,20 ; CPM Read Sequential function
LD DE,FCB ; FCB
CALL BDOS ; Read next 128 bytes
OR A ; Set flags to check EOF
JR NZ,_LDX ; Non-zero is EOF
JR Z,_LD ; Load loop
;
_LDX LD C,16 ; CPM Close File function
LD DE,FCB ; FCB
CALL BDOS ; Do it
;
; Display file information
;
FINFO:
LD A, (FILTYP)
CP TYPPT3
JR NZ, FINF_E
LD HL, MDLADDR ; First line
LD B, 63
CALL PRT_HLB
LD DE, EOL
CALL PRTSTR
LD B, 36 ; Second line
CALL PRT_HLB
LD DE, EOL
CALL PRTSTR
FINF_E:
;
; Play loop
LD DE,MSGPLY ; Playing message
CALL PRTSTR ; Print message
LD A,(FILTYP) ; Get file type
CP TYPPT2 ; PT2?
JR Z,GOPT2 ; If so, do it
CP TYPPT3 ; PT3?
JR Z,GOPT3 ; If so, do it
CP TYPMYM ; MYM?
JR Z,gomym ; If so, do it
JP ERRNAM ; This should never happen
GOPT2 LD A,2 ; SETUP value to PT2 sound files
LD (START+10),A ; Save it
; Avg TS / quark for PT2 files has *not* been measured!!!
LD DE,185 ; Avg TS / quark = 7400, so 185 delay loops
JR GOPTX ; Play PTx file
GOPT3 LD A,0 ; SETUP value to PT3 sound files
LD (START+10),A ; Save it
LD DE,185 ; Avg TS / quark = 7400, so 185 delay loops
JR GOPTX ; Play PTx file
GOPTX LD HL,(QDLY) ; Get basic quark delay
OR A ; Clear carry
SBC HL,DE ; Adjust for file type
LD (QDLY),HL ; Save updated quark delay factor
CALL START ; Do initialization
PTXLP CALL START+5 ; Play one quark
LD A,(START+10) ; Get setup byte
BIT 7,A ; Check bit 7 (loop point passed)
JR NZ,EXIT ; Bail out when done playing
CALL GETKEY ; Check for keypress
JR NZ,EXIT ; Abort on keypress
CALL WAITQ ; Wait one quark period
JR PTXLP ; Loop for next quark
;
gomym ld hl,(QDLY) ; Get basic quark delay
or a ; Clear carry
ld de,125 ; Avg TS / quark = ~5000, so 125 delay loops
sbc hl,de ; Adjust for file type
ld (QDLY),hl ; Save updated quark delay factor
call mymini ; Initialize player
call extract ; Unpack the first fragment
mymlp call extract
jr nc,EXIT ; CF clear at end of tune
waitvb call WAITQ
call upsg ; Update PSG registers
call GETKEY ; Check for keypess
jr nz,EXIT ; Bail out if so
ld a,(played) ; Wait until VBI has played a fragment
or a
jr nz,waitvb
ld (psource),iy
ld a,FRAG
ld (played),a
jr mymlp
;
EXIT CALL START+8 ; Mute audio
LD DE,MSGEND ; Completion message
CALL PRTSTR ; Print message
JP 0 ; Exit the easy way
;
; Wait for quark play time. Can use hardware timer if
; supported by hardware or simple delay loop otherwise.
; Delay loop requires QDLY to be pre-set to to achieve
; optimal 20ms wait time.
;
WAITQ:
; Delay spin loop (40 tstates per loop)
DLY LD BC,(QDLY) ; Load quark delay factor
DLY1 DEC BC ; [6]
NOP ; [4]
NOP ; [4]
NOP ; [4]
NOP ; [4]
LD A,B ; [4]
OR C ; [4]
JP NZ,DLY1 ; [10]
RET
;
; Get a keystroke from CPM
;
GETKEY LD C,6 ; BDOS direct I/O
LD E,00FFh ; Get character if available
CALL BDOS ; Call BDOS
OR A ; Set flags, Z set if no key
RET ; Done
;
; Print character in A without destroying any registers
;
PRTCHR:
PUSH BC ; save registers
PUSH DE
PUSH HL
LD E,A ; character to print in E
LD C,2 ; BDOS function to output a character
CALL BDOS ; do it
POP HL ; restore registers
POP DE
POP BC
RET
;
; Print a '$' terminated string at (DE) without destroying any registers
;
PRTSTR:
PUSH AF
PUSH BC
;PUSH DE ; string is already here
PUSH HL
LD C,9 ; BDOS print string$
CALL BDOS
POP HL
;POP DE
POP BC
POP AF
RET
;
; Print B characters pointed by HL
;
PRT_HLB:
LD A,(HL)
INC HL
CALL PRTCHR
DJNZ PRT_HLB
RET
;
ERRCMD: ; Command error, display usage info
LD DE,MSGUSE
JR ERR
;
ERRNAM: ; Missing or invalid filename parameter
LD DE,MSGNAM
JR ERR
;
ERRFIL: ; Error opening sound file
LD DE,MSGFIL
JR ERR
;
ERRSIZ: ; Sound file is too large for memory
LD DE,MSGSIZ
;JR ERR
;
ERR: ; print error string and return error signal
CALL PRTSTR ; print error string
JP 0 ; fast exit
;
;
CFG: ; ACTIVE CONFIG VALUES (FROM SELECTED CFGTBL ENTRY)
PORTS:
RSEL DB IO_RSEL ; Register selection port
RDAT DB IO_RDAT ; Register data port
;
QDLY DW 0 ; quark delay factor
WMOD DB 0 ; delay mode, non-zero to use timer
;
DMA DW 0 ; Working DMA
FILTYP DB 0 ; Sound file type (TYPPT2, TYPPT3, TYPMYM)
;
TMP DB 0 ; work around use of undocumented Z80
;
MSGBAN DB "Tune Player for CP/M 08/08/2020"
EOL DB 13,10,"$"
MSGUSE DB "Copyright (C) 2020, Andrzej Borsuk, GNU GPLv3",13,10
DB "Copyright (C) 2020, Wayne Warthen, GNU GPL v3",13,10
DB "PTxPlayer Copyright (C) 2004-2007 S.V.Bulba",13,10
DB "MYMPlay by Marq/Lieves!Tuore",13,10,13,10
DB "Usage: PLAY <filename>.[PT2|PT3|MYM]$"
MSGNAM DB "Filename invalid (must be .PT2, .PT3, or .MYM)$"
MSGFIL DB "File not found!$"
MSGSIZ DB "File too large!$"
MSGPLY DB "playing $"
MSGEND DB 13," $"
;
;===============================================================================
; PTx Player Routines
;===============================================================================
;
;Universal PT2 and PT3 player for ZX Spectrum and MSX
;(c)2004-2007 S.V.Bulba <vorobey@mail.khstu.ru>
;http://bulba.untergrund.net (http://bulba.at.kz)
;Release number
;Release EQU "1"
Release: EQU "1"
;Conditional assembly
;1) Version of ROUT (ZX or MSX standards)
ZX EQU 0
MSX EQU 0
CPM EQU 1
;2) Current position counter at (START+11)
CurPosCounter EQU 0
;3) Allow channels allocation bits at (START+10)
ACBBAC EQU 0
;4) Allow loop checking and disabling
LoopChecker EQU 1
;5) Insert official identificator
Id EQU 1
;Features
;--------
;-Can be compiled at any address (i.e. no need rounding ORG
; address).
;-Variables (VARS) can be located at any address (not only after
;code block).
;-INIT subprogram checks PT3-module version and rightly
; generates both note and volume tables outside of code block
; (in VARS).
;-Two portamento (spc. command 3xxx) algorithms (depending of
; PT3 module version).
;-New 1.XX and 2.XX special command behaviour (only for PT v3.7
; and higher).
;-Any Tempo value are accepted (including Tempo=1 and Tempo=2).
;-Fully compatible with Ay_Emul PT3 and PT2 players codes.
;-See also notes at the end of this source code.
;Limitations
;-----------
;-Can run in RAM only (self-modified code is used).
;-PT2 position list must be end by 00FFh marker only.
;Warning!!! PLAY subprogram can crash if no module are loaded
;into RAM or INIT subprogram was not called before.
;Call MUTE or INIT one more time to mute sound after stopping
;playing
;ORG 00C000h
;Test codes (commented)
; LD A,2 ;PT2,ABC,Looped
; LD (START+10),A
; CALL START
; EI
;_LP HALT
; CALL START+5
; XOR A
; IN A,(00FEh)
; CPL
; AND 15
; JR Z,_LP
; JR START+8
TonA EQU 0
TonB EQU 2
TonC EQU 4
Noise EQU 6
Mixer EQU 7
AmplA EQU 8
AmplB EQU 9
AmplC EQU 10
Env EQU 11
EnvTp EQU 13
;ChannelsVars
; STRUCT CHP
;reset group
PsInOr EQU 0
PsInSm EQU 1
CrAmSl EQU 2
CrNsSl EQU 3
CrEnSl EQU 4
TSlCnt EQU 5
CrTnSl EQU 6
TnAcc EQU 8
COnOff EQU 10
;reset group
OnOffD EQU 11
;IX for PTDECOD here (+12)
OffOnD EQU 12
OrnPtr EQU 13
SamPtr EQU 15
NNtSkp EQU 17
Note EQU 18
SlToNt EQU 19
Env_En EQU 20
Flags EQU 21
;Enabled - 0,SimpleGliss - 2
TnSlDl EQU 22
TSlStp EQU 23
TnDelt EQU 25
NtSkCn EQU 27
Volume EQU 28
; ENDS
CHP EQU 29
;Entry and other points
;START initialize playing of module at MDLADDR
;START+3 initialization with module address in HL
;START+5 play one quark
;START+8 mute
;START+10 setup and status flags
;START+11 current position value (byte) (optional)
START
LD HL,MDLADDR
JR INIT
JP PLAY
JR MUTE
SETUP DB 0 ;set bit0, if you want to play without looping
;(optional);
;set bit1 for PT2 and reset for PT3 before
;calling INIT;
;bits2-3: 00b-ABC, 01b ACB, 10b BAC (optional);
;bits4-6 are not used
;bit7 is set each time, when loop point is passed
;(optional)
IF CurPosCounter
CurPos DB 0 ;for visualization only (i.e. no need for playing)
ENDIF
;Identifier
IF Id
DB "=Uni PT2 and PT3 Player r.",Release,"="
ENDIF
IF LoopChecker
CHECKLP LD HL,SETUP
SET 7,(HL)
BIT 0,(HL)
RET Z
POP HL
LD HL,DelyCnt
INC (HL)
LD HL,ChanA+NtSkCn
INC (HL)
ENDIF
MUTE XOR A
LD H,A
LD L,A
LD (AYREGS+AmplA),A
LD (AYREGS+AmplB),HL
JP ROUT
INIT
;HL - AddressOfModule
LD A,(START+10)
AND 2
JR NZ,INITPT2
CALL SETMDAD
PUSH HL
LD DE,100
ADD HL,DE
LD A,(HL)
LD (Delay),A
PUSH HL
POP IX
ADD HL,DE
LD (CrPsPtr),HL
LD E,(IX+102-100)
INC HL
IF CurPosCounter
LD A,L
LD (PosSub+1),A
ENDIF
ADD HL,DE
LD (LPosPtr),HL
POP DE
LD L,(IX+103-100)
LD H,(IX+104-100)
ADD HL,DE
LD (PatsPtr),HL
LD HL,169
ADD HL,DE
LD (OrnPtrs),HL
LD HL,105
ADD HL,DE
LD (SamPtrs),HL
LD A,(IX+13-100) ;EXTRACT VERSION NUMBER
SUB 0030h
JR C,L20
CP 10
JR C,L21
L20 LD A,6
L21 LD (Version),A
PUSH AF ;VolTable version
CP 4
LD A,(IX+99-100) ;TONE TABLE NUMBER
RLA
AND 7
PUSH AF ;NoteTable number
LD HL,(e_-SamCnv-2)*256+0018h
LD (SamCnv),HL
LD A,00BAh
LD (OrnCP),A
LD (SamCP),A
LD A,007Bh
LD (OrnLD),A
LD (SamLD),A
LD A,0087h
LD (SamClc2),A
LD BC,PT3PD
LD HL,0
LD DE,PT3EMPTYORN
JR INITCOMMON
INITPT2 LD A,(HL)
LD (Delay),A
PUSH HL
PUSH HL
PUSH HL
INC HL
INC HL
LD A,(HL)
INC HL
LD (SamPtrs),HL
LD E,(HL)
INC HL
LD D,(HL)
POP HL
AND A
SBC HL,DE
CALL SETMDAD
POP HL
LD DE,67
ADD HL,DE
LD (OrnPtrs),HL
LD E,32
ADD HL,DE
LD C,(HL)
INC HL
LD B,(HL)
LD E,30
ADD HL,DE
LD (CrPsPtr),HL
LD E,A
INC HL
IF CurPosCounter
LD A,L
LD (PosSub+1),A
ENDIF
ADD HL,DE
LD (LPosPtr),HL
POP HL
ADD HL,BC
LD (PatsPtr),HL
LD A,5
LD (Version),A
PUSH AF
LD A,2
PUSH AF
LD HL,0051CBh
LD (SamCnv),HL
LD A,00BBh
LD (OrnCP),A
LD (SamCP),A
LD A,007Ah
LD (OrnLD),A
LD (SamLD),A
LD A,0080h
LD (SamClc2),A
LD BC,PT2PD
LD HL,008687h
LD DE,PT2EMPTYORN
INITCOMMON
LD (PTDECOD+1),BC
LD (PsCalc),HL
PUSH DE
;note table data depacker
;(c) Ivan Roshin
LD DE,T_PACK
LD BC,T1_+(2*49)-1
TP_0 LD A,(DE)
INC DE
CP 15*2
JR NC,TP_1
LD H,A
LD A,(DE)
LD L,A
INC DE
JR TP_2
TP_1 PUSH DE
LD D,0
LD E,A
ADD HL,DE
ADD HL,DE
POP DE
TP_2 LD A,H
LD (BC),A
DEC BC
LD A,L
LD (BC),A
DEC BC
SUB (00F8h*2) & 00FFh
JR NZ,TP_0
IF LoopChecker
LD HL,SETUP
RES 7,(HL)
IF CurPosCounter
INC HL
LD (HL),A
ENDIF
ELSE
IF CurPosCounter
LD (CurPos),A
ENDIF
ENDIF
LD HL,VARS
LD (HL),A
LD DE,VARS+1
LD BC,VAR0END-VARS-1
LDIR
LD (AdInPtA),HL ;ptr to zero
INC A
LD (DelyCnt),A
LD HL,00F001h ;H - Volume, L - NtSkCn
LD (ChanA+NtSkCn),HL
LD (ChanB+NtSkCn),HL
LD (ChanC+NtSkCn),HL
POP HL
LD (ChanA+OrnPtr),HL
LD (ChanB+OrnPtr),HL
LD (ChanC+OrnPtr),HL
POP AF
;NoteTableCreator (c) Ivan Roshin
;A - NoteTableNumber*2+VersionForNoteTable
;(xx1b - 3.xx..3.4r, xx0b - 3.4x..3.6x..VTII1.0)
LD HL,NT_DATA
PUSH DE
LD D,B
ADD A,A
LD E,A
ADD HL,DE
LD E,(HL)
INC HL
SRL E
SBC A,A
AND 00A7h ;0000h (NOP) or 00A7h (AND A)
LD (L3),A
EX DE,HL
POP BC ;BC=T1_
ADD HL,BC
LD A,(DE)
ADD A,T_ & 00FFh
LD C,A
ADC A,T_/256
SUB C
LD B,A
PUSH BC
LD DE,NT_
PUSH DE
LD B,12
LD IX,TMP ; +WW
L1 PUSH BC
LD C,(HL)
INC HL
PUSH HL
LD B,(HL)
PUSH DE
EX DE,HL
LD DE,23
;LD IXH,8 ; -WW
LD (IX),8 ; +WW
L2 SRL B
RR C
L3 DB 0019h ;AND A or NOP
LD A,C
ADC A,D ;=ADC 0
LD (HL),A
INC HL
LD A,B
ADC A,D
LD (HL),A
ADD HL,DE
;DEC IXH ; -WW
DEC (IX) ; +WW
JR NZ,L2
POP DE
INC DE
INC DE
POP HL
INC HL
POP BC
DJNZ L1
POP HL
POP DE
LD A,E
CP TCOLD_1 & 00FFh
JR NZ,CORR_1
LD A,00FDh
LD (NT_+002Eh),A
CORR_1 LD A,(DE)
AND A
JR Z,TC_EXIT
RRA
PUSH AF
ADD A,A
LD C,A
ADD HL,BC
POP AF
JR NC,CORR_2
DEC (HL)
DEC (HL)
CORR_2 INC (HL)
AND A
SBC HL,BC
INC DE
JR CORR_1
TC_EXIT
POP AF
;VolTableCreator (c) Ivan Roshin
;A - VersionForVolumeTable (0..4 - 3.xx..3.4x;
;5.. - 2.x,3.5x..3.6x..VTII1.0)
CP 5
LD HL,0011h
LD D,H
LD E,H
LD A,0017h
JR NC,M1
DEC L
LD E,L
XOR A
M1 LD (M2),A
LD IX,VT_+16
LD C,00Fh
INITV2 PUSH HL
ADD HL,DE
EX DE,HL
SBC HL,HL
LD B,0010h
INITV1 LD A,L
M2 DB 007Dh
LD A,H
ADC A,0
LD (IX),A
INC IX
ADD HL,DE
DJNZ INITV1
POP HL
LD A,E
CP 0077h
JR NZ,M3
INC E
M3 DEC C
JR NZ,INITV2
JP ROUT
SETMDAD LD (MODADDR),HL
LD (MDADDR1),HL
LD (MDADDR2),HL
RET
PTDECOD JP 00C3C3h
;PT2 pattern decoder
PD2_SAM CALL SETSAM
JR PD2_LOOP
PD2_EOff LD (IX-12+Env_En),A
JR PD2_LOOP
PD2_ENV LD (IX-12+Env_En),16
LD (AYREGS+EnvTp),A
LD A,(BC)
INC BC
LD L,A
LD A,(BC)
INC BC
LD H,A
LD (EnvBase),HL
JR PD2_LOOP
PD2_ORN CALL SETORN
JR PD2_LOOP
PD2_SKIP INC A
LD (IX-12+NNtSkp),A
JR PD2_LOOP
PD2_VOL RRCA
RRCA
RRCA
RRCA
LD (IX-12+Volume),A
JR PD2_LOOP
PD2_DEL CALL C_DELAY
JR PD2_LOOP
PD2_GLIS SET 2,(IX-12+Flags)
INC A
LD (IX-12+TnSlDl),A
LD (IX-12+TSlCnt),A
LD A,(BC)
INC BC
LD (IX-12+TSlStp),A
ADD A,A
SBC A,A
LD (IX-12+TSlStp+1),A
SCF
JR PD2_LP2
PT2PD AND A
PD2_LP2 EX AF,AF'
PD2_LOOP LD A,(BC)
INC BC
ADD A,0020h
JR Z,PD2_REL
JR C,PD2_SAM
ADD A,96
JR C,PD2_NOTE
INC A
JR Z,PD2_EOff
ADD A,15
JP Z,PD_FIN
JR C,PD2_ENV
ADD A,0010h
JR C,PD2_ORN
ADD A,0040h
JR C,PD2_SKIP
ADD A,0010h
JR C,PD2_VOL
INC A
JR Z,PD2_DEL
INC A
JR Z,PD2_GLIS
INC A
JR Z,PD2_PORT
INC A
JR Z,PD2_STOP
LD A,(BC)
INC BC
LD (IX-12+CrNsSl),A
JR PD2_LOOP
PD2_PORT RES 2,(IX-12+Flags)
LD A,(BC)
INC BC
INC BC ;ignoring precalc delta to right sound
INC BC
SCF
JR PD2_LP2
PD2_STOP LD (IX-12+TSlCnt),A
JR PD2_LOOP
PD2_REL LD (IX-12+Flags),A
JR PD2_EXIT
PD2_NOTE LD L,A
LD A,(IX-12+Note)
LD (PrNote+1),A
LD (IX-12+Note),L
XOR A
LD (IX-12+TSlCnt),A
SET 0,(IX-12+Flags)
EX AF,AF'
JR NC,NOGLIS2
BIT 2,(IX-12+Flags)
JR NZ,NOPORT2
LD (LoStep),A
ADD A,A
SBC A,A
EX AF,AF'
LD H,A
LD L,A
INC A
CALL SETPORT
NOPORT2 LD (IX-12+TSlCnt),1
NOGLIS2 XOR A