build.gradle

plugins {
    id 'java'
    id 'java-library'
    id 'maven-publish'
    id "com.gradleup.shadow" version "8.3.2"
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
    withSourcesJar()
}

group 'net.covers1624'
archivesBaseName = "FastRemapper"
version '0.3.2'

version = "$version." + (System.getenv("BUILD_NUMBER") ?: "1")
println "Starting build of ${archivesBaseName}, Version: ${version}"

repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://maven.minecraftforge.net/" }
}

dependencies {
    api 'net.covers1624:Quack:0.4.6.68'

    api 'net.sf.jopt-simple:jopt-simple:5.0.4'
    api 'org.ow2.asm:asm:9.7'
    api('org.ow2.asm:asm-commons:9.7') {
        exclude module: 'asm-tree'
    }

    api 'net.minecraftforge:srgutils:0.4.3'

    compileOnly 'com.google.code.findbugs:jsr305:3.0.2'
    compileOnly 'org.jetbrains:annotations:22.0.0'

    testImplementation 'org.ow2.asm:asm-util:9.2'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.1'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.10.1'
}

jar {
    manifest {
        attributes 'Main-Class': 'net.covers1624.fastremap.FastRemapper'
        attributes 'Multi-Release': 'true'
    }
    from file("LICENSE.txt")
}

shadowJar {
    configurations = [project.configurations.runtimeClasspath]
    manifest {
        attributes 'Main-Class': 'net.covers1624.fastremap.FastRemapper'
        attributes 'Multi-Release': 'true'
    }
    from file("LICENSE.txt")
}
assemble.dependsOn shadowJar

publishing {
    repositories {
        if (System.getenv('MAVEN_PASS')) {
            maven {
                url "https://nexus.covers1624.net/repository/maven-releases/"
                credentials {
                    username 'covers1624'
                    password System.getenv('MAVEN_PASS')
                }
            }
        }
    }
    publications {
        FastRemapper(MavenPublication) {
            groupId project.group
            artifactId project.archivesBaseName
            version project.version
            from components["java"]

            pom {
                name = archivesBaseName
                description = archivesBaseName
                //The publish plugin doesnt like GString's here apparently..
                url = "https://github.com/covers1624/${archivesBaseName}".toString()
                scm {
                    url = "https://github.com/covers1624/${archivesBaseName}".toString()
                    connection = "scm:git:git://github.com/covers1624/${archivesBaseName}.git".toString()
                    connection = "scm:git:git@github.com:covers1624/${archivesBaseName}.git".toString()
                }

                issueManagement {
                    system = 'github'
                    url = "https://github.com/covers1624/${archivesBaseName}/issues".toString()
                }
                licenses {
                    license {
                        name = "MIT"
                        url = "https://raw.githubusercontent.com/covers1624/${archivesBaseName}/master/LICENSE.txt".toString()
                        distribution = 'repo'
                    }
                }
                developers {
                    developer {
                        id = 'covers1624'
                        name = 'covers1624'
                    }
                }
            }
        }
    }
}