Gamesettings.CB

/////Funktiot settingsien lukuun by Latexi95

Type MAIN_Settings
    Field key$
    Field value$
EndType

Function MAIN_ParseSettings(filePath$)
    MAIN_ClearSettings()
    file = OpenToRead(filePath$)
    If file = 0 Then Return False
    lineNum = 1
    While Not EOF(file)
        l$ = ReadLine(file)
        notComment$ = Trim(GetWord(l$,1,"#"))
        If notComment <> "" Then
            If CountWords(notComment$,"=") < 2 Then
                MakeError "Syntax error in file "+filePath$+" at line "+lineNum
            EndIf
            If CountWords(notComment$,"=") = 2 Then
                newSetting.MAIN_Settings = New(MAIN_Settings)
                newSetting\key$ = Lower(Trim(GetWord(notComment$,1,"=")))
                newSetting\value$ = Trim(GetWord(notComment$,2,"="))
            Else
                place = InStr(notComment$,"=")
                newSetting.MAIN_Settings = New(MAIN_Settings)
                newSetting\key$ = Lower(Trim(Left(notComment$,place-1)))
                newSetting\value$ = Trim(Mid(notComment,place+1))
            EndIf
        EndIf
        lineNum + 1
    Wend
    CloseFile file
EndFunction

Function MAIN_SaveSettings(filePath$)
    f = OpenToWrite(filePath$)
    For setting.MAIN_Settings = Each MAIN_Settings
        WriteLine f,setting\key$ + " = " + setting\value
    Next setting
    CloseFile f     
EndFunction

Function MAIN_DeleteSetting(key$)
    key$ = Lower(key$)
    For setting.MAIN_Settings = Each MAIN_Settings
        If setting\key$ = key Then
            Delete setting
            Return True
        EndIf
    Next setting
    Return False
EndFunction



Function MAIN_GetSetting(key$)
    key$ = Lower(key$)
    For setting.MAIN_Settings = Each MAIN_Settings
        If setting\key$ = key Then Return setting\value$
    Next setting
    Return ""
EndFunction

Function MAIN_HasSetting(key$)
    key$ = Lower(key$)
    For setting.MAIN_Settings = Each MAIN_Settings
        If setting\key$ = key Then Return True
    Next setting
    Return False
EndFunction

Function MAIN_SetSetting(key$,value$)
    key$ = Lower(key$)
    For setting.MAIN_Settings = Each MAIN_Settings
        If setting\key$ = key Then
            setting\value = value
            Return True
        EndIf
    Next setting
    newSetting.MAIN_Settings = New(MAIN_Settings)
    newSetting\key = key
    newSetting\value = value
    Return False
EndFunction

Function MAIN_ClearSettings()
    For setting.MAIN_Settings = Each MAIN_Settings
        Delete setting
    Next setting
EndFunction