-
Notifications
You must be signed in to change notification settings - Fork 2
/
apertium-ita.ita.rlx
1725 lines (1350 loc) · 96.9 KB
/
apertium-ita.ita.rlx
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
DELIMITERS = "<.>" "<!>" "<?>" "<...>" "<¶>" "<:>";
SOFT-DELIMITERS = "<,>" "<;>";
OPTIONS += no-inline-templates ;
SUBREADINGS = LTR ; # Alternate, left-to-right (main reading on the left)
SETS
LIST BOS = (>>>) sent ;
LIST EOS = (<<<) sent ;
LIST A = adj ;
LIST Adv = adv ;
LIST PreAdv = preadv ;
LIST Pron = prn ;
LIST N = n ;
LIST Acr = (n acr) ;
LIST NP = np ;
LIST V = vblex ;
LIST Vall = vblex vbmod vbser vbhaver ;
LIST Vaux = vbser vbhaver ;
LIST Vmod = vbmod ;
LIST Inf = inf ;
LIST Ger = ger ;
LIST PP = pp ;
LIST Pri = pri ;
LIST Ifi = ifi ;
LIST Prs = prs ;
LIST Pis = pis ;
LIST Subj = prs pis ;
LIST Imper = imp ;
LIST Det = det ;
LIST Def = def ;
LIST Ind = ind ;
LIST Dem = dem ;
LIST Pos = pos ;
LIST PreDet = predet ;
LIST CnjCoo = cnjcoo ;
LIST CnjSub = cnjsub ;
LIST CnjAdv = cnjadv ;
LIST Interj = ij ;
LIST Interr = itg ;
LIST Num = num ;
LIST Prep = pr ;
LIST Rel = rel ;
LIST CM = cm ;
LIST Lpar = lpar ;
LIST Guio = guio ;
LIST Quot = quot ;
SET Noun_Adj = N OR A ;
SET Noun_Adj_PP = N OR A OR PP ;
SET Adj_PP = A OR PP ;
SET Noun_NP = N OR NP ;
SET Adv_PreAdv = Adv OR PreAdv ;
SET Aord = (adj ord) ;
SET Ant = (np ant) ;
SET Cog = (np cog) ;
SET Ant_Cog = Ant OR Cog ;
SET Top = (np top) OR (np loc) OR (np hyd) ;
SET Org = (org) ;
SET Al = (al) ;
LIST Sg = sg ;
LIST Pl = pl ;
LIST SP = sp ;
LIST M = m ;
LIST F = f ;
LIST MF = mf ;
LIST Masc = m mf ;
LIST Fem = f mf ;
LIST SgSp = sg sp ;
LIST PlSp = pl sp ;
SET MascSg = (m sg) OR (m sp) OR (mf sg) OR (mf sp) ;
SET MascPl = (m pl) OR (m sp) OR (mf pl) OR (mf sp) ;
SET FemSg = (f sg) OR (f sp) OR (mf sg) OR (mf sp) ;
SET FemPl = (f pl) OR (f sp) OR (mf pl) OR (mf sp) ;
LIST P1 = (p1) ;
LIST P2 = (p2) ;
LIST P3 = (p3) ;
SET Sg1 = (p1 sg) ;
SET Sg2 = (p2 sg) ;
SET Sg3 = (p3 sg) ;
SET Pl1 = (p1 pl) ;
SET Pl2 = (p2 pl) ;
SET Pl3 = (p3 pl) ;
SET Pers = (p1) OR (p2) OR (p3) ;
SET ConcordaGN = MascSg OR MascPl OR FemSg OR FemPl;
SET ConcordaSP = SgSp OR PlSp ;
SET ConcordaGV = Sg1 OR Sg2 OR Sg3 OR Pl1 OR Pl2 OR Pl3 ;
SET Ref = (prn pro ref) ;
SET Pro = (prn pro) ;
SET Enc = (prn enc) ;
SET Tn = (prn tn) ;
SET Tn_Nt = (prn tn nt) ;
SET Pro_Nt = (prn pro nt) ;
SET Pref1 = (pref) ; # "real" prefix
SET Pref2 = (adj mf sp) ; # adj.mf.sp used as a prefix
SET Aord = (adj ord) OR ("sette") ; # sette/setta
LIST unknown = ("\\*.*"r) ;
LIST unknownMajIni = ("\\*[A-ZÀÁÈÉíÒÓÚÜÇ].*"r) ;
LIST unknownMajIni2 = ("\\*[A-ZÀÁÈÉÍÌÒÓÚÜÇ][a-zàáèéìíòóùúïüçñ·]+.*"r) ;
LIST unknownMaj = ("\\*[A-ZÀÁÈÉíÒÓÚÜÇ]*"r) ;
LIST MajIni = ("<[A-ZÀÁÈÉíÒÓÚÜÇ].*>"r) ;
LIST MinIni = ("<[a-zàáèéìíòóùúçñ].*>"r) ;
LIST MajIni2 = ("<[A-ZÀÁÈÉÍÌÒÓÚÜÇ][a-zàáèéìíòóùúïüçñ·]+.*>"r) ;
LIST Maj = ("<[A-ZÀÁÈÉíÒÓÚÜÇ]*>"r) ;
LIST segles_num_romans = ("[IVX][IVX]*"r) ;
LIST Anno = ("[1-2][0-9][0-9][0-9]"r) ;
LIST Avere = vbhaver ;
LIST Ser = vbser ;
LIST Essere = "essere" ;
LIST Dovere = "dovere" ;
LIST Abbastanza = "abbastanza" ;
LIST Altro = "altro" ;
LIST Anche = "anche" ;
LIST Ancora = "ancora" ;
LIST Andare = "andare" ;
LIST Bua = "bua" ;
LIST Bue = "bue" ;
LIST Calibro = "calibro" ;
LIST Cardinale = "cardinale" ;
LIST Certo = "certo" ;
LIST Che = "che" ;
LIST Chi = "chi" ;
LIST Ci = "ci" ;
LIST Circa = "circa" ;
LIST Colle = "colle" ;
LIST Collo = "collo" ;
LIST Come = "come" ;
LIST Considerare = "considerare" ;
LIST Conte = "conte" ;
LIST Conto = "conto" ;
LIST Cosa = "cosa" ;
LIST Da = "da" ;
LIST Dai = "dai" ;
LIST Dallo = "dallo" ;
LIST Dare = "dare" ;
LIST Dei = "dei" ;
LIST Di = "di" ;
LIST Diventare = "diventare" ;
LIST Diverso = "diverso" ;
LIST Dopo = "dopo" ;
LIST Dove = "dove" ;
LIST Duce = "Duce" ;
LIST Era = "era" ;
LIST Il = "il" ;
LIST In = "in" ;
LIST Io = "io" ;
LIST Fare = "fare" ;
LIST Fine = "fine" ;
LIST Fronte = "fronte" ;
LIST Genere = "genere" ;
LIST Genero = "genero" ;
LIST Giudicare = "giudicare" ;
LIST Ione = "ione" ;
LIST Ionio = "ionio" ;
LIST Latta = "latta" ;
LIST Latte = "latte" ;
LIST Lo = "lo" ;
LIST Loro = "loro" ;
LIST Lui = "lui" ;
LIST Lei = "Lei" ;
LIST Indire = "indire" ;
LIST Indicare = "indicare" ;
LIST Mandato = "mandato" ;
LIST Mantenere = "mantenere" ;
LIST Mezzo = "mezzo" ;
LIST Molto = "molto" ;
LIST Mosca = "Mosca" ;
LIST Nato = "nato" ;
LIST Ogni = "ogni" ;
LIST Oltre = "oltre" ;
LIST Ora = "ora" ;
LIST Parere = "parere" ;
LIST Partita = "partita" ;
LIST Perche = "perché" ;
LIST Primo = "primo" ;
LIST Puo_essere = "può essere" ;
LIST Principale = "principale" ;
LIST Principe = "principe" ;
LIST Principio = "principio" ;
LIST Quale = "quale" ;
LIST Qualunque = "qualunque" ;
LIST Quanto = "quanto" ;
LIST Regia = "regia" ;
LIST Rimanere = "rimanere" ;
LIST Risultare = "risultare" ;
LIST San = "<San>" ;
LIST Santo = "santo" ;
LIST Secondo = "secondo" ;
LIST Sembrare = "sembrare" ;
LIST Sentire = "sentire" ;
LIST Serie = "serie" ;
LIST Sette = "sette" ;
LIST Si = "si" ;
LIST Sole = "sole" ;
LIST Solo = "solo" ;
LIST Sotto = "sotto" ;
LIST Stato = "stato" ;
LIST Stesso = "stesso" ;
LIST Subito = "subito" ;
LIST Tra = "tra" ;
LIST Tratta = "tratta" ;
LIST Trovare = "trovare" ;
LIST Tu = "tu" ;
LIST Turbo = "turbo" ;
LIST Tutto = "tutto" ;
LIST Ultimo = "ultimo" ;
LIST Un = "un" ;
LIST Vario = "vario" ;
LIST Verso = "verso" ;
LIST Venire = "venire" ;
LIST Vi = "vi" ;
LIST VCop = vbser "sembrare" "parere" ;
LIST Mese = "gennaio" "febbraio" "marzo" "aprile" "maggio" "giugno" "luglio" "agosto" "settembre" "ottobre" "novembre" "dicembre" ;
LIST Gentilizio = "abcaso" "accadiano" "accado" "acheo" "adyghè" "africano" "ainu" "albanese" "algonchino" "alsaziano" "altai" "alvernese" "amazigh" "americano" "amorreo" "andaluso" "angioino" "apache" "arabo" "aragonese" "arameo" "aranese" "armeno" "asiatico" "assiro" "asturiano" "ateniese" "australiano" "avaro" "aymarà" "azero" "balkar" "baltico" "bambara" "bantu" "basco" "bashkir" "battriano" "bavarese" "beluci" "bengalese" "berbero" "bielorusso" "birmano" "bolognese" "borgognone" "boscimane" "boscimano" "bosniaco" "bretone" "bulgaro" "burgundio" "burgundo" "buriato" "cabardino" "cabilo" "calabrese" "calmucco" "cambogiano" "cananeo" "cantonese" "caracalpaco" "caraciai-balcaro" "careliano" "cartaginese" "casciubo" "cassita" "castigliano" "catalano" "ceceno" "ceco" "cecoslovacco" "centroamericano" "ceremisso" "cherokee" "chuvash" "cimmerio" "cinese" "circasso" "ciukcio" "comanche" "coreano" "cornico" "corso" "cretese" "croato" "cumano" "curdo" "dacio" "dalmata" "danese" "dioula" "dorio" "ebraico" "elamita" "emiliano" "eoliano" "eschimese" "estone" "etiope" "etrusco" "europeo" "fenicio" "fiammingo" "finlandese" "fiorentino" "francese" "franco" "frigio" "frisone" "friulano" "fula" "fulani" "gallese" "gallo" "genovese" "georgiano" "giapponese" "giavanese" "goto" "greco" "guaraní" "guascone" "gujarati" "hausa" "hawaiano" "hazara" "hurrita" "ibero" "igbo" "illirio" "indonesiano" "inglese" "inguscio" "inuit" "ionio" "irlandese" "irochese" "islandese" "istriano" "italiano" "ittita" "jacuto" "jakuto" "karachai" "kashmiro" "kazako" "khanti" "khmer" "kirghizo" "komi" "laotiano" "latino" "leonese" "lesgo" "lettone" "lezghiano" "lidio" "ligure" "limosino" "linguadociano" "lituano" "lombardo" "longobardo" "loreno" "lussemburghese" "macedone" "maiorchino" "malese" "malgascio" "maltese" "manciù" "mannese" "mansi" "maori" "mapuce" "mari" "marshallese" "miceneo" "micronesiano" "milanese" "mingrelio" "minoico" "minorchino" "mirandese" "moghul" "mohawk" "moldavo" "mongolo" "montenegrino" "mordvino" "mozarabo" "nabateo" "napoletano" "napolitano" "navajo" "nepalese" "nizzardo" "nogai" "normanno" "nordamericano" "norvegese" "nubiano" "occitano" "olandese" "oromo" "osco" "osseto" "ostiaco" "ostrogoto" "ottentotto" "ottomano" "palmireno" "pangiabi" "pashtun" "pecenego" "persiano" "peul" "picardo" "piemontese" "pisano" "polacco" "polinesiano" "portoghese" "provenzale" "punico" "punjabi" "quechua" "rapanui" "romagnolo" "romano" "rumeno" "russo" "ruteno" "sabino" "sakha" "samoano" "saraceno" "sardo" "savoiardo" "scita" "scozzese" "serbo" "siciliano" "sindhi" "singalese" "siriaco" "slavo" "slovacco" "sloveno" "sogdiano" "somalo" "songhai" "sorabo" "spagnolo" "spartano" "sudamericano" "sumero" "svedese" "svevo" "swahili" "tagico" "tailandese" "taiwanese" "tamil" "tartaro" "tataro" "tebano" "tedesco" "telugu" "tibetano" "toscano" "tracio" "troiano" "tuareg" "tunguse" "turco" "turkmeno" "tuvano" "ucraino" "udmurto" "uiguro" "umbro" "ungherese" "unno" "uzbeko" "valdese" "valenciano" "vallone" "vandalo" "veneziano" "vichingo" "vietnamita" "visigoto" "votiaco" "xhosa" "yoruba" "zulu" ;
LIST AdjPre = "buono" "principale" ;
LIST Excl = "!" ;
LIST Nsg = (n sg) ;
LIST Npl = (n pl) ;
LIST Vconj = (vblex p1) (vblex p2) (vblex p3) ; # verb conjugat
LIST Vinterr = ("domandare") ("chiedere") ;
LIST Secoli = ("Duecento") ("Trecento") ("Quattrocento") ("Cinquecento") ("Seicento") ("Settecento") ("Ottocento") ("Novecento") ("Duemila") ;
# verbi seguiti da aggetivo
LIST VAdj = ("considerare") ("giudicare") ("sentire") ("risultare") ("parere") ("mantenere") ("rimanere") ;
# aggetivi seguiti da nome
LIST AdjN = ("tanto") ("principale") ("ultimo") ("altro") ("unico") ("ex") ;
# coincidències nom propi/comú
SET NomPropiComu = ("Sala") OR ("Guerra") OR ("Guardia");
SET Dignità = ("presidente") OR ("presidentessa") OR ("presidenta") OR ("vicepresidente") OR ("vicepresidentessa") OR ("vicepresidenta") OR ("governatore") OR ("imperatore") OR ("re") OR ("principe") OR ("barone") OR ("conte") OR ("visconte") OR ("marchese") OR ("duca") OR ("arciduca") OR ("vescovo") OR ("arcivescovo");
# All possible word categories
SET WORD = N | V | A | Pron | Det | Adv | CnjCoo | CnjSub | Interj | Num | ("\?") | ("!") ;
SET PRE-N = A | Det | Num | CnjCoo ;
SET MARK = CM | ("\\") | ("\;") ;
SET WORDMARK = WORD | MARK ;
SET N-MOD = A | Det | Num ;
# Categories which cannot be part of a noun phrase
SET NPNH = WORDMARK - PRE-N ;
SET NPNHA = WORDMARK - PRE-N - Adv ;
SET NOT-ADV = WORDMARK - Adv ;
# Barriers
SET S-BOUNDARY = CnjSub | Interr | EOS;
SET Barrera_Final_SN = EOS OR Prep OR Det OR CnjSub OR CnjAdv OR Vall OR Rel OR Pro ; # Vall és perillós per la ambigüitat, però en general, prolífic
SET Barrera_Final_Estrict_SN = EOS OR Prep OR Det OR CnjSub OR CnjAdv OR Rel OR Pro ;
SET Barrera_Inicial_SN = BOS OR Prep OR CnjSub OR CnjAdv OR Vall OR Rel ; # Vall és perillós per la ambigüitat, però en general, prolífic
SET Barrera_Inicial_Estrict_SN = BOS OR Prep OR CnjSub OR CnjAdv OR Rel ;
SET Barrera_Inicial_Prop = BOS OR CnjSub OR CnjAdv OR Rel ;
SET Limite_Barrera_Inicial_SN = ("esser") OR ("parere") OR ("avere") ;
SECTION
SELECT Interj IF (NOT -1/* Det + MascSg) (0 ("buon giorno")) ;
SELECT Interj IF (NOT -1/* Det + FemSg) (0 ("buona sera")) ;
SELECT Interj IF (NOT -1/* Det + FemSg) (0 ("buona notte")) ;
REMOVE Interj IF (NOT 1* ("!")) ;
SELECT Interj IF (-1 BOS OR CM) (1 ("!")) ;
SELECT Interj IF (1 CM) (1* ("!")) ;
SELECT Interj IF (0 ("<Presto>")) (1 CM) ;
SELECT Pron IF (0 Io) ;
SELECT Pron IF (0 Lui) (0 Loro) (1C Det) ;
SELECT Lui IF (0 Lui) (0 Loro) (-1 Vall) (NOT 1 A OR N) (NOT 0 ("<Loro>")) ; # per proporre loro i libri
SELECT Lei IF (0 ("<Lei>")) (1 Ser + Sg OR Diventare + Sg) (2 Adj_PP + M + SgSp) ; # Lei è simpatico
SELECT Lei IF (0 ("<Loro>")) (1 Ser + Pl OR Diventare + Pl) (2 Adj_PP + M + PlSp) ; # Loro sono simpatici
SELECT Lei IF (0 ("<Lei>")) (1 Adv) (2 Ser + Sg OR Diventare + Sg) (3 Adj_PP + M + SgSp) ; # Lei non è simpatico
SELECT Lei IF (0 ("<Loro>")) (1 Adv) (2 Ser + Pl OR Diventare + Pl) (3 Adj_PP + M + PlSp) ; # Loro non sono simpatici
SELECT Lei IF (0 ("<Lei>")) (1 Ser + Sg OR Diventare + Sg) (2 Adv_PreAdv) (3 Adj_PP + M + SgSp) ; # Lei è molto simpatico
SELECT Lei IF (0 ("<Loro>")) (1 Ser + Pl OR Diventare + Pl) (2 Adv_PreAdv) (3 Adj_PP + M + PlSp) ; # Loro sono molto simpatici
SELECT Lei IF (0 ("<Lei>")) (1 Adv) (2 Ser + Sg OR Diventare + Sg) (3 Adv_PreAdv) (4 Adj_PP + M + SgSp) ; # Lei non è molto simpatico
SELECT Lei IF (0 ("<Loro>")) (1 Adv) (2 Ser + Pl OR Diventare + Pl) (3 Adv_PreAdv) (4 Adj_PP + M + PlSp) ; # Loro non sono molto simpatici
SELECT Lui + F IF (0 Lui) (0 Lei) (0 ("<Lei>")) (-1 BOS) ;
SELECT Lei IF (0 Lui) (0 Lei) (0 ("<Lei>") OR ("<Loro>")) (NOT -1 BOS) ;
REMOVE Lei IF (0 Lui) (0 Lei) (NOT 0 ("<Lei>") OR ("<Loro>")) ;
SELECT Lui + Pron IF (0 Lui) (0 Loro) (-1C Prep) (NOT 1 A OR N) ; # tra di loro
REMOVE Det IF (0 Loro) (1C Vall) ;
REMOVE Det IF (0 Loro) (1 Adv) (2 Vall) ;
SELECT Lui IF (0 Loro) (1 Vall + P3 + Pl) ;
SELECT Lui IF (0 Loro) (1 Adv) (2 Vall + P3 + Pl) ;
SELECT Pron IF (-1 ("non")) (0 Lo) (0 Il) (1 Inf) ;
SELECT Det IF (0 Lo) (0 Il) (1 Inf) ;
SELECT Pron IF (0 Lo) (0 Il) (1C Vall) ;
SELECT Pron IF (0 Lo) (0 Il) (1 Pro) (2 Vall) ;
SELECT Det IF (0 Lo) (0 Il) (NOT 1 Vall) (NOT 2 Vall) ;
SELECT Det IF (0 Lo) (0 Il + &&ConcordaGN) (1 N + &&ConcordaGN) (NOT 1 Vall) ;
SELECT Det IF (0 Lo) (0 Il) (1 A) (2 N) ;
LIST No_Pro_Nt = "dare# fastidio" "innalzare" "infuriare" "molestare" "uccidere" ;
REMOVE Pro_Nt IF (0 Lo) (1 No_Pro_Nt) ; # lo infuria
REMOVE Pro_Nt IF (0 Lo) (1 Avere) (2 No_Pro_Nt + PP) ; # lo avere infuriato
REMOVE Pro_Nt IF (0 Lo) (1 Avere) (2 Adv) (3 No_Pro_Nt + PP) ;
REMOVE Pro_Nt IF (0 Lo) (1 Avere) (2 Adv OR PreAdv) (3 Adv) (4 No_Pro_Nt + PP) ;
REMOVE Pro_Nt IF (0 Lo) (1 ("fare")) (2 No_Pro_Nt + Inf) ; # lo fa infuriare
REMOVE Pro_Nt IF (0 Lo) (1 ("fare")) (2 Adv) (3 No_Pro_Nt + Inf) ; # lo fa sempre infuriare
SELECT Prep IF (0 Sotto) (1 Det) ;
SELECT PreDet IF (0 PreDet + &&ConcordaGN) (1 Det + Def + &&ConcordaGN) (2 N + &&ConcordaGN) ; # ambedue le aree politiche
SELECT Pron IF (0 Tutto + &&ConcordaGN) (NOT 1 Det + &&ConcordaGN) ;
SELECT Avere IF (1 PP) ;
SELECT Avere IF (1 Adv) (2 PP) ;
SELECT Avere IF (1 Adv OR PreAdv) (2 Adv) (3 PP) ;
SELECT Ser IF (0 Puo_essere) (1 PP) ;
SELECT Ser IF (0 Puo_essere) (1 A) ;
SELECT PP IF (-1 Essere) (0 Stato) ;
SELECT PP IF (-2 Essere) (-1 Adv) (0 Stato) ;
SELECT PP IF (-3 Essere) (-2 Adv) (-1 Adv) (0 Stato) ;
SELECT Ser IF (-2 ("arribare")) (-1 ("a")) (0 Essere) ;
SELECT Ser IF (-1 Ser) (0 Ser + PP) (1 PP) ;
SELECT Ser IF (-2 Ser) (-1 Adv) (0 Ser + PP) (1 PP) ;
SELECT Ser IF (-1 Ser) (0 Ser + PP) (1 Adv) (2 PP) ;
SELECT Ser IF (-2 Ci) (-1 Ser) (0 Ser + PP) ; # c'è stato
SELECT Ser IF (-1 Ser) (0 PP) (1C Det) ; # è stato una sventura
SELECT Ser IF (-1 Ser) (0 PP) (1 Adv) (2C Det) ; # è stato invece una sventura
SELECT Ser IF (-1 Ser) (0 PP) (1 Adv OR PreAdv) (2 Adv OR PreDet) (3C Det) ;
SELECT Ser IF (-2 Ser) (-1 Adv) (0 PP) (1C Det) ;
SELECT Ser IF (-2 Ser) (-1 Adv) (0 PP) (1 Adv OR PreDet) (2C Det) ;
SELECT Ser IF (-2 Ser) (0 PP) (1 Adv OR PreAdv) (2 Adv OR PreDet) (3C Det) ;
SELECT PP IF (-1 Stato LINK -1 Essere) ;
SELECT Ser IF (-1C Adv) (0 Era) ; # non era già arribato
SELECT Ser IF (0 Era) (1 PP + Sg) ;
SELECT Ser IF (0 Era) (1 Adv) (2 PP + Sg) ;
SELECT Ser IF (-1 Barrera_Inicial_Prop) (0 Era) (1 Det + Sg) ; # Era un rappresentante
SELECT Ser IF (-1 Barrera_Inicial_Prop) (0 Era) (1 N + Sg) ; # Era rappresentante
SELECT Ser IF (-1 Barrera_Inicial_Prop) (0 Era) (1 A + Sg) ; # Era intelligente
SELECT Ser IF (-1 Barrera_Inicial_Prop) (0 Era) (1 Adv) (2 A + Sg) ; # Era molto intelligente
REMOVE Ant IF (-1 BOS) (0 ("<Era>")) (NOT 1* ("Zeus") OR ("Crono") OR ("Rea") OR ("Giunone") OR ("Eracle")) ;
REMOVE Ant IF (0 ("<Era>")) (1 PP) ;
REMOVE Ant IF (0 ("<Era>")) (1 Adv) (2 PP) ;
#SELECT Pron IF (0C Pron OR Det) (NOT 1* N BARRIER NPNHA) ; -- aquesta regla genera infinitat d'errors
SELECT V IF (-1 Adv) (0 ("<fa>"i)) ; # non fa, sempre fa
SELECT Adv IF (-2 Num OR Ind) (-1 ("secondo") OR ("minuto") OR ("ora") OR ("giorno") OR ("settimana") OR ("mese") OR ("anno") OR ("lustro") OR ("decennio") OR ("secolo") OR ("millennio")) (0 ("<fa>"i)) ; # una settimana fa
SELECT Adv IF (-3 ("dozzina") OR ("ventina") OR ("trentina") OR ("quarantina") OR ("cinquantina") OR ("centinaio") OR ("migliaio") OR ("milione") OR ("miliardo")) (-2 Di) (-1 ("secondo") OR ("minuto") OR ("ora") OR ("giorno") OR ("settimana") OR ("mese") OR ("anno") OR ("lustro") OR ("decennio") OR ("secolo") OR ("millennio")) (0 ("<fa>"i)) ; # una settimana fa
REMOVE Adv IF (0 ("<fa>"i)) ;
REMOVE Ant IF (-1 BOS) (0 ("Che")) ;
REMOVE A IF (0 ("don")) (NOT -1 NP OR unknownMajIni) ;
# Prefissi
SELECT Pref1 IF (0 (META:/-/r)) (1 N OR A OR V OR unknown) ;
SELECT Pref1 IF (1 ("-")) (2 N OR A OR V OR unknown) ;
SELECT Pref1 IF (0 ("al")) (0 (META:/-/r)) (1 MajIni OR unknownMajIni) ;
SELECT Pref1 IF (0 ("al")) (1 ("-")) (2 MajIni OR unknownMajIni) ;
REMOVE Pref1 ; # IF (NOT 0 ("anti") OR ("auto") OR ("multi") OR ("neo") OR ("pluri") OR ("post") OR ("pre") OR ("proto") OR ("ex") OR ("semi")) (NOT 0 (META:/-/r)) (NOT 1 ("-")) ;
SELECT Pref2 IF (0 (META:/-/r)) (1 N OR A OR V OR unknown) ;
SELECT Pref2 IF (1 ("-")) (2 N OR A OR V OR unknown) ;
REMOVE Pref2 IF (0 ("anti") OR ("auto") OR ("multi") OR ("neo") OR ("pluri") OR ("post") OR ("pre") OR ("proto") OR ("ex") OR ("semi")) (NOT 0 (META:/-/r)) (NOT 1 ("-")) ;
SELECT A IF (0 ("anti") OR ("auto") OR ("multi") OR ("post") OR ("pre") OR ("semi")) (0 (META:/-/r)) (1 N OR A OR V OR unknown) ;
SELECT A IF (0 ("anti") OR ("auto") OR ("multi") OR ("post") OR ("pre") OR ("semi")) (1 ("-")) (2 N OR A OR V OR unknown) ;
REMOVE A IF (0 ("anti") OR ("auto") OR ("multi") OR ("post") OR ("pre") OR ("semi")) (NOT 0 (META:/-/r)) (NOT 1 ("-")) ;
SELECT N OR A OR V IF (-1C Pref1 OR Pref2) (0 (META:/-/r)) ;
SELECT N OR A OR V IF (-2C Pref1 OR Pref2) (-1 ("-")) ;
SECTION
REMOVE Imper IF (NOT 1* Excl) ;
SELECT Imper IF (0C Vall) (1* Excl) (NOT -1* Vall + Pers) (NOT 1* Vall + Pers) ;
SELECT Essere IF (0 Sg1) ;
SELECT Vmod IF (0 Dovere) (1 Vall + Inf) ;
SELECT Vmod IF (0 Dovere) (1 Adv OR Pron) (2 Vall + Inf) ;
REMOVE Vmod IF (0 Dovere) (NOT 1 Inf) (NOT 2 Inf) ;
SELECT PP IF (-1 Andare + Inf) (0 PP + Sg) ;
SELECT PP IF (-1 Andare + Ger) (0 PP + Sg) ;
SELECT PP IF (-1 Andare + Sg) (0 PP + Sg) ;
SELECT PP IF (-1 Andare + Pl) (0 PP + Pl) ;
SELECT Adj_PP (-2 Ser + Sg) (-1 Tutto + Sg) (0 Adj_PP + Sg) ;
SELECT Adj_PP (-2 Ser + Pl) (-1 Tutto + Pl) (0 Adj_PP + Pl) ;
SELECT Adj_PP (-2 Avere) (-1 Tutto) (0 Adj_PP) ;
SELECT Imper IF (-1 BOS OR Guio) (0C ("<dai>"i) OR ("<dagli>"i) ) (1* Excl) ;
#REMOVE V IF (0 ("dai")) ; # dai: distanza dai subordinati. WARNING: No funciona no sé perquè
#REMOVE V IF (0 Dai) ; # dai: distanza dai subordinati. WARNING: No funciona no sé perquè
#SELECT Prep IF (0 Dai) ; # dai: distanza dai subordinati. WARNING: No funciona no sé perquè
REMOVE V IF (0 Sg2) (0/* Prep) ; # dai (alternativa bèstia però funciona)
SELECT Prep IF (0 ("<dei>"i)) (1 unknown) ;
SELECT Prep IF (0 ("<nei>"i)) (1 unknown) ;
SELECT Prep IF (-1C Noun_Adj) (0 ("<dei>"i)) ;
SELECT Prep IF (-1 ("<uno>"i)) (0 ("<dei>"i)) ;
REMOVE Vall + Pers IF (-1 ("<dei>"i)) ;
REMOVE Vall + Pers IF (-1 ("<nei>"i)) ;
# Le regole seguenti sono commentate perché le regole di trasferimento ita-srd prevedono l'analisi come "prep + det.def" invece di "det.ind"
#SELECT Det IF (-2 Ci) (-1 Ser) (0 ("<dei>"i)) (1 Noun_Adj + MascPl) ; # ci furono dei negoziati
#SELECT Det IF (-3 Ci) (-2 Ser) (-1 Adv) (0 ("<dei>"i)) (1 Noun_Adj + MascPl) ; # ci furono dei negoziati
#SELECT Det IF (-3 Ci) (-2 Ser) (-1 Ser + PP) (0 ("<dei>"i)) (1 Noun_Adj + MascPl) ; # ci sono stati dei negoziati
#SELECT Det IF (-4 Ci) (-3 Ser) (-2 Ser + PP) (-1 Adv) (0 ("<dei>"i)) (1 Noun_Adj + MascPl) ; # ci sono stati dei negoziati
REMOVE N IF (NOT -1/* Det + FemSg OR A + FemSg) (0 ("<era>"i)) (NOT 1C V + Pers) ; # era figlia
REMOVE ("riso_pianta") IF (0 ("<riso>"i)) (1* ("goia") OR ("allegria") OR ("lacrima") OR ("ridere") OR ("piangere"));
REMOVE ("riso_pianta") IF (0 ("<riso>"i)) (-1* ("goia") OR ("allegria") OR ("lacrima") OR ("ridere") OR ("piangere"));
SELECT ("riso_pianta") IF (0 ("<riso>"i)) (0 ("riso")) ;
LIST ChiesaEcc = "chiesa" "duomo" "capella" ;
REMOVE NP IF (-2 ChiesaEcc) (-1 Di) (0 San) (1 MajIni OR unknownMajIni) ;
REMOVE NP IF (-3 ChiesaEcc) (-2 A) (-1 Di) (0 San) (1 MajIni OR unknownMajIni) ;
REMOVE NP IF (-5 ChiesaEcc) (-4 Di) (-3 San) (-2 MajIni OR unknownMajIni) (-1 CnjCoo) (0 San) ;
REMOVE NP IF (-6 ChiesaEcc) (-5 A) (-4 Di) (-3 San) (-2 MajIni OR unknownMajIni) (-1 CnjCoo) (0 San) ;
SELECT NP IF (0 San) (1 MajIni OR unknownMajIni) ;
REMOVE NP IF (-1 BOS) (0 ("<Primo>")) (1 MinIni) ;
REMOVE NP IF (0 ("<Valle>")) (1 Di) (1/* Det + Def) ;
SELECT NP IF (-1 Ant) (0 Di) (1 MajIni OR unknownMajIni) ;
SELECT NP IF (NOT -1 BOS OR MajIni OR Quot) (NOT -1 (META:/[–—"“«]/r)) (0 Di) (1 MajIni OR unknownMajIni) ;
REMOVE NP IF (0 Di) ;
SELECT Pron IF (0 ("alcun") OR ("ciascun") OR ("qualcun") OR ("nessun")) (1 Prep) ;
SELECT Det IF (-1 Prep LINK NOT 0/* N) (0 A OR Det) (NOT 0 ("I")) (1 N) ;
SELECT Pron IF (0 ("<gli>") OR ("<Gli>")) (1 ("si")) ;
SELECT Pron IF (0 Si) (1 Vall + P3) ;
SELECT A IF (-1/* Det + &&ConcordaGN) (0 Altro + &&ConcordaGN) (1 N + &&ConcordaGN) ;
REMOVE A IF (-2/* Det + Sg) (-1 Anno) (0 Det) (1C N) (NOT 0 Certo OR Vario) ; # nel 2009 diversi amici
REMOVE A IF (-2 Mese) (-1 Anno) (0 Det) (1C N) (NOT 0 Certo OR Vario) ; # il 13 dicembre 2008 diversi amici
REMOVE A IF (NOT -1/* Det + Ind OR Num) (0 Det) (1C N) (NOT 0 Certo OR Vario) ; # mia mamma ; un suo libro
SELECT Det IF (NOT -1/* Det OR Num OR A + Pos) (0 Diverso + MascPl) (1 Noun_Adj + MascPl) ;
SELECT Det IF (NOT -1/* Det OR Num OR A + Pos) (0 Diverso + FemPl) (1 Noun_Adj + FemPl) ; # diversi amici
SELECT A IF (-1/* Det OR Num OR A + Pos) (0 Diverso + MascPl) (1 Noun_Adj + MascPl) ;
SELECT A IF (-1/* Det OR Num OR A + Pos) (0 Diverso + FemPl) (1 Noun_Adj + FemPl) ; # due diversi amici
SELECT A IF (-1 Noun_Adj_PP + &&ConcordaGN) (0 Diverso + &&ConcordaGN) (1 Barrera_Final_Estrict_SN) ; # provider diversi
REMOVE Cog IF (0 ("<XI>")) ;
REMOVE Num IF (-1 Quot) (0 ("<I>")) (1 Noun_Adj + MascPl) ; # Nella serie televisiva statunitense "I misteri della laguna"
REMOVE Num IF (0 (META:/[-–—"“«]/r)) (0 ("<I>")) (1 Noun_Adj + MascPl) ; # Nella serie televisiva statunitense "I misteri della laguna"
REMOVE Num IF (-1 (META:/[-–—"“«]/r)) (0 ("<I>")) (1 Noun_Adj + MascPl) ; # Nella serie televisiva statunitense "I misteri della laguna"
#REMOVE Num IF (0 (META:/\"/r)) (0 ("<I>")) (1 Noun_Adj + MascPl) ; # Nella serie televisiva statunitense "I misteri della laguna"
#REMOVE Num IF (-1 (META:/\"/r)) (0 ("<I>")) (1 Noun_Adj + MascPl) ; # Nella serie televisiva statunitense "I misteri della laguna"
#SELECT Ant IF (-1C Ant) (0 Ant) (-1 (META:/-/r)) ;
#REMOVE Num IF (0 ("<I>")) (1 Noun_Adj + MascPl) ; # Nella serie televisiva statunitense "I misteri della laguna"
REMOVE Principio IF (0 Principe) (0 Principio) (-2 ("parco")) (-1 Di) ;
REMOVE Principio IF (0 Principe) (0 Principio) (1 Gentilizio) ;
REMOVE Principe IF (0 Principe) (0 Principio) (NOT 1 Di) (NOT -1 Di) ;
REMOVE Principe IF (0 Principe) (0 Principio) (1 Di) (NOT 2 Top OR unknownMajIni) ;
REMOVE Principio IF (0 Principe) (0 Principio) (1 Di) (2 Top LINK NOT 0 Cog) ;
SELECT Genere IF (0 Genere) (0 Genero) (NOT 1 Di) ;
SELECT Genere IF (0 Genere) (0 Genero) (1 Di) (NOT 2 Ant_Cog OR unknownMajIni) ;
SELECT Genero IF (0 Genere) (0 Genero) (1 Di) (2 Ant_Cog) ;
SELECT ("peso_valuta") IF (0 ("peso")) (1 ("argentino") OR ("boliviano") OR ("cileno") OR ("colombiano") OR ("cubano") OR ("dominicano") OR ("filippino") OR ("honduregno") OR ("messicano") OR ("uruguaiano")) ;
REMOVE ("peso_valuta") IF (0 ("peso")) ;
SELECT Colle IF (0 Colle) (0 Collo) ; # sette colli
SELECT N IF (0 Calibro) (-1 ("fucile") OR ("pistola") OR ("revolver")) ;
SELECT Bue IF (NOT -1 F OR Pl) (0 Bua) (NOT -1 F OR Pl) ;
SELECT A + &&ConcordaGN IF (0 Santo + &&ConcordaGN) (1 Ant + &&ConcordaGN) ;
SELECT A IF (0 Santo + Pl) (1 Ant) (2 CnjCoo) (3 Ant) ;
SELECT A IF (0 Santo) (1 unknownMajIni) ;
SELECT A IF (0 ("<Santo>")) (1 ("spirito") OR ("sepolcro")) ;
SELECT N IF (0 ("<Vergine>")) (-1/* Det + Fem) ;
SELECT N IF (0 ("<Vergine>")) (-1 A + Fem) ;
SELECT N IF (0 ("<Vergine>")) (1 ("Maria")) ;
SELECT NP IF (0 ("<Conti>")) (-1 Ant OR Cog) ;
SELECT NP IF (0 ("<Visconti>")) (-1 Ant OR Cog) ;
SELECT NP IF (-1 Det + Pl) (0 ("<Visconti>")) ;
SELECT Conte IF (0 Conte) (0 Conto) (1 Di) (2 Top OR unknownMajIni) ; # conti di Barcellona
SELECT Conto IF (0 Conte) (0 Conto) (NOT 1 Di) ;
SELECT Conto IF (0 Conte) (0 Conto) (1 Di) (NOT 2 Top OR unknownMajIni) ;
REMOVE NP IF (0 ("<Nato>")) (-1 BOS) ;
SELECT N IF (0 Partita + FemSg) (1 ("giocchare") + PP + FemSg) ;
SELECT N IF (0 Partita + FemSg) (1 ("vincere") + PP + FemSg) ;
SELECT N IF (0 Partita + FemSg) (1 ("perdere") + PP + FemSg) ;
SELECT N IF (0 Partita + FemPl) (1 ("giocchare") + PP + FemPl) ;
SELECT N IF (0 Partita + FemPl) (1 ("vincere") + PP + FemPl) ;
SELECT N IF (0 Partita + FemPl) (1 ("perdere") + PP + FemPl) ;
SELECT PP IF (-1 Partita + FemSg) (0 ("giocchare") + PP + FemSg) ;
SELECT PP IF (-1 Partita + FemSg) (0 ("vincere") + PP + FemSg) ;
SELECT PP IF (-1 Partita + FemSg) (0 ("perdere") + PP + FemSg) ;
SELECT PP IF (-1 Partita + FemPl) (0 ("giocchare") + PP + FemPl) ;
SELECT PP IF (-1 Partita + FemPl) (0 ("vincere") + PP + FemPl) ;
SELECT PP IF (-1 Partita + FemPl) (0 ("perdere") + PP + FemPl) ;
SELECT PP + &&ConcordaGN IF (-2C PP) (-2 PP + &&ConcordaGN) (-1 CnjCoo) (0 PP + &&ConcordaGN) ; # umiliati e offesi
SELECT PP + &&ConcordaGN IF (2C PP) (0 PP + &&ConcordaGN) (1 CnjCoo) (2 PP + &&ConcordaGN) ; # offesi e umiliati
SELECT N IF (0 Regia) (1 Di) ; # regia di
SELECT Adv IF (0 Ancora) (-1C Ser OR V) (1 Noun_Adj_PP) ;
SELECT Adv IF (0 Ancora) (-1C Ser OR V) (1 unknown) ;
SELECT Adv IF (0 Ancora) (NOT -1/* Det + FemSg) ;
REMOVE PreAdv IF (-1 N OR A) (0 Che) ;
SELECT Interr IF (-1 BOS) (0 Che OR Cosa OR Come OR Quale OR Quanto OR Dove) (1* ("<?>")) ;
SELECT Interr IF (-1 BOS) (0 Che) (1* ("<!>")) ;
SELECT Interr IF (0 Come OR Quale OR Quanto OR Dove) (1 V) (1* ("<?>")) ;
SELECT Interr + A IF (0 Quanto + &&ConcordaGN) (1 Noun_Adj + &&ConcordaGN) (2 V) (1* ("<?>")) ;
SELECT Interr + Pron IF (0 Quanto) (1 V) (1* ("<?>")) ;
SELECT V + Pers IF (-1 Come OR Quale OR Quanto + Pron OR Dove) (0 V + Pers) (1* ("?")) ;
SELECT Interr IF (0 Come OR Quale OR Quanto OR Dove) (1 Tn) (2 V) (1* ("?")) ;
SELECT Interr IF (0 Come OR Quale OR Quanto OR Dove) (1 Det) (2 N) (3 V) (1* ("?")) ;
SELECT Interr IF (0 Come OR Quale OR Quanto OR Dove) (1 Det) (2 Noun_Adj) (3 Noun_Adj) (4 V) (1* ("?")) ;
LIST V_Interr = "sapere" "chiedere" "dire" "spiegare" "domandare" ;
SELECT Interr IF (-1 V_Interr) (0 Cosa OR Perche OR Come OR Quale OR Quanto OR Dove) ;
SELECT Interr IF (-2 V_Interr) (-1 Adv) (0 Cosa OR Perche OR Come OR Quale OR Quanto OR Dove) ;
SELECT Interr IF (0 Cosa OR Perche OR Quale OR Quanto OR Dove) (1 Inf) ;
SELECT Interr IF (0 Cosa OR Perche OR Quale OR Quanto OR Dove) (1 Pro) (2 Inf) ;
SELECT Interr IF (0 Cosa OR Perche OR Quale OR Quanto OR Dove) (1 Pro) (2 Pro) (3 Inf) ;
SELECT Prep IF (0 Come OR Quale) (-1 Vall) (NOT -1 PP) ; # adottare como
SELECT Prep IF (0 Come OR Quale) (-2 Avere OR Ser OR Venire) (-1 PP) ; # avere/essere/venire adottato como
SELECT Prep IF (0 Come OR Quale) (-3 Avere OR Ser OR Venire) (-2 Adv) (-1 PP) ;
SELECT Prep IF (0 Come) (-1 Barrera_Inicial_Estrict_SN OR CM) ;
#REMOVE Prep IF (0 Come OR Quale) (NOT -1 PP) (NOT -2 PP) (NOT -3 PP) ;
SELECT Prep IF (0 ("<ne>"i)) (1C Det) ; # ne "Il pipistrello" ; ne "I predatori"
SELECT Prep IF (0 ("<ne>"i)) (1 Quot) (2C Det) ;
SELECT Prep IF (0 ("<ne>"i)) (1C ("<il>"i) OR ("<i>"i)) ;
SELECT Prep IF (0 ("<ne>"i)) (1 Quot) (2C ("<il>"i) OR ("<i>"i)) ;
REMOVE Prep IF (0 ("<ne>"i)) ;
SELECT ("in direzione") IF (0 ("in direzione")) (1 NP OR unknownMajIni) ;
REMOVE ("in direzione") IF (0 ("in direzione")) ;
REMOVE ("di mezzo") IF (0 ("di mezzo")) (1 N + MascSg) ;
REMOVE Prep IF (0 ("di mezzo")) ;
REMOVE ("di fianco") IF (0 ("di fianco")) (1 A + MascSg) ;
REMOVE Prep IF (0 ("di fianco")) ;
SELECT N IF (0 ("dato che")) (-1/* Det + MascSg) ;
REMOVE N IF (0 ("dato che")) ;
SELECT A IF (0 ("prima di")) (-1/* Det + FemSg) ;
REMOVE A IF (0 ("prima di")) ;
SELECT A IF (0 ("prima che")) (-1/* Det + FemSg) ;
REMOVE A IF (0 ("prima che")) ;
SELECT Prep IF (-1 ("<nel caso>"i)) (0 Di) ;
SELECT Prep IF (0 ("nel caso")) (1 Di) ;
REMOVE Prep IF (0 ("nel caso")) ;
SELECT ("d'estate") IF (NOT -1 N OR A) (0 ("d'estate")) ;
REMOVE ("d'estate") ;
SELECT ("d'inverno") IF (NOT -1 N OR A) (0 ("d'inverno")) ;
REMOVE ("d'inverno") ;
SELECT A IF (0 ("corrispondente")) (1 ("a")) (NOT 2 Top) (NOT 2 MajIni) ;
REMOVE Adv IF (0 Dopo) (1 Circa OR Oltre) ; # dopo circa 10 anni
SELECT Adv IF (-1 Dopo) (0 Circa) ; # dopo circa 10 anni
SELECT Prep IF (-1 Dopo) (0 Oltre) ; # dopo oltre 10 anni
SELECT Adv IF (0 Circa) (1 Num) ; # dopo circa 10 anni
SELECT Prep IF (0 Oltre) (1 Num) ; # dopo oltre 10 anni
REMOVE Prep IF (-1 Vall) (0 Circa) (1C Noun_Adj) ;
SELECT Prep IF (0 Verso) (1 Det + &&ConcordaGN) (2 Noun_Adj + &&ConcordaGN) ;
SELECT Prep IF (0 Verso) (1 Det + &&ConcordaGN) (2 Adv OR PreAdv) (3 A + &&ConcordaGN) ;
SELECT Prep IF (0 Verso) (1 A + Pl + &&ConcordaGN) (2 N + &&ConcordaGN) ;
SELECT Prep IF (0 Verso) (1 Adv OR PreAdv) (2 A + Pl + &&ConcordaGN) (3 N + &&ConcordaGN) ;
SELECT Al IF (0 Duce) (-1 Def + MascSg) ;
SELECT A IF (-1 Det + &&ConcordaGN) (0 Certo + &&ConcordaGN) (1 N + &&ConcordaGN) ; # un certo inquinamento
SELECT A IF (-1 N + &&ConcordaGN) (0 Certo + &&ConcordaGN) ; # una notizia certa riguardante
SELECT A + Vario IF (-1 Det + MascPl) (0 Vario + MascPl) (1 N + MascPl) ;
SELECT A + Vario IF (-1 Det + FemPl) (0 Vario + FemPl) (1 N + FemPl) ;
SELECT A IF (0 Principale) (-1 Def OR Pos) ; # il principale responsabile
REMOVE A IF (0 ("<Natale>")) ;
SELECT N IF (-1 ("per")) (0 ("<Natale>")) ;
SELECT N IF (-1 ("dopo")) (0 ("<Natale>")) ;
SELECT N IF (-2 ("vigilia")) (-1 Di) (0 ("<Natale>")) ;
SELECT N IF (-2 ("cena")) (-1 Di) (0 ("<Natale>")) ;
SELECT N IF (-2 ("regalo")) (-1 Di) (0 ("<Natale>")) ;
SELECT N IF (-2 ("albero")) (-1 Di) (0 ("<Natale>")) ;
SELECT N IF (-2 ("giorno")) (-1 Prep) (0 ("<Natale>")) ; # giorno di Natale ; giorno dopo Natale
SELECT N IF (0 ("<Natale>")) (1 Num) ; # Natale 2023
REMOVE N IF (0 Sette) (1 N + MascPl) ;
REMOVE N IF (0 Sette) (1 N + FemPl) ;
REMOVE N IF (0 Sette) (1 A + MascPl) (2 N + MascPl) ;
REMOVE N IF (0 Sette) (1 A + FemPl) (2 N + FemPl) ;
SELECT N IF (0 Cardinale) (1 Ant_Cog OR unknownMajIni) ;
REMOVE V IF (0 Ultimo + &&ConcordaGN) (-1 Def + &&ConcordaGN) ; # l'ultimo
REMOVE V IF (0 Ultimo + FemSg) (-1 Def + FemSg) ; # l'ultima
REMOVE V IF (0 Ultimo + MascPl) (-1 Def + MascPl) ;
REMOVE V IF (0 Mandato) (-1 Primo) ;
SELECT N IF (0 Serie) (1 A) ;
SELECT N IF (0 ("<dati>"i)) (1 Anno) ;
REMOVE A IF (0 Nato) (1 ("a")) ; # una russa nata a Mosca
SELECT Masc IF (NOT -1/* F OR N) (0 Fronte + Fem) (NOT 1 F) ;
SELECT Masc IF (NOT -1/* F OR N) (0 Fronte + Fem) (1 Prep) ;
SELECT Fem IF (NOT -1/* M) (0 ("biennale") + Masc) (NOT 1 M) ;
SELECT Latte + Sg IF (NOT -1/* Pl) (0 Latta + Pl) (NOT 1 Pl) ;
REMOVE Indire IF (0 Indicare) (0 Indire) ;
REMOVE Det IF (0 ("<gli>"i) ) (NOT 1 MascPl) (1 Vall) ; # gli corse
SELECT P1 + Sg IF (-1 Io) (0 Vall + P1 + Sg) ;
SELECT P2 + Sg IF (-1 Tu) (0 Vall + P2 + Sg) ;
SELECT Sg IF (0 ("<sono>"i)) (-1 Io) ; # io sono
SELECT Sg IF (0 ("<sono>"i)) (-2 Io) (-1 Adv OR Pron) ;
SELECT Sg IF (0 ("<sono>"i)) (1 Io) ; # sono io
SELECT Sg IF (0 ("<sono>"i)) (2 Io) (1 Adv OR Pron) ;
SELECT Sg IF (0 ("<sono>"i)) (-1 Loro) ; # loro sono
SELECT Sg IF (0 ("<sono>"i)) (-2 Loro) (-1 Adv OR Pron) ;
SELECT Sg IF (0 ("<sono>"i)) (1 Loro) ; # sono loro
SELECT Sg IF (0 ("<sono>"i)) (2 Loro) (1 Adv OR Pron) ;
#SELECT Sg IF (0 ("<sono>"i)) (-1C N + Sg OR A + Sg OR PP + Sg OR NP + Sg) ; # MA: I locali di vendita sono un luoco
#SELECT Sg IF (0 ("<sono>"i)) (-2C N + Sg OR A + Sg OR PP + Sg OR NP + Sg) (-1 Adv OR Pron) ;
#SELECT Pl IF (0 ("<sono>"i)) (-1C N + Pl OR A + Pl OR PP + Pl OR NP + Pl) ;
#SELECT Pl IF (0 ("<sono>"i)) (-2C N + Pl OR A + Pl OR PP + Pl OR NP + Pl) (-1 Adv OR Pron) ;
SELECT Sg IF (0 ("<sono>"i)) (1 Adv) (2 Adv_PreAdv) (3 A + Sg OR PP + Sg) ; # sono sempre molto povero
SELECT Pl IF (0 ("<sono>"i)) (1 Adv) (2 Adv_PreAdv) (3 A + Pl OR PP + Pl) ; # sono sempre molto poveri
SELECT Sg IF (0 ("<sono>"i)) (1 Adv_PreAdv) (2 A + Sg OR PP + Sg) ; # sono molto povero; sono sempre un bambino
SELECT Pl IF (0 ("<sono>"i)) (1 Adv_PreAdv) (2 A + Pl OR PP + Pl OR Det + Pl OR PreDet + Pl) ; # sono molto poveri; sono sempre dei bambini
SELECT Sg IF (0 ("<sono>"i)) (1 A + Sg OR PP + Sg) ; # sono povero; sono un bambino; sono tutta la famiglia; MA: sono un luogo importante
SELECT Pl IF (0 ("<sono>"i)) (1 A + Pl OR PP + Pl OR Det + Pl OR PreDet + Pl) ; # sono poveri; sono dei bambini; sono tutti i bambini
SELECT Pl IF (0 ("<sono>"i)) (1 Adv) (2 Num) (NOT 2 ("uno")) ;
SELECT Pl IF (0 ("<sono>"i)) (1 Num) (NOT 1 ("uno")) ;
SELECT Sg IF (0 ("<sono>"i)) (-1 BOS) (1 Det + Sg) (NOT 1 Pl) ; # Questo è problematico: Sono la chiave di..., Sono il simbolo di...
SELECT Pl IF (0 ("<sono>"i)) (-1 BOS) (1 Det + Pl) (NOT 1 Sg) ;
SELECT Sg IF (0 ("<sono>"i)) (-1 BOS) (1 N + Sg) (NOT 1 Pl) ;
SELECT Pl IF (0 ("<sono>"i)) (-1 BOS) (1 N + Pl) (NOT 1 Sg) ;
SELECT A IF (-1/* Det + &&ConcordaGN) (0 Primo + &&ConcordaGN) ; # li primo
SELECT A IF (-1 Prep) (0 Primo + &&ConcordaGN) (1 N + &&ConcordaGN) ; # per prima cosa
SELECT A IF (-1/* Det + &&ConcordaGN) (0 Aord + &&ConcordaGN) (1 N + &&ConcordaGN) ; # nell'ottavo centenario
SELECT A IF (-1 Prep) (0 Aord + &&ConcordaGN) (1 N + &&ConcordaGN) ;
SELECT PP IF (-1 Venire) (0 Noun_Adj_PP) ; # viene divisa
SELECT A IF (-1/* Det + MascSg) (0 Secondo + MascSg) (1 Noun_Adj_PP + MascSg) ;
SELECT A IF (0 Secondo) (1 Di) (2 Num) ; # Secondo dei dieci figli
SELECT A IF (-1 ("atto") + MascSg OR ("capitolo") + MascSg) (0 Secondo + MascSg) (NOT 1 Det) ;
REMOVE CnjAdv IF (-1/* Det + MascSg) (0 Secondo + MascSg) ;
REMOVE Prep IF (-1/* Det + MascSg) (0 Secondo + MascSg) ;
SELECT Prep IF (0 Secondo) (1 NP) ;
SELECT Prep IF (0 Secondo) (1 Det) (2 Noun_Adj) ;
#SELECT PP IF (0 Subito) (1 Da) ;
SELECT Adv IF (NOT -1 Avere) (NOT -1 Adv) (0 Subito) (NOT 1 Da) ;
SELECT Adv IF (-2 Avere) (NOT -1 Adv) (0 Subito) (NOT 1 Da) ;
SELECT A IF (-1 N + &&ConcordaGN) (0 Stesso + &&ConcordaGN) ; # i umanisti stessi
SELECT N IF (0 Turbo) (-1 ("motoro") OR NP OR unknownMajIni) ;
REMOVE N IF (0 Ora) (0 Adv) (NOT -1/* Det + MascSg) (1C PP) ; # ora conservato
SELECT N IF (0 ("attacco")) (1 ("hacker")) ;
REMOVE N IF (NOT 1/* Det + Def + MascSg) (0 ("oltremare") OR ("oltreoceano")) ;
SELECT CnjAdv IF (0 Qualunque) (1 Prs OR Pis) ;
REMOVE CnjAdv IF (0 Qualunque) (NOT 1 Prs OR Pis) ;
SELECT Acr IF (0 ("ROM")) ;
SELECT Num IF (-1 MajIni2) (0 ("<I>")) ; # Armanda I
SELECT Num IF (-1 unknownMajIni2) (0 ("<I>")) ; # Armandax I
REMOVE CnjAdv IF (-1 BOS) (0 Interr) (0 CnjAdv) (1* ("?"));
#SELECT Interr IF (0 Interr) (0 CnjAdv) (-1 Vinterr) ; # problema: il Principe Taik fu chiesto come pagamento
#SELECT Interr IF (0 Interr) (0 CnjAdv) (1C Vall) ; # de moment comento aquesta regla que provoca molts canvis
REMOVE Interr IF (-1/* Det) (0 Interr) (0 Rel) ; # nella quale
REMOVE Interr IF (NOT -1 Vall OR Adv) (0 Interr) (0 CnjAdv) ; # ha ricevuto una certa notorietà da quando
REMOVE Interr IF (NOT -2 Vall) (-1 Adv) (0 Interr) (0 CnjAdv) ;
REMOVE Interr IF (-1 N + &&ConcordaGN) (0 Interr) (0 Rel + &&ConcordaGN) ; # figure quali l’eufemismo
REMOVE Interr IF (-2 N + &&ConcordaGN) (-1 A + &&ConcordaGN) (0 Interr) (0 Rel + &&ConcordaGN) ; # figure retoriche quali l’eufemismo
SELECT Rel IF (-1C N OR A OR NP) (0 Che OR Chi) ; # l'uomo che dice
SELECT Rel IF (-2 N OR A OR NP) (-1 CM) (0 Che OR Chi) ; # l'uomo, che dice
SELECT Rel IF (-1/* Det + Def) (0 Che OR Chi) ;
SELECT Rel IF (-1/* Det + Dem) (0 Che OR Chi) ;
SELECT Rel IF (-1 ("ciò") OR ("tutto ciò")) (0 Che) ;
SELECT Rel IF (-1 unknown) (0 Che OR Chi) ;
SELECT Rel IF (-2 unknown) (-1 CM) (0 Che OR Chi) ;
SELECT Interr IF (-1 BOS) (0 Che OR Chi) (1* ("?")) ;
SELECT Interr IF (-2 BOS) (-1 Prep) (0 Che OR Chi) (1* ("?")) ;
SELECT Interr IF (-1 ("sapere") OR ("domandare") OR ("chiedere") OR ("spiegare")) (0 Chi) ;
SELECT Interr IF (-2 ("sapere") OR ("domandare") OR ("chiedere") OR ("spiegare")) (-1 Adv) (0 Chi) ;
SELECT Interr IF (-1 ("domandare") OR ("chiedere")) (0 Che) ;
SELECT Interr IF (-2 ("domandare") OR ("chiedere")) (-1 Adv) (0 Che) ;
REMOVE Interr IF (0 Che OR Chi) ;
REMOVE A IF (0 Che) (NOT 1 N) ;
REMOVE Prep IF (-1 Vall) (0 Prep) (0 Adv) (1 Ger) ; # si chiamò fuori dando vita
SELECT Aord IF (-1 Det + Def + &&ConcordaGN) (0 Aord + &&ConcordaGN) (1 N + &&ConcordaGN) ; # il quinto piano
SELECT A + Pos IF (-1 Det + Def + &&ConcordaGN) (0 A + Pos + &&ConcordaGN) (1 Aord + &&ConcordaGN) ; # il suo secondo libro, il suo terzo libro
SELECT Aord IF (-2 Det + Def + &&ConcordaGN) (-1 A + Pos + &&ConcordaGN) (0 Aord + &&ConcordaGN) (1 N + &&ConcordaGN) ; # il suo secondo libro, il suo terzo libro
SELECT Aord IF (-1 Det + Def + MascSg) (0 Aord + MascSg) (1 Vall + P3 + Sg) ; # il terzo è...
REMOVE N IF (-1C Vall + Sg) (0 Aord + Sg) ; # arrivarò sesto
REMOVE N IF (-1C Vall + Pl) (0 Aord + Pl) ; # arrivarono sesti
REMOVE N IF (-1 Vall) (-1/* Enc) (0 Aord) ; # classificandosi terzo
SELECT PreAdv OR Adv IF (0 Molto) (1C A OR PP) ; # molto affettuoso
SELECT PreAdv IF (0 ("<molto>")) (1 A + Sg) ; # molto malalta
SELECT PreAdv IF (0 ("<molto>")) (1 A + Pl) ;
SELECT Det + &&ConcordaGN OR A + &&ConcordaGN IF (0 Molto + &&ConcordaGN) (1C N + &&ConcordaGN) ;
REMOVE Pron IF (0 Molto + &&ConcordaGN) (1 Noun_Adj_PP + &&ConcordaGN) ; # molti danni
SELECT PreAdv IF (-1 VCop + &&ConcordaSP) (0 Abbastanza) (1 Adj_PP + &&ConcordaSP) ; # è abbastanza noto
SELECT Adv IF (-1 VCop + &&ConcordaSP) (0 Abbastanza) (1 Adj_PP + &&ConcordaSP) ;
SELECT Det + &&ConcordaGN IF (0/* Det + &&ConcordaGN) (0/* Pron) (1 N + &&ConcordaGN) (NOT 0 ("un altro")) (NOT 0 Loro) (NOT 0 ("molto")) (NOT 1 ("un altro") OR Vall) ;
SELECT Det IF (0/* Det) (0/* Pron) (1 N) (2 A) (NOT 0 ("un altro")) (NOT 0 Loro) (NOT 0 ("molto")) (NOT 1 ("un altro")) ; # problema: le altre pinne grigie
SELECT Det IF (0/* Det) (0/* Pron) (1 A) (2 N) (NOT 0 ("un altro")) (NOT 0 Loro) (NOT 0 ("molto")) (NOT 1 ("un altro")) ; # problema: le altre pinne grigie
SELECT A + &&ConcordaGN IF (0 A + Pos + &&ConcordaGN) (0 Pron) (1 Adj_PP + &&ConcordaGN) (2 N + &&ConcordaGN) ;
SELECT A + &&ConcordaGN IF (0 A + Pos + &&ConcordaGN) (0 Pron) (1 Num) (2 N + &&ConcordaGN) ; # le sue tre manifestazioni ; i sui 3 metri
SELECT A + &&ConcordaGN IF (0 A + Pos + &&ConcordaGN) (0 Pron) (1 Num) (2 Adj_PP + &&ConcordaGN) (3 N + &&ConcordaGN) ; # le sue due grandi passioni
SELECT PreAdv IF (-1 N + &&ConcordaGN) (0 PreAdv) (1 A + &&ConcordaGN) ;
REMOVE PreAdv IF (0 Adv) (0 PreAdv) (NOT 1 A OR PP OR Adv) ; # tutelando così la credibilità
REMOVE PreAdv IF (0 Adv) (0 PreAdv) (1 Come) ; # proprio come me
SELECT PreAdv IF (0 Molto) (1C A OR PP OR Adv) ; # era molto complessa, e molto corrotta
SELECT A OR Adv OR PP IF (-1C PreAdv) ;
REMOVE CnjAdv IF (0 Adv) (0 CnjAdv) (NOT 0 Interr) (NOT 1* Vall + Pers) ; # tutelando così la credibilità / ha ricevuto una certa notorietà da quando
REMOVE CnjAdv IF (0 ("visto che")) (-1 Avere) ; # ha visto che
REMOVE CnjAdv IF (0 ("visto che")) (-2 Avere) (-1 Adv) ; # ha visto che
SELECT CnjAdv IF (0 ("visto che")) (NOT -2 Avere) (NOT -1 Avere) ; # ha visto che
REMOVE CnjAdv IF (0 ("considerato che")) (-1 Avere) ; # ha considerato che
REMOVE CnjAdv IF (0 ("considerato che")) (-2 Avere) (-1 Adv) ; # ha visto che
SELECT CnjAdv IF (0 ("considerato che")) (NOT -2 Avere) (NOT -1 Avere) ; # ha visto che
REMOVE PP IF (-1 V LINK NOT 0 PP) (0 PP) (0 Adv) ; # denominò subito il territorio
REMOVE PP IF (-1C Tn OR Pro OR Det LINK NOT 0 Dem) (-1 Pron) (0 Vall + Pers) ; # Chi me la porta? / Quelle ligate a
REMOVE PP IF (0 Vall + Pers) (-1 BOS OR CnjSub OR CnjAdv OR Rel) (NOT 0 Dare) ; # porto loro
REMOVE PP IF (0 Vall + Pers) (-1 Adv) (-2 BOS OR CnjSub OR CnjAdv OR Rel) (NOT 0 Dare) ;
REMOVE PP IF (0 Vall + Pers) (-1 CM) (-2 Adv OR Interj) (-3 BOS OR CnjSub OR CnjAdv OR Rel) (NOT 0 Dare) ;
REMOVE PP IF (0 Vall + Pers) (-1 CM) (-2 Adv OR Interj) (-3 CM) (-4 CnjSub OR CnjAdv OR Rel) (NOT 0 Dare) ;
SELECT Det IF (0 Det) (0 Pron) (1 unknown) ;
SELECT Det IF (-1 BOS) (0 ("I")) (NOT 1 EOS) ; # .I movimentos
SELECT Num IF (NOT -1 BOS) (0 ("I")) (1C N + Sg OR A + Sg) ; # del secolo I a.C.
SELECT N IF (0 Secoli) (-1/* Det + Def + MascSg) ;
SELECT Det IF (NOT -1 Ant) (0 ("I")) (1 Cog) ; # I Jefferson
REMOVE N IF (0 ("<V>")) (-1 Ant) (NOT 1 Cog OR Ant) ; # Petro I
REMOVE N IF (0 ("<V>")) (-1 unknownMajIni) ; # Strannocz I
SELECT N IF (0 ("<V>")) (-1 Num) ; # 220 V
REMOVE A IF (0 ("accado")) (NOT -1 N) ;
REMOVE N IF (0 ("accado") + Sg) ;
REMOVE N IF (0 ("accado") + Fem) ;
SELECT Noun_Adj + Masc IF (-1/1 Det + M) (0C Noun_Adj) ;
SELECT Noun_Adj + Fem IF (-1/1 Det + F) (0C Noun_Adj) ;
SELECT Noun_Adj + SgSp IF (-1/1 Det + Sg) (0C Noun_Adj) ; # della serie TV
SELECT Noun_Adj + PlSp IF (-1/1 Det + Pl) (0C Noun_Adj) ;
SELECT Det + Ind IF (-1 ("come")) (0 Det + Ind + Pl) (1C Noun_Adj + Pl) ; # come dei intrepidi viaggiatori
SELECT Det + Ind IF (-1 Prep) (0 Det + Ind + Pl) (1C Noun_Adj + Pl) ; # a dei intrepidi viaggiatori
SELECT SUB:1 Det IF (0/1 Det + M) (1C Noun_Adj) ;
SELECT SUB:1 Det IF (0/1 Det + F) (1C Noun_Adj) ;
SELECT SUB:1 Det IF (0/1 Det + Sg) (1C Noun_Adj) ; # della serie TV
SELECT SUB:1 Det IF (0/1 Det + Pl) (1C Noun_Adj) ;
SELECT A + &&ConcordaGN IF (NOT -1 N) (0 AdjPre + &&ConcordaGN) (1 N + &&ConcordaGN) (2C A OR Barrera_Final_Estrict_SN) ; # i principali parchi
SELECT N + &&ConcordaGN IF (-1C Prep) (0 N + &&ConcordaGN LINK NOT 0 MajIni) (1 A + &&ConcordaGN) (2C A OR Barrera_Final_Estrict_SN) ; # dei musulmani ribelli del distretto
SELECT N + &&ConcordaGN IF (-1/1 Det + &&ConcordaGN) (0 N + &&ConcordaGN LINK NOT 0 MajIni) (1 A + &&ConcordaGN) (2C A OR Barrera_Final_Estrict_SN) ; # dei musulmani ribelli del distretto
SELECT N IF (0 N) (0 V) (NOT 0 PP) (-1C A) (1 Prep) ; # le più grandi collezioni di pesci
SELECT N IF (0 N) (0 V) (NOT 0 PP) (-1 A) (1 Prep) ; # genere teatrale e musicale nato nel 1856
SELECT N IF (0 N) (0 A) (-1 Def) (1 ("più")) ; # il comune più estesso
SELECT V IF (0 N) (0 V) (NOT -2/* Det) (-1 Rel) (NOT -1 ("il cui") OR ("come")) ; # il paese in cui abito / la donna il cui figlio / dal cui inizio
SELECT N IF (0 N + &&ConcordaGN) (0 V) (-1 ("il cui") + &&ConcordaGN) (1 V) ; # il cui suoni ricordanno
SELECT Sg If (-1 ("il cui") + Sg) (0 V) (NOT 0 N) ;
SELECT Pl If (-1 ("il cui") + Pl) (0 V) (NOT 0 N) ;
SELECT Noun_Adj + &&ConcordaGN If (-1 ("il cui") + &&ConcordaGN) (NOT 0 V) ; # il cui capitale
SELECT Noun_Adj + &&ConcordaGN If (-1 ("il cui") + &&ConcordaGN) (1C Vall) ; # il cui capitale è
SELECT N + &&ConcordaGN If (-1 ("il cui") + &&ConcordaGN) (1C Vall) ; # il cui capitale è
SELECT Noun_Adj + &&ConcordaGN If (-1 ("il cui") + &&ConcordaGN) (1 Noun_Adj + &&ConcordaGN) (2C Vall) ;
REMOVE Prep IF (0 Adv) (0 Prep) (-1 V) (1 CnjCoo) ; # andavano su e giù
SELECT N IF (NOT -1 N) (0 ("amico")) (1 Ant_Cog OR unknownMajIni) ; # al suo amico Monty
SELECT M IF (NOT -1 M OR F) (0C N) (1 Ant + M) ;
SELECT F IF (NOT -1 M OR F) (0C N) (1 Ant + F) ;
SELECT M IF (NOT -1 M OR F) (0C N) (1 A + MF) (2 Ant + M) ;
SELECT F IF (NOT -1 M OR F) (0C N) (1 A + MF) (2 Ant + F) ;
SELECT M IF (NOT -1 M OR F) (0C N) (1 CM OR Lpar) (2 Ant + M) ;
SELECT F IF (NOT -1 M OR F) (0C N) (1 CM OR Lpar) (2 Ant + F) ;
SELECT M IF (-2 Ant + M) (-1 CM OR Lpar) (0C N) (NOT 1 M OR F) ;
SELECT F IF (-2 Ant + F) (-1 CM OR Lpar) (0C N) (NOT 1 M OR F) ;
SELECT M IF (-3 Ant + M) (-2 Ant OR Cog) (-1 CM OR Lpar) (0C N) (NOT 1 M OR F) ;
SELECT F IF (-3 Ant + F) (-2 Ant OR Cog) (-1 CM OR Lpar) (0C N) (NOT 1 M OR F) ;
# Partitivo
#SELECT Un IF (-1 Ser + PP + MascPl) (0 Un + MascPl) (1 N + MascPl) ;
#SELECT Un IF (-1 Ser + PP + FemPl) (0 Un + FemPl) (1 N + FemPl) ;
#SELECT Un IF (-1 Ser + Pl) (NOT -1 Ser + PP) (0 Un + MascPl) (1 N + MascPl) ;
#SELECT Un IF (-1 Ser + Pl) (NOT -1 Ser + PP) (0 Un + FemPl) (1 N + FemPl) ;
SELECT N IF (-1 ("pieno")) (0 Sole) ;
SELECT Adv IF (0 Solo + MascSg) (1 Da) ; # 5 milioni e mezzo di euro solo dal video
SELECT N IF (0 ("<Stato>")) (NOT -1 BOS) ;
SELECT N IF (0 Stato) (-1 Det OR Aord OR Pos OR AdjN) ;
# NP
REMOVE NP IF (0 ("Arcangelo")) (1 ("Michele") OR ("Gabriele")) ;
REMOVE NP IF (-1/* Det + MascSg) (0 ("Corsaro")) ;
REMOVE NP IF (0 ("<Corsaro>")) (1 ("<Nero>")) ;
REMOVE NP IF (-2 Ant) (-1 Det + Def + Sg + &&ConcordaGN) (0 Noun_Adj + &&ConcordaGN) ; # Ludovico il Pio
REMOVE NP IF (-1/* Det + MascPl) (0 ("Nativi")) ;
REMOVE NP IF (0 ("<Grande>")) (1 N + MascSg) ; # Grande Maestro
REMOVE NP IF (-1 ("<Grande>")) (0 ("<Maestro>")) ;
SELECT NP IF (0 NP) (NOT -1 BOS) (NOT 0 ("Lei") OR ("Loro") OR ("Mia") OR ("Sole") OR ("Gran") OR ("Grande") OR ("Alta") OR ("Basso") OR ("Bassa") OR ("Bassi") OR ("Guerra") OR ("Marina") OR ("Regina") OR ("Beni") OR ("Castello") OR ("Castelli") OR ("Lago") OR ("Val") OR ("Monte") OR ("Monti") OR ("Casa") OR ("Valle") OR ("Villa") OR ("Consiglio") OR ("Tesoro") OR ("Verde") OR ("Verdi") OR ("Vecchio") OR ("Chiesa") OR ("Croce") OR ("Rosario") OR ("Santo") OR ("Santa") OR ("Santi") OR ("Sante") OR ("Immacolata") OR ("Cantone") OR ("Bandiera") OR ("Campo") OR ("Evangelista") OR ("Evangelisti") OR ("Signore") OR ("Signori") OR ("Re") OR ("Zarina") OR ("Delfino") OR ("Duca") OR ("Marchesi") OR ("Conte") OR ("Contessa") OR ("Conti") OR ("Visconti") OR ("Barone") OR ("Baroni") OR ("Principe") OR ("Governatori") OR ("Giardini") OR ("Palazzo") OR ("Palazzi") OR ("Primo") OR ("Prima") OR ("Bello") OR ("Bella") OR ("Belli") OR ("Belle") OR ("Costa") OR ("Golfo") OR ("Terzo") OR ("Terza") OR ("Terzi") OR ("Usa") OR ("USA") OR ("Salvatore") OR ("Via") OR ("Capo") OR ("Terra") OR ("Natale")) (NOT 0 Gentilizio) ;
# Llevem paraules que, per una raó o altra, es posen en majúscules sense ser NP
SELECT NP IF (0 ("Val")) (0 (META:/-/r)) ;
SELECT NP IF (0 ("Val")) (1 ("-")) ;
REMOVE NP IF (0 ("Prima")) (-1 BOS) ;
REMOVE NP IF (-1 Det + Def) (0 ("Salvatore")) ;
SELECT NP IF (0 ("Salvatore")) ;
REMOVE NP IF (NOT -1 Ant) (0 ("Via")) (NOT 0 (META:/-/r)) (1 MajIni OR unknownMajIni) ;
SELECT N IF (NOT -1 Ant) (0 ("via")) (NOT 0 (META:/-/r)) (1 MajIni OR unknownMajIni) ;
SELECT N IF (NOT -1 Ant) (0 ("via")) (1 Di) (2 MajIni OR unknownMajIni) ;
SELECT N IF (NOT -1 Ant) (0 ("via")) (1 Di) (2 Det) (3 MajIni OR unknownMajIni) ;
REMOVE NP IF (0 ("Signore") OR ("Signori") OR ("Delfino") OR ("Duca") OR ("Conte") OR ("Contessa") OR ("Conti") OR ("Barone") OR ("Baroni") OR ("Principe")) (1 Ant OR unknownMajIni) ;
SELECT Ant IF (-1 ("duca") OR ("marchese") OR ("conte") OR ("barone") OR ("principe") OR ("re") OR ("tsar") OR ("papa")) (0 Ant) ;
SELECT Ant OR Cog IF (-1 ("signore")) (0 Ant OR Cog) ;
REMOVE NP IF (0 ("Sacco")) (1 Di) (2 MajIni OR unknownMajIni) ;
REMOVE NP IF (-1/* Det + MascSg) (0 Noun_Adj + MascSg) ;
REMOVE NP IF (-1/* Det + MascPl OR ("<dai>") OR ("<dei>")) (0 Noun_Adj + MascPl) (NOT 0 ("USA") OR ("Usa_min")) ;
REMOVE NP IF (-1/* Det + FemSg) (0 Noun_Adj + FemSg) ;
REMOVE NP IF (-1/* Det + FemPl) (0 Noun_Adj + FemPl) ;
REMOVE NP IF (0 ("Signore") OR ("Signori") OR ("Duca") OR ("Duca") OR ("Marchesi") OR ("Conte") OR ("Contessa") OR ("Conti") OR ("Barone") OR ("Baroni") OR ("Principe")) (1 Di) (2 Top OR ("San") OR unknownMajIni) ;
REMOVE NP IF (0 ("Principe")) (1 ("elettore")) ;
SELECT Sg IF (0 ("signore") OR ("marchese")) (1 Ant OR unknownMajIni) (NOT 1 Ant + Fem) (NOT -1/* Pl) ;
SELECT Sg IF (0 ("signore") OR ("marchese")) (1 Di) (2 Top OR ("San") OR unknownMajIni) (NOT -1/* Pl) ;
REMOVE NP IF (0 ("Capo")) (1 ("di")) ;
REMOVE NP IF (-2 Ant) (-1 Det + Def + MascSg) (0 NP) (0 Noun_Adj + MascSg) ; # Plinio il Vecchio
REMOVE NP IF (-2 Ant) (-1 Det + Def + FemSg) (0 NP) (0 Noun_Adj + FemSg) ; # Caterina la Grande
SELECT A IF (-1 Noun_Adj) (0 ("<USA>")) ; # le sale cinematografiche USA
SELECT N IF (-1/* Det + Def + MascSg) (0 ("<Sole>")) ; # il Sole
SELECT N IF (-1/* Det + Def + MascSg) (0 ("<Castello>")) ; # il Castello
SELECT N IF (-1/* Det + Def + MascPl) (0 ("<Castelli>")) ; # i Castelli
SELECT N IF (-1/* Det + Def + MascSg) (0 ("<Consiglio>")) ; # il Consiglio
SELECT N IF (-1/* Det + Def + MascSg) (0 ("<Tesoro>")) ; # il Tesoro
SELECT N IF (-1/* Det + Def + MascSg) (0 ("<Cantone>")) ; # il Cantone
SELECT N IF (-1/* Det + Def + FemSg) (0 ("<Guerra>")) ; # la Guerra (Mundial, d'Independència, etc.)
SELECT N IF (-2/* Det + Def + FemSg) (-1 A + FemSg) (0 ("<Guerra>")) ; # la Gran Guerra
SELECT N IF (-1/* Det + Def + FemSg) (0 ("<Regina>")) ; # la Regina Maria Carolina
SELECT N IF (-2/* Det + Def + FemSg) (-1 A + FemSg) (0 ("<Regina>")) ;
SELECT N IF (-1/* Det + Def + FemSg) (0 ("<Chiesa>")) ; # la Chiesa
SELECT N IF (-1/* Det + Def + FemSg) (0 ("<Bandiera>")) ; # la Bandiera
SELECT N IF (-1/* Det + MascSg) (0 ("<Evangelista>")) ; # un Evangelista
SELECT N IF (-1/* Det + MascPl OR Num) (0 ("<Evangelisti>")) ; # i Evangelisti
SELECT N IF (-1/* Det + &&ConcordaGN) (0 NP) (0 N + &&ConcordaGN) (1C A + &&ConcordaGN) ;
SELECT N IF (-1/* Det + MascPl) (0 NP) (0 N + MascPl) (1C A + MascPl) ;
SELECT N IF (-1/* Det + FemSg) (0 NP) (0 N + FemSg) (1C A + FemSg) ;
SELECT N IF (-1/* Det + FemPl) (0 NP) (0 N + FemPl) (1C A + FemPl) ;
REMOVE Cog IF (-1 BOS) (0 ("<Dati>")) ;
REMOVE Cog IF (NOT -1 Ant) (0 ("<Palazzo>")) ;
REMOVE Cog IF (NOT -1 Ant) (0 ("<Antonino>")) ;
REMOVE Cog IF (0 ("<Costa>")) (1 A + FemSg) ;
REMOVE Cog IF (0 ("Roma")) (NOT -1 Ant OR Cog) ;
SELECT Al IF (-1/* Det + FemSg) (0 ("<Madonna>")) ;
SELECT Al IF (0 ("<Madonna>")) (1 Di) ;
REMOVE Al IF (0 ("<Madonna>")) ;
SELECT NP IF (0 Top) (0 N OR A) (NOT -1C (ant) OR (cog));
REMOVE Cog IF (-1 In OR Da) (0 Top) (0 Cog) ;
REMOVE Ant IF (-1 In OR Da) (0 Top) (0 Ant) ;
SELECT Top IF (-1 ("regione") OR ("distretto")) (0 Top) ;
SELECT Top IF (-2 ("regione") OR ("distretto") OR ("città")) (-1 Di) (0 Top) ;
SELECT NP IF (0 N OR NP) (2 NP) (1 Guio) ; # Pierre-Michel
SELECT Ant IF (0 Ant) (2C Ant) (1 Guio) ; # Jean-René
SELECT Ant IF (-2C Ant) (0 Ant) (-1 Guio) ;
SELECT Cog IF (0 Cog) (2C Cog) (1 Guio) ;
SELECT Cog IF (-2C Cog) (0 Cog) (-1 Guio) ;
SELECT Top IF (0 Top) (2C Top) (1 Guio) ;
SELECT Top IF (-2C Top) (0 Top) (-1 Guio) ;
SELECT Top IF (NOT -3 Ant OR Cog) (-2 Top) (0 Top) (-1 Guio) ; # Milano-Napoli
SELECT Top IF (NOT -1 Ant OR Cog) (0 Top) (2 Top) (1 Guio) ; # Milano-Napoli
SELECT NP IF (0 N OR NP) (1 NP) (0 (META:/-/r)) ; # Pierre-Michel
SELECT Ant IF (0 Ant) (1C Ant) (0 (META:/-/r)) ; # Jean-René
SELECT Ant IF (-1C Ant) (0 Ant) (-1 (META:/-/r)) ;
SELECT Cog IF (0 Cog) (1C Cog) (0 (META:/-/r)) ;
SELECT Cog IF (-1C Cog) (0 Cog) (-1 (META:/-/r)) ;
SELECT Top IF (0 Top) (1C Top) (0 (META:/-/r)) ;
SELECT Top IF (-1C Top) (0 Top) (-1 (META:/-/r)) ;
SELECT Top IF (NOT -2 Ant OR Cog) (-1 Top) (0 Top) (-1 (META:/-/r)) ; # Milano-Napoli
SELECT Top IF (NOT -1 Ant OR Cog) (0 Top) (1 Top) (0 (META:/-/r)) ; # Milano-Napoli
SELECT Ant IF (0 Ant) (1C Ant) ; # Rosa Maria
SELECT Ant IF (0 Ant) (1 Cog) (NOT -1 Ant) ; # Giordano Bruno
SELECT Ant IF (-1 ("santo")) (0 Ant) (0 Cog OR Top) ;
SELECT Ant IF (-1 ("San")) (0 Ant) (0 Cog OR Top) ; # San Paolo
SELECT Cog IF (0 Cog OR Ant) (-1C Ant) (NOT 1 segles_num_romans) (NOT 1 Cog) (NOT 1 Di);
SELECT Ant_Cog IF (0 Cog OR Ant) (1C Cog) (NOT 0 ("Lago") OR ("Val") OR ("Monte") OR ("Monti") OR ("Torre")) ;
SELECT Ant_Cog IF (0 Cog OR Ant) (1 unknownMajIni) (NOT 0 ("Lago") OR ("Val") OR ("Monte") OR ("Monti") OR ("Torre")) ;
SELECT Ant_Cog IF (-1 unknownMajIni) (0 Cog OR Ant) ;
SELECT Ant IF (0 Ant) (0 Cog) (1 Di) (2 Top OR unknownMajIni) ; # Alfonso di Portogallo
SELECT Top IF (-2 Ant) (-1 Di) (0 Ant OR Cog OR Top) ; # Ipparco di Nicea
SELECT Top IF (-3 Ant) (-2 segles_num_romans) (-1 Di) (0 Ant OR Cog OR Top) ; # Joan II di Castiglia
SELECT Top IF (-2 ("concilio") OR ("parlamento") OR ("statuto") OR ("costituzione") OR ("trattato") OR ("dichiarazione"))
(-1 Di) (0 Ant OR Cog OR Top) ;
# concilio di Nicea
SELECT Top IF (-2 ("corona") OR ("regno") OR ("giudicato") OR ("contea") OR ("ducato") OR ("despotado")) (-1 Di) (0 Cog OR Top) ; # regno di Castiglia
SELECT Top IF (-2 Dignità) (-1 Di) (0 Ant OR Cog) ; # principe di Viana
SELECT Top IF (-2 ("città") OR ("aeroporto") OR ("porto") OR ("regno") OR ("giudicato") OR ("principato") OR ("granducato") OR ("ducato") OR ("marchesato") OR ("contea") OR ("baronia") OR ("signoria") OR ("califfato") OR ("emirato") OR ("sultanato") OR ("khanato") OR ("satrapia") OR ("repubblica") OR ("arcivescovado") OR ("vescovado")) (-1 Di) (0 Cog OR Ant) ;