forked from testpushpleaseignore/acquisition
-
Notifications
You must be signed in to change notification settings - Fork 3
/
installer.iss
92 lines (72 loc) · 3.18 KB
/
installer.iss
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
; Acquistion installer script
;-----------------------------------------------------------------------------------------
; Check command-line arguments.
#ifndef BUILD_DIR
#error "BUILD_DIR must be defined using the /D command-line parameter to run this script."
#endif
#ifndef DEPLOY_DIR
#error "DEPLOY_DIR must be defined using the /D command-line parameter to run this script."
#endif
;-----------------------------------------------------------------------------------------
; Load and check the version defines.
#define VERSION_H BUILD_DIR + "\version_defines.h"
#include VERSION_H
#ifndef APP_NAME
#error "APP_NAME not defined in " + VERSION_H
#endif
#ifndef APP_VERSION_STRING
#error "APP_VERSION_STRING not defined in " + VERSION_H
#endif
#ifndef APP_PUBLISHER
#error "APP_PUBLISHER not defined in " + VERSION_H
#endif
#ifndef APP_URL
#error "APP_URL not defined in " + VERSION_H
#endif
;-----------------------------------------------------------------------------------------
#pragma message "BUILD_DIR = " + BUILD_DIR
#pragma message "DEPLY_DIR = " + DEPLOY_DIR
#pragma message "VERSION_H = " + VERSION_H
#pragma message "APP_NAME = " + APP_NAME
#pragma message "APP_VERSION_STRING = " + APP_VERSION_STRING
#pragma message "APP_PUBLISHER = " + APP_PUBLISHER
#pragma message "APP_URL = " + APP_URL
;-----------------------------------------------------------------------------------------
; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
[Setup]
; NOTE: The value of AppId uniquely identifies this application. Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
;
; This is the same GUID as the testpushpleaseignore fork of Acquisition:
AppId={{53E25C0C-0305-47BB-9884-F0F202297AF4}
AppName={#APP_NAME}
AppVersion={#APP_VERSION_STRING}
AppPublisher={#APP_PUBLISHER}
AppPublisherURL={#APP_URL}
;AppSupportURL={#AppURL}
AppUpdatesURL={#APP_URL}
DefaultDirName={autopf}\{#APP_NAME}
DisableProgramGroupPage=yes
LicenseFile=COPYING
OutputBaseFilename={#APP_NAME}_setup_{#APP_VERSION_STRING}
PrivilegesRequired=lowest
PrivilegesRequiredOverridesAllowed=dialog
Compression=lzma2
SolidCompression=yes
WizardStyle=modern
MinVersion=10.0
[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"
[Tasks]
Name: "vc_redist"; Description: "Install Microsoft Visual C++ Runtime"; Flags: checkedonce
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; Flags: unchecked
[Files]
Source: "{#DEPLOY_DIR}\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
; NOTE: Don't use "Flags: ignoreversion" on any shared system files
[Icons]
Name: "{autoprograms}\{#APP_NAME}"; Filename: "{app}\{#APP_NAME}.exe"
Name: "{autodesktop}\{#APP_NAME}"; Filename: "{app}\{#APP_NAME}.exe"; Tasks: desktopicon
[Run]
Filename: "{app}\{#APP_NAME}.exe"; Description: "{cm:LaunchProgram,{#StringChange(APP_NAME, '&', '&&')}}"; Flags: nowait postinstall skipifsilent
Filename: "{app}\vc_redist.x64.exe"; Parameters: "/install"; Tasks: vc_redist;