build.gradle

plugins {
    id 'application'
    id 'checkstyle'
    id 'pmd'
    id 'jacoco'
    id 'io.spring.dependency-management' version '1.1.5'
    id 'org.springframework.boot' version '3.2.5'
    id 'org.owasp.dependencycheck' version '9.2.0'
    id 'com.github.ben-manes.versions' version '0.51.0'
    id 'org.sonarqube' version '4.4.1.3373'
}

group = 'uk.gov.hmcts.juror'
version = '0.0.2'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

sourceSets {
    main {
        java {
            srcDir 'src/main/java'
            srcDir 'src/generated/java'
        }
    }
    functionalTest {
        java {
            compileClasspath += main.output
            runtimeClasspath += main.output
            srcDir file('src/functionalTest/java')
        }
        resources.srcDir file('src/functionalTest/resources')
    }

    integrationTest {
        java {
            compileClasspath += main.output
            runtimeClasspath += main.output
            srcDir file('src/integrationTest/java')
        }
        resources.srcDir file('src/integrationTest/resources')
    }

    smokeTest {
        java {
            compileClasspath += main.output
            runtimeClasspath += main.output
            srcDir file('src/smokeTest/java')
        }
        resources.srcDir file('src/smokeTest/resources')
    }
}

configurations {
    functionalTestImplementation.extendsFrom testImplementation
    functionalTestRuntimeOnly.extendsFrom runtimeOnly

    integrationTestImplementation.extendsFrom testImplementation
    integrationTestRuntimeOnly.extendsFrom runtimeOnly

    smokeTestImplementation.extendsFrom testImplementation
    smokeTestRuntimeOnly.extendsFrom runtimeOnly
    jaxb
}

tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:unchecked" << "-Werror"
}

// https://github.com/gradle/gradle/issues/16791
tasks.withType(JavaExec).configureEach {
    javaLauncher.set(javaToolchains.launcherFor(java.toolchain))
}

tasks.withType(Test) {
    useJUnitPlatform()

    testLogging {
        exceptionFormat = 'full'
    }
}

test {
    failFast = true
}

task functional(type: Test) {
    description = "Runs functional tests"
    group = "Verification"
    testClassesDirs = sourceSets.functionalTest.output.classesDirs
    classpath = sourceSets.functionalTest.runtimeClasspath
}

task integration(type: Test) {
    description = "Runs integration tests"
    group = "Verification"
    testClassesDirs = sourceSets.integrationTest.output.classesDirs
    classpath = sourceSets.integrationTest.runtimeClasspath
    failFast = false
}

task smoke(type: Test) {
    description = "Runs Smoke Tests"
    testClassesDirs = sourceSets.smokeTest.output.classesDirs
    classpath = sourceSets.smokeTest.runtimeClasspath
}

task genJaxb {
    ext.sourcesDir = "src/generated/java"
    ext.schema = "src/main/resources/schema/JurorService.xsd"

    outputs.dir sourcesDir

    doLast() {
        project.ant {
            taskdef name: "xjc", classname: "com.sun.tools.xjc.XJCTask",
                    classpath: configurations.jaxb.asPath
            mkdir(dir: sourcesDir)

            xjc(destdir: sourcesDir, schema: schema) {
                arg(value: "-wsdl")
                produces(dir: sourcesDir, includes: "**/*.java")
            }
        }
    }
}

checkstyle {
    maxWarnings = 0
    toolVersion = '10.17.0'
    getConfigDirectory().set(new File(rootDir, 'config/checkstyle'))

    checkstyleMain {
        source = "src/main/java"
    }
}

pmd {
    toolVersion = "6.55.0"
    sourceSets = [sourceSets.main, sourceSets.test, sourceSets.functionalTest, sourceSets.integrationTest, sourceSets.smokeTest]
    reportsDir = file("$project.buildDir/reports/pmd")
    // https://github.com/pmd/pmd/issues/876
    ruleSets = []
    ruleSetFiles = files("config/pmd/ruleset.xml")

    pmdMain {
        source = "src/main/java"
    }
}

jacocoTestReport {
    executionData(test, integration)
    reports {
        xml.required = true
        csv.required = false
        html.required = true
    }
}

project.tasks['sonarqube'].dependsOn jacocoTestReport
project.tasks['check'].dependsOn integration

sonarqube {
    properties {
        property "sonar.projectName", "Juror :: pnc"
        property "sonar.projectKey", "uk.gov.hmcts.juror:pnc"
    }
}

// before committing a change, make sure task still works
dependencyUpdates {
    def isNonStable = { String version ->
        def stableKeyword = ['RELEASE', 'FINAL', 'GA'].any { qualifier -> version.toUpperCase().contains(qualifier) }
        def regex = /^[0-9,.v-]+$/
        return !stableKeyword && !(version ==~ regex)
    }
    rejectVersionIf { selection -> // <---- notice how the closure argument is named
        return isNonStable(selection.candidate.version) && !isNonStable(selection.currentVersion)
    }
}

