build.gradle

buildscript {
    apply from: 'https://raw.githubusercontent.com/blackducksoftware/integration-resources/master/gradle_common/buildscript-repositories.gradle', to: buildscript

    apply from: 'https://raw.githubusercontent.com/blackducksoftware/integration-resources/master/gradle_common/buildscript-cgp-version.gradle'

    ext {
        javaTargetCompatibility = 8
        javaSourceCompatibility = 8
    }

    dependencies { classpath "com.blackduck.integration:common-gradle-plugin:${managedCgpVersion}" }
}

plugins {
    id 'org.springframework.boot' version '2.5.0'
    id "com.moowork.node" version "1.3.1"
}

version = '0.9.0'
description = 'Management of the Integration Team\'s Black Duck VM\'s'

ext {
    javaSourceCompatibility = JavaVersion.VERSION_11
    javaTargetCompatibility = JavaVersion.VERSION_11
}

apply plugin: 'com.blackduck.integration.solution'
apply plugin: 'io.spring.dependency-management'

node {
    version = '14.17.3'
}

task buildReactApp(type: NodeTask, dependsOn: 'npm_install') {
    script = project.file('node_modules/webpack/bin/webpack.js')
    args = ['--mode', 'development',
            '--entry', './src/main/webapp/js/Main.jsx',
            '-o', './src/main/resources/static/dist']
}

processResources.dependsOn 'buildReactApp'
//clean.delete << file('node_modules')
clean.delete << file('src/main/resources/static/dist')

dependencies {
    implementation 'com.blackduck.integration:blackduck-common:67.0.0'
    implementation 'com.vdurmont:semver4j:3.1.0'

    implementation 'org.springframework.boot:spring-boot-starter-web'

    implementation 'javax.validation:validation-api:2.0.1.Final'

    implementation 'io.springfox:springfox-boot-starter:3.0.0'
    implementation 'io.springfox:springfox-swagger-ui:3.0.0'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}