build.gradle

plugins {
	id 'java'
	id 'com.github.johnrengelman.shadow' version '6.0.0'
}

group 'me.clip'
version "2.10.7-DEV-${System.getProperty("BUILD_NUMBER")}"
description 'PlaceholderAPI'

sourceCompatibility = JavaVersion.VERSION_1_8

repositories {
	mavenLocal()
	maven {
		url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
	}
	maven {
		url = 'https://repo.codemc.org/repository/maven-public'
	}
	maven {
		url = 'https://rayzr.dev/repo/'
	}
	maven {
		url = 'http://repo.maven.apache.org/maven2'
	}
}

dependencies {
	implementation 'com.google.code.gson:gson:2.8.5'
	implementation 'org.bstats:bstats-bukkit:1.5'
	implementation 'me.rayzr522:jsonmessage:1.2.1'
	
	compileOnly 'org.spigotmc:spigot-api:1.16.1-R0.1-SNAPSHOT'
	compileOnly 'org.jetbrains:annotations:19.0.0'
	
	testImplementation 'org.openjdk.jmh:jmh-core:1.23'
	testImplementation 'org.openjdk.jmh:jmh-generator-annprocess:1.23'
	
	testCompile "org.junit.jupiter:junit-jupiter-engine:5.6.2"
	testRuntime "org.junit.jupiter:junit-jupiter-engine:5.6.2"
}

import org.apache.tools.ant.filters.ReplaceTokens

processResources {
	from(sourceSets.main.resources.srcDirs) {
		filter ReplaceTokens, tokens: [name: rootProject.name, version: project.version, description: project.description]
	}
}

compileJava.options.encoding = 'UTF-8'

shadowJar {
	archiveClassifier.set("")
	relocate "org.bstats", "me.clip.placeholderapi.metrics"
	relocate "com.google.gson", "me.clip.placeholderapi.libs.gson"
	relocate "me.rayzr522.jsonmessage", "me.clip.placeholderapi.libs.jsonmessage"
}

test {
	useJUnitPlatform()
}

sourceSets {
	test.compileClasspath += configurations.compileOnly
	test.runtimeClasspath += configurations.compileOnly
}