// https://jeremylong.github.io/DependencyCheck/dependency-check-gradle/configuration.html
dependencyCheck {
    // Specifies if the build should be failed if a CVSS score above a specified level is identified.
    // range of 0-10 fails the build, anything greater and it doesn't fail the build
    failBuildOnCVSS = 0
    suppressionFile = 'config/owasp/suppressions.xml'

    analyzers {
        // Disable scanning of .NET related binaries
        assemblyEnabled = false
    }
    skipConfigurations = [
            "checkstyle",
            "compileOnly",
            "pmd",
            "integrationTest",
            "functionalTest",
            "smokeTest",
            "contractTestRuntimeClasspath",
            "contractTestCompileClasspath"
    ]
}

repositories {
    mavenLocal()
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

ext {
    log4JVersion = "2.23.1"
    springVersion = "3.3.1"
    springSeceurityVersion = "6.1.4"
    lombokVersion = "1.18.34"
}

ext['snakeyaml.version'] = '2.0'

dependencies {

    //Dependency overrides (Can be removed once other dependencies get updates to resolve security issues)
    implementation 'ch.qos.logback:logback-classic:1.5.4'
    implementation 'ch.qos.logback:logback-core:1.5.4'
    //END
    implementation 'com.github.hmcts:juror-spring-support-library:1.1.2'

    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-web', version: springVersion
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-actuator', version: springVersion
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-aop', version: springVersion
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-json', version: springVersion
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-validation', version: springVersion
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-security', version: springVersion
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-data-jpa', version: springVersion

    implementation group: 'org.springframework.data', name: 'spring-data-commons', version: springVersion
    implementation 'org.springframework.boot:spring-boot-starter-web-services'


    implementation group: 'org.springdoc', name: 'springdoc-openapi-starter-webmvc-ui', version: '2.6.0'
    implementation group: 'com.github.hmcts.java-logging', name: 'logging', version: '6.1.5'
    implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: log4JVersion
    implementation group: 'org.apache.logging.log4j', name: 'log4j-to-slf4j', version: log4JVersion

    implementation group: 'io.rest-assured', name: 'rest-assured', version: '5.4.0'

    // Database, repository
    implementation 'jakarta.persistence:jakarta.persistence-api:3.2.0'
    implementation 'org.postgresql:postgresql:42.7.3'
    implementation 'org.hibernate.orm:hibernate-envers:6.5.2.Final'

    // Documentation, logging

    implementation group: 'org.projectlombok', name: 'lombok', version: lombokVersion
    annotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombokVersion
    testImplementation group: 'org.projectlombok', name: 'lombok', version: lombokVersion
    testAnnotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombokVersion

    implementation 'org.jetbrains:annotations:24.1.0'
    testImplementation 'junit:junit:4.13.2'
    runtimeOnly(group: 'com.microsoft.azure', name: 'applicationinsights-core', version: '3.5.3')

    // Data Mapping
    implementation 'org.mapstruct:mapstruct:1.5.5.Final'
    annotationProcessor 'org.mapstruct:mapstruct-processor:1.5.5.Final'


    compileOnly 'jakarta.servlet:jakarta.servlet-api:6.1.0'

    // Validation
    testImplementation 'org.wiremock:wiremock-standalone:3.8.0'

    // Security
    implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.6'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.6'


    // Web requests
    implementation 'org.springframework:spring-webflux:6.1.10'

    testImplementation(platform('org.junit:junit-bom:5.10.3'))
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
    testImplementation group: 'org.springframework.boot', name: 'spring-boot-starter-test', {
        exclude group: 'junit', module: 'junit'
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }, version: springVersion

    //Other
    implementation 'org.apache.httpcomponents.client5:httpclient5:5.3.1'
    jaxb("org.glassfish.jaxb:jaxb-xjc")
    jaxb("org.glassfish.jaxb:jaxb-runtime")
}

mainClassName = 'uk.gov.hmcts.juror.pnc.check.Application'

bootJar {
    archiveFileName = "juror-pnc.jar"

    manifest {
        attributes('Implementation-Version': project.version.toString())
    }
}

// Gradle 7.x issue, workaround from: https://github.com/gradle/gradle/issues/17236#issuecomment-894768083
rootProject.tasks.named("processSmokeTestResources") {
    duplicatesStrategy = 'include'
}

wrapper {
    distributionType = Wrapper.DistributionType.ALL
}
compileJava.dependsOn genJaxb

task runAllStyleChecks {
    dependsOn 'checkstyleMain'
    dependsOn 'checkstyleTest'
    dependsOn 'checkstyleIntegrationTest'
    dependsOn 'checkstyleSmokeTest'
    dependsOn 'checkstyleFunctionalTest'

    dependsOn 'pmdMain'
    dependsOn 'pmdTest'
    dependsOn 'pmdIntegrationTest'
    dependsOn 'pmdSmokeTest'
    dependsOn 'pmdFunctionalTest'
}