deploy.gradle

apply plugin: 'com.jfrog.bintray'
apply plugin: 'maven-publish'

publishing {
    publications {
        Production(MavenPublication) {
            artifact("$buildDir/outputs/aar/lib-release.aar")
            groupId 'co.opensi.kkiapay' // replace with your groupId
            artifactId 'kkiapay' // replace with your artifactId
            version VERSION_NAME

            //The publication doesn't know about our dependencies, so we have to manually add them to the pom
            pom.withXml {
               def dependenciesNode = asNode().appendNode('dependencies')
                //Iterate over the implementation dependencies (we don't want the test ones), adding a <dependency> node for each
                configurations.implementation.allDependencies.each {
                    if (it.name != 'unspecified') {
                        def dependencyNode = dependenciesNode.appendNode('dependency')
                        dependencyNode.appendNode('groupId', it.group)
                        dependencyNode.appendNode('artifactId', it.name)
                        dependencyNode.appendNode('version', it.version)
                    }
                }
            }
        }
    }
}

bintray {
    // Get Bintray credential from environment variable
    user = System.getenv('BINTRAY_USER') // Get bintray User
    key = System.getenv('BINTRAY_API_KEY') // Get bintray Secret API Key
    dryRun = false
    override = false
    publish = true
    pkg {
        repo = 'KKIAPAY-ANDROID-SDK' // Bintray repo name
        name = 'android-sdk' // library module name
        userOrg = 'kkiapay' //  Bintray user name
        licenses = ['MIT']
        desc = 'Android SDK for kkiapay API'
        websiteUrl = 'https://kkiapay.me'
        vcsUrl = 'https://github.com/kkiapay/android-sdk' // repo url

        version {
            name = VERSION_NAME //Bintray logical version name
            vcsTag = VERSION_NAME
        }
    }
    publications = ['Production']
}