build.gradle

plugins {
    id 'java'
    id 'jacoco'
}

group 'cs4120.cyr7'
version '1.0'

repositories {
    mavenCentral()
}

dependencies {
    compile fileTree(dir: 'dependencies', include: ['*.jar'])
}

jar {
    manifest {
        attributes "Main-Class": "cyr7.cli.CLI"
    }

    from {
        configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

sourceSets {
    main {
        java {
            srcDirs = ['src/java']
        }
        resources {
            srcDirs = ['src/resources']
        }
    }
    test {
        java {
            srcDirs = ['tests/java']
        }
        resources {
            srcDirs = ['tests/resources']
        }
    }
}

test {
    useJUnitPlatform {
        excludeTags 'benchmark'
    }
    enableAssertions = true
    testLogging {
        events "passed", "skipped", "failed"
        showStandardStreams = true
        showStackTraces = true
        exceptionFormat = 'full'
    }
    finalizedBy jacocoTestReport
}

task coreTest(type: Test) {
    dependsOn assemble
    useJUnitPlatform {
        includeTags 'core'
    }
    enableAssertions = true
    testLogging {
        events "passed", "skipped", "failed"
        showStandardStreams = true
        showStackTraces = true
        exceptionFormat = 'full'
    }
}

task benchmark(type: Test) {
    dependsOn assemble
    useJUnitPlatform {
        includeTags 'benchmark'
    }
    enableAssertions = true
    testLogging {
        events "passed", "skipped", "failed"
        showStandardStreams = true
        showStackTraces = true
        exceptionFormat = 'full'
    }
}