build.gradle

def getRepositoryUsername() {
    return hasProperty('mavenUsername') ? mavenUsername : ""
}
        
def getRepositoryPassword() {
    return hasProperty('mavenPassword') ? mavenPassword : ""
}

allprojects() {
    group = 'edu.cmu.sphinx'
    version = '5prealpha-SNAPSHOT'
}

subprojects() {
    apply plugin: 'java'
    apply plugin: 'maven'
    
    uploadArchives {
        repositories {
            mavenDeployer {
                repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                    authentication(userName: getRepositoryUsername(), password: getRepositoryPassword())
                }
                snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                    authentication(userName: getRepositoryUsername(), password: getRepositoryPassword())
                }
            }
        }
    }
    
    repositories() {
         mavenCentral()
    }

    compileJava.options.encoding = 'UTF-8'
    javadoc.options.encoding = 'UTF-8'
    sourceCompatibility = 1.7
    targetCompatibility = 1.7

    task javadocJar(type: Jar) {
        classifier = 'javadoc'
        from javadoc
    }
    
    task packageSources(type: Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    artifacts.archives packageSources, javadocJar
}