ESP32 Update.h V2

[bill-i-am-code]

I'm having some problems when updating my project to use ESP32 V2.0.6.

With the code below, all works as expected in V1.0.6, and both SPIFFS data and sketch data is updated from bin files. I have recently tried to do this with the later V2 library and have an issue with the SPIFFS update - it seems Update.onProgress is never called.
Updating the flash part

I'm sure I must be missing an obvious change, any help gratefully received.

#include <WiFi.h>
#include <HTTPClient.h>
#include <Update.h>

// location of firmware file on external web server
String codeFileName = "http://192.168.4.210/esp32fw2.bin";
String spiffsFileName = "http://192.168.4.210/oscar.spiffs.bin";

HTTPClient client;
// Your WiFi credentials
const char *ssid = "xxxxxxxxxxxxxx";
const char *password = "xxxxxxxxxxxxxxxxx";

bool updateFirmware(String fileName)
{
  // Connect to external web server
  client.begin(fileName);
  // Get file, just to check if each reachable
  int resp = client.GET();
  Serial.print("Response: ");
  Serial.println(resp);
  // If file is reachable, start downloading
  if (resp == 200)
  {
    // get length of document (is -1 when Server sends no Content-Length header)
    size_t fileSize = client.getSize();

    int cmd = (fileName.indexOf("spiffs") > -1) ? 100 : 0;
    Serial.println(fileName);
    Serial.println(cmd);
    Update.begin(fileSize, cmd);
    Update.onProgress(progress);
    // create buffer for read
    uint8_t buff[1024] = {0};
    // get tcp stream
    WiFiClient *stream = client.getStreamPtr();
    // read all data from server
    Serial.println("Updating firmware...");
    while (client.connected() && (fileSize > 0))
    {
      // get available data size
      size_t size = stream->available();
      if (size)
      {
        // read up to 1024 byte
        int c = stream->readBytes(buff, ((size > sizeof(buff)) ? sizeof(buff) : size));
        Update.write(buff, c);
        if (fileSize > 0)
        {
          fileSize -= c;
        }
      }
      delay(1);
    }
    if (fileSize == 0)
    {
      Update.end(true);
      return true;
    }
  }
  else
  {
    return false;
  }
  client.end();
}

void setup()
{
  Serial.begin(115200);
  // Start WiFi connection
  WiFi.mode(WIFI_MODE_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  if (updateFirmware(spiffsFileName))
  {
    if (updateFirmware(codeFileName))
    {
      Serial.println("Update Success");
      // Restart ESP32 to see changes
      ESP.restart();
    }
  }
  else
  {
    Serial.println("Cannot download firmware file. Only HTTP response 200: OK is supported. Double check firmware location #defined in HOST.");
  }
}

void loop() {}

void progress(size_t prg, size_t sz)
{
  Serial.println((prg * 100) / sz);
}

[mrengineer7777]

We wrote our own library based on an example. See https://github.com/mikalhart/ESP32-OTA-Pull/blob/main/src/ESP32OTAPull.h DoOTAUpdate(). The callback works correctly in their example.

[bill-i-am-code]

As an update for anyone searching and finding this in the future.
The main issue I was suffering did indeed turn out to be something simple. The default ESP32 partition map has changed between V1 and V2. In V1 the SPIFFS partition has size 0x170000, in V2 this is reduced to 0x160000. So the SPIFFS images (which I was creating from command line using mkspiffs rather than from the arduino IDE) would not fit.
In V2 there is a partition coredump at 0x3F0000 size 0x10000
It was also necessary to change, for example:
SYSTEM_EVENT_ETH_START to ARDUINO_EVENT_ETH_START as required.

[mjtrini]

Hi Bill,

Where did you make the change as stated:

It was also necessary to change, for example:
SYSTEM_EVENT_ETH_START to ARDUINO_EVENT_ETH_START as required.

Regards,
Michael.

[bill-i-am-code]

Hi Michael

Have a look here https://github.com/espressif/arduino-esp32/blob/master/libraries/WiFi/examples/WiFiClientEvents/WiFiClientEvents.ino
for an example of Wifi events.

Regards,
Bill