diff --git a/pkgs/development/rocm-modules/6/default.nix b/pkgs/development/rocm-modules/6/default.nix
index e4e745f74b56e..56875144890b0 100644
--- a/pkgs/development/rocm-modules/6/default.nix
+++ b/pkgs/development/rocm-modules/6/default.nix
@@ -150,7 +150,10 @@ in rec {
stdenv = llvm.rocmClangStdenv;
};
- hiprand = rocrand; # rocrand includes hiprand
+ hiprand = callPackage ./hiprand {
+ inherit rocmUpdateScript rocm-cmake clr rocrand;
+ stdenv = llvm.rocmClangStdenv;
+ };
rocfft = callPackage ./rocfft {
inherit rocmUpdateScript rocm-cmake rocrand rocfft clr;
diff --git a/pkgs/development/rocm-modules/6/hiprand/default.nix b/pkgs/development/rocm-modules/6/hiprand/default.nix
new file mode 100644
index 0000000000000..7251a0e5a07e5
--- /dev/null
+++ b/pkgs/development/rocm-modules/6/hiprand/default.nix
@@ -0,0 +1,76 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, rocmUpdateScript
+, cmake
+, rocm-cmake
+, clr
+, rocrand
+, gtest
+, buildTests ? false
+, gpuTargets ? [ ]
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+ pname = "hiprand";
+ version = "6.0.2";
+
+ outputs = [
+ "out"
+ ] ++ lib.optionals buildTests [
+ "test"
+ ];
+
+ src = fetchFromGitHub {
+ owner = "ROCm";
+ repo = "hipRAND";
+ rev = "rocm-${finalAttrs.version}";
+ hash = "sha256-uGHzOhUX5JEknVFwhHhWFdPmwLS/TuaXYMeItS7tXIg=";
+ };
+
+ nativeBuildInputs = [
+ cmake
+ rocm-cmake
+ clr
+ ];
+
+ buildInputs = [ rocrand ] ++ (lib.optionals buildTests [ gtest ]);
+
+ cmakeFlags = [
+ "-DCMAKE_C_COMPILER=hipcc"
+ "-DCMAKE_CXX_COMPILER=hipcc"
+ "-DHIP_ROOT_DIR=${clr}"
+ # Manually define CMAKE_INSTALL_
+ # See: https://github.com/NixOS/nixpkgs/pull/197838
+ "-DCMAKE_INSTALL_BINDIR=bin"
+ "-DCMAKE_INSTALL_LIBDIR=lib"
+ "-DCMAKE_INSTALL_INCLUDEDIR=include"
+ ] ++ lib.optionals (gpuTargets != [ ]) [
+ "-DAMDGPU_TARGETS=${lib.concatStringsSep ";" gpuTargets}"
+ ] ++ lib.optionals buildTests [
+ "-DBUILD_TEST=ON"
+ ];
+
+ postInstall = lib.optionalString buildTests ''
+ mkdir -p $test/bin
+ mv $out/bin/test_* $test/bin
+ rm -r $out/bin/hipRAND
+ # Fail if bin/ isn't actually empty
+ rmdir $out/bin
+ '';
+
+ passthru.updateScript = rocmUpdateScript {
+ name = finalAttrs.pname;
+ owner = finalAttrs.src.owner;
+ repo = finalAttrs.src.repo;
+ };
+
+ meta = with lib; {
+ description = "A HIP wrapper for rocRAND and cuRAND";
+ homepage = "https://github.com/ROCm/hipRAND";
+ license = with licenses; [ mit ];
+ maintainers = teams.rocm.members;
+ platforms = platforms.linux;
+ broken = versions.minor finalAttrs.version != versions.minor stdenv.cc.version || versionAtLeast finalAttrs.version "7.0.0";
+ };
+})
diff --git a/pkgs/development/rocm-modules/6/rocrand/default.nix b/pkgs/development/rocm-modules/6/rocrand/default.nix
index f09ff3b12059a..7d0e80b5af4e6 100644
--- a/pkgs/development/rocm-modules/6/rocrand/default.nix
+++ b/pkgs/development/rocm-modules/6/rocrand/default.nix
@@ -29,7 +29,6 @@ stdenv.mkDerivation (finalAttrs: {
repo = "rocRAND";
rev = "rocm-${finalAttrs.version}";
hash = "sha256-BBkcYOP+zh3OQTxuSkeiJizwnE9Gr5Jbhx0e8SU/mmU=";
- fetchSubmodules = true; # For inline hipRAND
};
nativeBuildInputs = [
@@ -68,6 +67,8 @@ stdenv.mkDerivation (finalAttrs: {
mkdir -p $benchmark/bin
mv $out/bin/benchmark_* $benchmark/bin
'' + lib.optionalString (buildTests || buildBenchmarks) ''
+ rm -r $out/bin/rocRAND
+ # Fail if bin/ isn't actually empty
rmdir $out/bin
'';