How to write and use templates with package

[owulveryck]

Hello,

I am brand new to cue. I'd like to use it to define a template and a set of constraints for data schema.

Here is a quick summary of what I am trying to achieve:
I would like all my data producers to generate events that match a certain format: envelop + data.
I would like the envelop to be the same for all my producers
I would like data to be specific to the producers (all producers define their own schema with their constraints on each field).

My tests
So far I've defined this package:

package event

// Definition of the envelop
#Envelop: {
	subject:         =~"^[0-9a-fA-F]{8}-[0-9a-fA-F]{4}-[0-9a-fA-F]{4}-[0-9a-fA-F]{4}-[0-9a-fA-F]{12}$" // a uuid
	source:          =~"^net.mycompany.+"
	type:            =~"^net.mycompany.+:[cud]" // c : create u : update d : delete
	dataContentType: string
}

#Data: {}

#Event: {
	envelop: #Envelop
	data:    #Data
}

I made a sample data producer and the directory tree looks like this:

.
├── cue.mod
│   ├── module.cue
│   ├── pkg
│   └── usr
├── producers
│   └── sample1
│       └── definitions.cue
├── schemas
│   └── event
│       └── event.cue

And the sample1 definition file look like this

package sample1

import (
	"mycompany.net/mypackage/schemas/event"
)

#message: #event.Event & {
	envelop: {
		source: "net.mycompany.sample1"
	}
	data: {
               sampleField: ˜= "^abc$" 
        }
}

test: #message & {
	envelop: {
		type: "bla"
	}
}

Now to the questions:

• why does the system complains about event not being defined:

imported and not used: "mycompany.net/mypackage/schemas/event":
    ./producers/sample1/definitions.cue:4:2
#message: reference "#event" not found:
    ./producers/sample1/definitions.cue:7:11

(it works if I replace the #event.Event by event.Event)

• Why do I have test.envelop: field not allowed: type: ./producers/sample1/definitions.cue:9:11 in the definition?

I guess that I may have misunderstood an underlying concept of the language.

Thank you for your help.

[PierreR]

Don't you need to prefix the call to #event with the event namespace (last segment of the import string) ?

[owulveryck]

Thank you for your answer. I don't think I understand the comment though. #event.Event has already the event prefix. What else could I add?

[owulveryck]

First self-answer, the # reference the definition, and should not be put in front of the namespace.

s/#event.Event/event.#Event/

package sample1

import (
	"mycompany.net/mypackage/schemas/event"
)

#message: event.#Event & {
	envelop: {
		source: "net.mycompany.sample1"
	}
	data: {
               sampleField: ˜= "^abc$" 
        }
}

test: #message & {
	envelop: {
		type: "bla"
	}
}

[owulveryck]

Here is a working example:

package event

// Definition of the envelop
#Envelop: {
	subject:          =~"^[0-9a-fA-F]{8}-[0-9a-fA-F]{4}-[0-9a-fA-F]{4}-[0-9a-fA-F]{4}-[0-9a-fA-F]{12}$" // a uuid
	source:           =~"^net.mycompany.+"
	type:             =~"^net.mycompany.+:[cud]" // c : create u : update d : delete
	dataContentType?: string
}

#Data: {}

#Event: {
	envelop: #Envelop
	data:    #Data
}

and the schema for the producer:

package sample1

import (
	"github.com/mycompany/masterschema/schemas/event:event"
)

#Schema: {
	envelop: event.#Envelop & {
		source: "net.mycompany.sample1"
	}
	data: {
		data1: string
	}
}

And a sample data:

message: #Schema & {
	envelop: {
		type:    "net.mycompany.sample1:c"
		subject: "123e4567-e89b-12d3-a456-426614174000"
	}
	data: {
		data1: "bla"
	}
}

[myitcv]

Just as you found out, it's the definition itself that is "named" #Envelop (for example) and hence is addressed via event.#Envelop when access via the import github.com/mycompany/masterschema/schemas/event

Note that the :event suffix on your import is only necessary if the package name does not match the directory that contains that package:

exec cue eval
cmp stdout stdout.golden

-- cue.mod/module.cue --
module: "github.com/mycompany/masterschema"
-- producer/producer.cue --
package producer

import (
	"github.com/mycompany/masterschema/schemas/event:event"
)

#Schema: {
	envelop: event.#Envelop & {
		source: "net.mycompany.sample1"
	}
	data: {
		data1: string
	}
}
-- sample.cue --
package sample

import "github.com/mycompany/masterschema/producer"

message: producer.#Schema & {
	envelop: {
		type:    "net.mycompany.sample1:c"
		subject: "123e4567-e89b-12d3-a456-426614174000"
	}
	data: {
		data1: "bla"
	}
}
-- schemas/event/event.cue --
package event

// Definition of the envelop
#Envelop: {
	subject:          =~"^[0-9a-fA-F]{8}-[0-9a-fA-F]{4}-[0-9a-fA-F]{4}-[0-9a-fA-F]{4}-[0-9a-fA-F]{12}$" // a uuid
	source:           =~"^net.mycompany.+"
	type:             =~"^net.mycompany.+:[cud]" // c : create u : update d : delete
	dataContentType?: string
}

#Data: {}

#Event: {
	envelop: #Envelop
	data:    #Data
}
-- stdout.golden --
message: {
    envelop: {
        subject: "123e4567-e89b-12d3-a456-426614174000"
        source:  "net.mycompany.sample1"
        type:    "net.mycompany.sample1:c"
    }
    data: {
        data1: "bla"
    }
}

[cueckoo]

This discussion has been migrated to cue-lang/cue#1028.

For more details about CUE's migration to a new home, please see cue-lang/cue#1078.