build.gradle.kts

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id("java")
    id("com.github.kt3k.coveralls") version "2.12.0"
    id("net.researchgate.release") version "3.0.0"
    kotlin("jvm") version "1.8.21"
    id("net.minecrell.plugin-yml.bukkit") version "0.5.3"
    id("com.github.johnrengelman.shadow") version "8.1.0"
    jacoco
}

group = "io.github.poeschl.bukkit"
version = "1.2.1"

repositories {
    mavenCentral()
    maven ("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
    maven ("https://maven.sk89q.com/repo/" )
    maven ("https://hub.spigotmc.org/nexus/content/repositories/snapshots" )
}

dependencies {
    compileOnly(libs.spigot.api)
    library(kotlin("stdlib-jdk8"))

    testImplementation(libs.spigot.api)

    testImplementation("org.junit.jupiter:junit-jupiter-api:5.3.1")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.3.1")
    testImplementation("org.mockito:mockito-core:5.3.1")
    testImplementation("org.assertj:assertj-core:3.24.2")
    testImplementation("org.mockito.kotlin:mockito-kotlin:4.1.0")
}

bukkit {
    name = rootProject.name
    authors = listOf("sarhatabaot")
    main = "io.github.poeschl.bukkit.logcleaner.LogCleanerPlugin"
    version = project.version.toString()
    apiVersion = "1.19"
}

val compileKotlin: KotlinCompile by tasks
compileKotlin.kotlinOptions {
    jvmTarget = "17"
}
val compileTestKotlin: KotlinCompile by tasks
compileTestKotlin.kotlinOptions {
    jvmTarget = "17"
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
}

tasks {
    build {
        dependsOn(shadowJar)
    }

    shadowJar {
        minimize()
        archiveClassifier.set("")

        dependencies {
            exclude("org.jetbrains.kotlin:*:*")
        }
    }
}

jacoco {
    toolVersion = "0.8.8"
}

tasks.jacocoTestReport {
    reports {
        xml.required.set(true)
        html.required.set(true)
    }
}