build.gradle

/*
 * Copyright (c) 2020, WSO2 Inc. (http://www.wso2.org) All Rights Reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
*/

plugins {
    id 'base'
    id 'maven-publish'
    id 'net.researchgate.release' version '2.8.0'
    id 'de.undercouch.download' version '5.4.0'
    id "com.github.johnrengelman.shadow" version "8.1.1"
    id "com.github.spotbugs" version "5.0.14"
}

description = 'Ballerina - Tools - Parent'

ext {
    ballerinaLangVersion = project.ballerinaLangVersion
    shortVersion = project.version.split("-")[0]
    c2cVersion = project.c2cVersion
    ballerinaJreVersion = project.ballerinaJreVersion
    ballerinaCommandVersion = project.ballerinaCommandVersion

    picocliVersion = "4.0.1"
    testngVersion = "7.6.1"
    netLingalaZip4jVersion = "2.8.0"
    commonsIoVersion = "2.6"
    commonsLang3Version = "3.9"
    lsp4jDebugVersion = "0.7.1"
    puppycrawlCheckstyleVersion = "10.12.1"
}

allprojects {
    apply plugin: 'maven-publish'

    group = project.group
    version = project.version

    repositories {
        mavenCentral()
    }

    release {
        // Workaround to fix build task not found issue in release plugin
        buildTasks = []
        failOnSnapshotDependencies = true
        failOnCommitNeeded = false
        versionPropertyFile = 'gradle.properties'
        tagTemplate = 'v${System.env.GIT_TAG}'
        git {
            // To release from any branch
            requireBranch = ''
        }
    }

    afterReleaseBuild.dependsOn publishToMavenLocal
    afterReleaseBuild.dependsOn publish
}

subprojects {
    apply plugin: 'java'
    sourceCompatibility = 17
    targetCompatibility = 17
    tasks.withType(JavaCompile) {
        options.encoding = 'UTF-8'
    }

    buildscript {
        repositories {
            /* Central Repository */
            maven { url "https://repo.maven.apache.org/maven2" }
            /* CWSO2 Releases Repository */
            maven { url "http://maven.wso2.org/nexus/content/repositories/releases/" }
            /* WSO2 Snapshot Repository */
            maven { url "http://maven.wso2.org/nexus/content/repositories/snapshots/" }
            /* WSO2 internal Repository */
            maven { url "http://maven.wso2.org/nexus/content/groups/wso2-public/" }

        }
    }

    repositories {
        /* local maven repository */
        mavenLocal()
        /* Central Repository */
        maven { url "https://repo.maven.apache.org/maven2" }
        /* WSO2 Releases Repository */
        maven { url "https://maven.wso2.org/nexus/content/repositories/releases/" }
        /* WSO2 internal Repository */
        maven { url "https://maven.wso2.org/nexus/content/groups/wso2-public/" }
        /* Github Package Repository */
        maven {
            url 'https://maven.pkg.github.com/ballerina-platform/*'
            credentials {
                username System.getenv('packageUser')
                password System.getenv('packagePAT')
            }
        }

    }

    configurations {
        jbalTools
        awsLambdaBala
        awsLambdaExamples
        azFunctionsBala
        azFunctionsExamples
        kubernetesAnnotations
        kubernetesExamples
        ballerinaStdLibs
        ballerinaC2cLibs
        ballerinaC2cTooling
        ballerinaOpenAPILibs
        exten {
            transitive = false
        }
        devTools
        externalTestJars
    }

    dependencies {
        jbalTools "org.ballerinalang:jballerina-tools:${ballerinaLangVersion}@zip"

        /* Ballerina Dev Tools */
        devTools "org.ballerinalang:ballerina-dev-tools:${devToolsVersion}"

        externalTestJars (group: 'mysql', name: 'mysql-connector-java', version: "8.0.21") {
            transitive = false
        }

        /* Standard libraries */
        ballerinaStdLibs "io.ballerina.lib:data.yaml-ballerina:${stdlibDataYamlVersion}"
        ballerinaStdLibs "io.ballerina.lib:data.jsondata-ballerina:${stdlibDataJsondataVersion}"
        ballerinaStdLibs "io.ballerina.lib:data.xmldata-ballerina:${stdlibDataXmldataVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:constraint-ballerina:${stdlibConstraintVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:io-ballerina:${stdlibIoVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:jballerina.java.arrays-ballerina:${stdlibJavaArraysVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:random-ballerina:${stdlibRandomVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:time-ballerina:${stdlibTimeVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:url-ballerina:${stdlibUrlVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:xmldata-ballerina:${stdlibXmldataVersion}"
        ballerinaStdLibs "io.ballerina.lib:ldap-ballerina:${stdlibLdapVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:crypto-ballerina:${stdlibCryptoVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:log-ballerina:${stdlibLogVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:os-ballerina:${stdlibOsVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:task-ballerina:${stdlibTaskVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:xslt-ballerina:${stdlibXsltVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:protobuf-ballerina:${stdlibProtobufVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:cache-ballerina:${stdlibCacheVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:file-ballerina:${stdlibFileVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:ftp-ballerina:${stdlibFtpVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:mime-ballerina:${stdlibMimeVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:mqtt-ballerina:${stdlibMqttVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:tcp-ballerina:${stdlibTcpVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:udp-ballerina:${stdlibUdpVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:uuid-ballerina:${stdlibUuidVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:auth-ballerina:${stdlibAuthVersion}"
        ballerinaStdLibs "io.ballerina.lib:avro-ballerina:${stdlibAvroVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:email-ballerina:${stdlibEmailVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:jwt-ballerina:${stdlibJwtVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:oauth2-ballerina:${stdlibOAuth2Version}"
        ballerinaStdLibs "io.ballerina.stdlib:http-ballerina:${stdlibHttpVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:graphql-ballerina:${stdlibGraphqlVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:grpc-ballerina:${stdlibGrpcVersion}"

        ballerinaStdLibs "org.ballerinalang:transaction-ballerina:${stdlibTransactionVersion}"
        ballerinaStdLibs "io.ballerina:observe-ballerina:${observeInternalVersion}"

        ballerinaStdLibs "io.ballerina.stdlib:websocket-ballerina:${stdlibWebsocketVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:websub-ballerina:${stdlibWebsubVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:websubhub-ballerina:${stdlibWebsubhubVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:sql-ballerina:${stdlibSqlVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:persist-ballerina:${stdlibPersistVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:yaml-ballerina:${stdlibYamlVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:toml-ballerina:${stdlibTomlVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:soap-ballerina:${stdlibSoapVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:observe-ballerina:${observeVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:math.vector-ballerina:${stdlibMathVectorVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:edi-ballerina:${stdlibEdiVersion}"

        /* Ballerina Persist Tool */
        ballerinaStdLibs "io.ballerina:persist-tools:${persistToolVersion}"

        /* Ballerina GraphQL */
        ballerinaStdLibs "io.ballerina:graphql-tools:${graphqlToolVersion}"

        /* Ballerina Protoc Tool */
        ballerinaStdLibs "io.ballerina:protoc-tools:${protocToolVersion}"

        /* Ballerina OpenAPI */
        ballerinaOpenAPILibs "io.ballerina:module-ballerina-openapi:${openapiToolVersion}"

        /* Ballerina AsyncAPI */
        ballerinaStdLibs "io.ballerina:module-ballerina-asyncapi:${asyncapiToolVersion}"

        /* Code to cloud extensions */
        ballerinaC2cLibs "io.ballerina:cloud-ballerina:${c2cVersion}"
        ballerinaC2cTooling "io.ballerina:cloud-tooling:${c2cVersion}"

    }
}