room20.asc

// Vor dem Computer (Police Molest)

/****************************
*   Raum-Funktionen
****************************/
function room_Load()
{
  aMusic57.Play();
	String seperator = String.Format("\\ **** Vor dem Computer");
	oGittertuer.Clickable = false;
}

function room_AfterFadeIn()
{
  if ( player.PreviousRoom == 21 ) // Supercomputer
  {
    oSicherheitstuer.SetView(57);
		oSicherheitstuer.Animate(0, 1, eOnce, eBlock, eBackwards);
    oSicherheitstuer.Visible = false;
	}		
}


/****************************
*   Tür-Hotspot-Funktionen
****************************/



/****************************
*   Objekt-Funktionen
****************************/



/****************************
*   Hotspot-Funktionen
****************************/
bool TuerOeffnen()
{
	player.Walk(268, 125, eBlock, eWalkableAreas);
	player.FaceDirection(eDirectionUp);

	Wait(30);
  PlaySound(46);
  Wait(40);

	PlaySound(43); 
  oGittertuer.Visible = false;
	player.Walk(268, 116, eBlock, eAnywhere);

  Wait(20);
  player.FaceDirection(eDirectionDown);
  Wait(30);

	PlaySound(43); 
  oGittertuer.Visible = true;
  Wait(30);

  PlaySound(46);
  player.ChangeRoom(18, 262, 124, eDirectionUp);
}

function hGittertuer_AnyClick()
{
	if (any_click_move(268, 125, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Dadurch gelangt man wieder in die Freiheit.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Die Tür ist fest.");
		}
		else if (UsedAction(eActUse) || UsedAction(eActOpen))
		{
			Wait(5);
			if ( player.InventoryQuantity[iGefaengnissch.ID] > 0 )
			{
				TuerOeffnen();
			}
			else
			{
				player.Say("Ich hab' den passenden Schlüssel nicht.");
			}
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Das geht nur, wenn die offen ist.");
		}
		else if (UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Das Gitter ist sehr stabil.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			if ( player.ActiveInventory == iGefaengnissch )
			{
				TuerOeffnen();
			}
/*
			else if ( player.ActiveInventory == iDing && player == cMichael )
			{
				player.Say("Ding kann alleine durch die offenen Gitterstäbe da unten. Ich muss es ihm nur sagen.");
			}
*/
			else
			{
				player.Say("Warum sollte ich das durch das Gitter schieben.");
			}
		}
		else Unhandled();
	}
}

function hKonsole_AnyClick()
{
	if (any_click_move(101, 127, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Da muss man eine Schlüsselkarte reinstecken, ...");
			player.Say("und dann wird auch noch der Fingerabdruck gescannt.");
			Wait(20);
			player.Say("Starke Sicherheitsmaßnahmen ...");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Nette Idee.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			if ( player.ActiveInventory == iSchluesselkarte )
			{
        player.Say("Ich sollte die Schlüsselkarte damit benutzen.");
      }
      else
      {
        player.Say("Dazu brauche ich die Schlüsselkarte.");
      }
		}
		else if (UsedAction(eActOpen))
		{
			Wait(5);
			player.Say("So einfach geht das nicht auf.");
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Das geht nicht.");
		}
		else if (UsedAction(eActPull))
		{
			Wait(5);
			player.Say("Das kann ich nicht mit den Fingern greifen.");
		}
		else if (UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Dann wird mein Fingerabdruck gescannt.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			if ( player.ActiveInventory == iSchluesselkarte )
			{
				Wait(10);
				PlaySound(4);
				player.LoseInventory(iSchluesselkarte);
				Wait(30);
				PlaySound(4);
				player.AddInventory(iSchluesselkarte);
				Wait(40);
				PlaySound(66);
				Wait(40);
				
				oSicherheitstuer.SetView(57);
				oSicherheitstuer.Visible = true;
				player.FaceDirection(eDirectionRight);
				oSicherheitstuer.Animate(0, 1, eOnce, eBlock);
				
				Wait(10);
				player.Walk(140, 122, eBlock, eAnywhere);
				player.FaceDirection(eDirectionUp);
				Wait(15);
				player.Walk(140, 112, eBlock, eAnywhere);
				player.ChangeRoom(21, 81, 123, eDirectionRight); // Supercomputer
			}
			else
			{
				player.Say("Damit geht das nicht.");
			}
		}
		else Unhandled();
	}
}

function hSicherheitstuer_AnyClick()
{
	if (any_click_move(142, 123, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Dahinter verbirgt sich die Computeranlage.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Die ist mir zu schwer. Außerdem kann ich sie nicht so einfach mitnehmen.");
		}
		else if (UsedAction(eActUse) || UsedAction(eActOpen))
		{
			Wait(5);
			player.Say("Per Hand kann man die nicht öffnen.");
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Sie ist ja nicht mal offen.");
		}
		else if (UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Die bewegt sich keinen Millimeter.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			player.Say("Sprengen wäre besser.");
		}
		else Unhandled();
	}
}

function hRohr_AnyClick()
{
	if (any_click_move(45, 116, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Es ist rund.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Ich komm' nicht ran.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Und wie bitte?");
		}
		else if (UsedAction(eActOpen) || UsedAction(eActClose) 
					|| UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Das klappt nicht.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			player.Say("Nicht mit diesem Teil.");
		}
		else Unhandled();
	}
}

function hZellentrakt_AnyClick()
{
	any_click_move(-10, 119, eDirectionLeft, true);
}

/****************************
*   Regionen-Funktionen
****************************/
function region1_WalksOnto()
{
	player.FaceDirection(eDirectionLeft);
	player.ChangeRoom(22, 7, 83, eDirectionDown); // Zellen Dr. Lieblich
}