build.gradle

import io.freefair.gradle.plugins.okhttp.tasks.UploadFile

plugins {
    id "com.gradle.plugin-publish" version "1.3.0"
    id "io.freefair.git-version"
    id "io.freefair.lombok"
    id "io.freefair.javadoc-links"
}

repositories {
    gradlePluginPortal()
    google()
    mavenCentral()
}

def freefairGradleVersion = "8.11"
def agpVersion = "8.7.2"

group = 'io.freefair.gradle'
description = "FreeFair Android Gradle Plugins"

tasks.withType(Javadoc).configureEach {
    options.addBooleanOption("Xdoclint:-missing", true)
    options.links "https://docs.gradle.org/$gradle.gradleVersion/javadoc/"
    options.links "https://developer.android.com/reference/tools/gradle-api/8.7/"
    options.links "https://docs.freefair.io/gradle-plugins/$freefairGradleVersion/api"
}

jar {
    manifest {
        attributes 'Implementation-Version': "$project.version"
    }
}

java {
    withSourcesJar()
    withJavadocJar()
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

test.useJUnitPlatform()

dependencies {
    api "com.android.tools.build:gradle-api:$agpVersion"
    runtimeOnly "com.android.tools.build:gradle:$agpVersion"

    api "io.freefair.gradle:lombok-plugin:$freefairGradleVersion"
    api "io.freefair.gradle:aspectj-plugin:$freefairGradleVersion"

    testImplementation platform("org.junit:junit-bom:5.11.2")

    testImplementation 'org.assertj:assertj-core:3.26.3'
    testImplementation 'org.junit.jupiter:junit-jupiter-api'
    testImplementation 'org.junit.jupiter:junit-jupiter-params'

    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
}

gradlePlugin {
    website = "https://docs.freefair.io/android-gradle-plugins/$version/"
    vcsUrl = 'https://github.com/freefair/android-gradle-plugins'
    plugins {
        androidJavadoc {
            id = "io.freefair.android-javadoc"
            implementationClass = "io.freefair.gradle.plugins.android.AndroidJavadocPlugin"
            displayName = "Android Javadoc Plugin"
            description = "Generate javadocs for all variants of your android project"
            tags.set(['android'])
        }
        androidLombok {
            id = "io.freefair.android-lombok"
            implementationClass = "io.freefair.gradle.plugins.android.lombok.AndroidLombokPlugin"
            displayName = "Android Lombok Plugin"
            description = "Automatic Lombok and Delombok configuration for your android project"
            tags.set(['android'])
        }
        androidCi {
            id = "io.freefair.android-ci"
            implementationClass = "io.freefair.gradle.plugins.android.ci.CiPlugin"
            displayName = "Android CI Plugin"
            description = "Properly configure your android project on CI servers (like travis)"
            tags.set(['android'])

        }
        androidCiLint {
            id = "io.freefair.android-ci-lint"
            implementationClass = "io.freefair.gradle.plugins.android.ci.CiLintPlugin"
            displayName = "Android CI Plugin"
            description = "Properly configure your android project on CI servers (like travis)"
            tags.set(['android'])
        }
        androidAspectjPostCompileWeaving {
            id = "io.freefair.android.aspectj.post-compile-weaving"
            implementationClass = "io.freefair.gradle.plugins.android.aspectj.AndroidAspectJPostCompileWeavingPlugin"
            displayName = "Android AspectJ Post-Compile Weaving Plugin"
            description = "Android AspectJ Post-Compile Weaving Plugin"
            tags.set(['android'])
        }
    }
}

plugins.withId("maven-publish") {
    project.apply plugin: 'io.freefair.maven-central.validate-poms'

    publishing {
        publications.withType(MavenPublication).configureEach {
            pom {
                url = 'https://github.com/freefair/android-gradle-plugins'
                name = provider { project.description }
                description = provider { project.description }
                inceptionYear = '2016'
                licenses {
                    license {
                        name = 'MIT'
                        url = 'https://github.com/freefair/android-gradle-plugins/blob/master/LICENSE'
                    }
                }
                organization {
                    name = 'FreeFair'
                    url = 'https://github.com/freefair'
                }
                developers {
                    developer {
                        id = 'larsgrefer'
                        name = 'Lars Grefer'
                        email = 'github@larsgrefer.de'
                        timezone = 'Europe/Berlin'
                    }
                }
                ciManagement {
                    system = 'GitHub Actions'
                    url = 'https://github.com/freefair/android-gradle-plugins/actions'
                }
                issueManagement {
                    system = 'GitHub Issues'
                    url = 'https://github.com/freefair/android-gradle-plugins/issues'
                }
                scm {
                    connection = 'scm:git:https://github.com/freefair/android-gradle-plugins.git'
                    developerConnection = 'scm:git:git@github.com:freefair/android-gradle-plugins.git'
                    url = 'https://github.com/freefair/android-gradle-plugins/'
                }
            }
        }
    }
}

tasks.register('uploadDocumentation', UploadFile) {
    dependsOn "javadocJar"
    username = "user"
    password = findProperty('freefairDocsPass')
    file = javadocJar.archiveFile
    url = "https://docs.freefair.io/api/$project.version?path=android-gradle-plugins"
}

tasks.named('wrapper') {
    distributionType = Wrapper.DistributionType.ALL
}