build.gradle

// This buildscript{} block configures the code driving the build
buildscript {
    repositories {
        google()
        mavenCentral()
        maven { url 'https://dl.bintray.com/kotlin/kotlin-eap' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.2.1'
    }
}

/**
 * This line applies the com.android.application plugin. Note that you should
 * only apply the com.android.application plugin. Applying the Java plugin as
 * well will result in a build error.
 */
apply plugin: 'com.android.application'

/**
 * This dependencies block includes any dependencies for the project itself. The
 * following line includes all the JAR files in the libs directory.
 */
dependencies {
    implementation 'androidx.appcompat:appcompat:1.3.0'
    implementation 'com.android.support.constraint:constraint-layout:2.0.4'
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation('cat.ereza:customactivityoncrash:2.3.0')
    implementation('com.github.YarikSOffice:lingver:1.3.0')
}

/**
 * The android{} block configures all of the parameters for the Android build.
 * You must provide a value for at least the compilation target.
 */
android {
    compileSdkVersion 30

    /**
     * This nested sourceSets block points the source code directories to the
     * existing folders in the project, instead of using the default new
     * organization.
     */
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = [
                    'res/layouts/main', 'res/layouts/options', 'res'
            ]
            assets.srcDirs = ['assets', 'html', 'res/html', 'src/main/assets']
        }

        // Move the tests to tests/java, tests/res, etc...
        //instrumentTest.setRoot('tests')

        /**
         * Move the build types to build-types/<type>
         * For instance, build-types/debug/java, build-types/debug/AndroidManifest.xml, ...
         * This moves them out of them default location under src/<type>/... which would
         * conflict with src/ being used by the main source set.
         * Adding new build types or product flavors should be accompanied
         * by a similar customization.
         */
        debug.setRoot('build-types/debug')
        release.setRoot('build-types/release')
    }
    defaultConfig {
        minSdkVersion 23
        targetSdkVersion 30
        applicationId "com.heathendean.catfarts"
        versionCode 1
        versionName "1.0"
    }
    applicationVariants.all { variant ->
        variant.resValue "string", "app_id", "Application ID: " + variant.applicationId
        variant.resValue "string", "version_number", "Version Number: " + variant.versionName
    }
    dependenciesInfo {
        includeInApk true
    }
//    aaptOptions {
//        cruncherEnabled = false
//    }
//    buildFeatures {
//        dataBinding true
//    }
}

// I believe this is for 'allprojects'?
repositories {
    google()
    mavenCentral()
    maven { url 'https://jitpack.io' }
}