build.gradle

/*

 Copyright (c) 2021-2024, Carlos Amengual.

 Licensed under a BSD-style License. You can find the license here:
 https://raw.githubusercontent.com/css4j/xml-dtd/master/LICENSE.txt

 */
 
 /*
  * SPDX-License-Identifier: BSD-3-Clause
  */

plugins {
	id 'java-library'
	id 'maven-publish'
}

group = 'io.sf.carte'

description = 'xml-dtd'

version = '4.3.1-SNAPSHOT'

sourceSets {
	main {
		java {
			srcDirs = ['src']
			includes += ["**/*.java"]
		}
		resources {
			srcDirs = ['src']
			excludes += ["**/*.java"]
		}
	}
	test {
		java {
			srcDirs = ['junit']
			includes += ["**/*.java"]
		}
		resources {
			srcDirs = ['junit']
			excludes += ["**/*.java"]
		}
	}
}

java {
	sourceCompatibility = JavaVersion.VERSION_1_8
	withJavadocJar()
	withSourcesJar()
	registerFeature('dtdparse') {
		usingSourceSet(sourceSets.main)
	}
	registerFeature('dtdecl') {
		usingSourceSet(sourceSets.main)
	}
}

dependencies {
	api('io.sf.carte:carte-util') {
		version {
			strictly '[3.4.0,)'
			prefer '3.6.0'
		}
	}
	dtdparseImplementation 'io.sf.carte:tokenproducer:[3.0,)'
	dtdeclImplementation 'io.sf.jclf:jclf-text:[5.0.0,)'
	testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

repositories {
	maven {
		url = uri('https://repo.maven.apache.org/maven2/')
	}
	maven {
		url "https://css4j.github.io/maven/"
		mavenContent {
			releasesOnly()
		}
		content {
			includeGroup 'io.sf.carte'
			includeGroup 'io.sf.jclf'
		}
	}
}

test {
	useJUnitPlatform()
}

tasks.compileJava {
	excludes += ['module-info.java']
	modularity.inferModulePath = false
	options.release = 8
}

tasks.register('compileModuleInfo', JavaCompile) {
	description = 'Compile module-info to Java 11 bytecode'
	dependsOn tasks.compileJava
	sourceCompatibility = JavaVersion.VERSION_11
	targetCompatibility = JavaVersion.VERSION_11
	source = sourceSets.main.java
	classpath = sourceSets.main.compileClasspath
	destinationDirectory = sourceSets.main.java.destinationDirectory
	modularity.inferModulePath = true
	includes = ['module-info.java']
}

classes.dependsOn compileModuleInfo

// Check bytecode version, in case some other task screws it
tasks.register('checkLegacyJava') {
	description = 'Check that classes are Java 8 bytecode (except module-info)'
	def classdir = sourceSets.main.output.classesDirs.files.stream().findAny().get()
	def classfiles = fileTree(classdir).matching({it.exclude('module-info.class')}).files
	doFirst() {
		if (!classfiles.isEmpty()) {
			def classfile = classfiles.stream().findAny().get()
			if (classfile != null) {
				def classbytes = classfile.bytes
				def bcversion = classbytes[6] * 128 + classbytes[7]
				if (bcversion != 52) {
					throw new GradleException("Bytecode on " + classfile +
							" is not valid Java 8. Version should be 52, instead is " + bcversion)
				}
			}
		}
	}
}

classes.finalizedBy checkLegacyJava

tasks.register('lineEndingConversion', CRLFConvert) {
	description 'Convert top-level files to Windows line endings'
	file "$rootDir/RELEASE_NOTES.md"
}

tasks.register('lineEndingConvCopy', CRLFConvertCopy) {
	description 'Convert LICENSE and NOTICE to Windows line endings'
	from "$rootDir/LICENSE.txt"
	from "$rootDir/NOTICE.txt"
}

tasks.register('cleanBuildSrc') {
	description = 'Clean the buildSrc directory'
	doLast {
		delete("$rootDir/buildSrc/build")
	}
}

tasks.named('clean') {
	finalizedBy('cleanBuildSrc')
}

tasks.withType(JavaCompile) {
	options.encoding = 'UTF-8'
}

tasks.withType(Javadoc) {
	options.addStringOption('Xdoclint:none', '-quiet')
	options.addStringOption('encoding', 'UTF-8')
	options.addStringOption('charset', 'UTF-8')
	options.links 'https://docs.oracle.com/en/java/javase/11/docs/api/'
}

tasks.withType(AbstractArchiveTask).configureEach {
	// Reproducible build
	preserveFileTimestamps = false
	reproducibleFileOrder = true
	// Copy license file
	dependsOn lineEndingConvCopy
	from ("$buildDir/tmp/crlf/LICENSE.txt") {
		into 'META-INF'
	}
	from ("$buildDir/tmp/crlf/NOTICE.txt") {
		into 'META-INF'
	}
}

build.dependsOn lineEndingConversion

publishing {
	repositories {
		maven {
			name = 'mavenRepo'
			/*
			 * The following section applies to the 'publish' task:
			 *
			 * If you plan to deploy to a repository, please configure the
			 * 'mavenReleaseRepoUrl' and/or 'mavenSnapshotRepoUrl' properties
			 * (for example in GRADLE_USER_HOME/gradle.properties).
			 *
			 * Otherwise, Gradle shall create a 'build/repository' subdirectory
			 * at ${rootDir} and deploy there.
			 *
			 * Properties 'mavenRepoUsername' and 'mavenRepoPassword' can also
			 * be set (generally from command line).
			 */
			def releasesUrl
			def snapshotsUrl
			if (project.hasProperty('mavenReleaseRepoUrl') && project.mavenReleaseRepoUrl) {
				releasesUrl = mavenReleaseRepoUrl
			} else {
				releasesUrl = "${rootDir}/build/repository/releases"
			}
			if (project.hasProperty('mavenSnapshotRepoUrl') && project.mavenSnapshotRepoUrl) {
				snapshotsUrl = mavenSnapshotRepoUrl
			} else {
				snapshotsUrl = "${rootDir}/build/repository/snapshots"
			}
			url = version.endsWith('-SNAPSHOT') ? snapshotsUrl : releasesUrl
			if (project.hasProperty('mavenRepoUsername') &&
					project.hasProperty('mavenRepoPassword')) {
				credentials.username = mavenRepoUsername
				credentials.password = mavenRepoPassword
			}
		}
	}
	publications {
		maven(MavenPublication) {
			from(components.java)
			suppressAllPomMetadataWarnings()
			pom {
				description = "XML DTD utility library"
				url = "https://css4j.github.io/resolver.html"
				licenses {
					license {
						name = "BSD 3-clause license"
						url = "https://css4j.github.io/LICENSE.txt"
					}
				}
				scm {
					connection = "scm:git:https://github.com/css4j/xml-dtd.git"
					developerConnection = "scm:git:git://git@github.com:css4j/xml-dtd.git"
					url = "https://github.com/css4j/xml-dtd"
				}
			}
		}
	}
}