-
Notifications
You must be signed in to change notification settings - Fork 1
/
G4ip.pl
1194 lines (1046 loc) · 30.3 KB
/
G4ip.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
INTUITIONISTIC PROPOSITIONAL LOGIC PROVER
*/
%%%
%%% Sequent Calculus Prover for SICStus Prolog
%%% by Naoyuki Tamura (tamura@kobe-u.ac.jp)
%%% Dept. Computer & Systems Eng., Kobe Univ., Japan
%%% TeX form output by Eiji Sugiyama (eiji@grad306c.scitec.kobe-u.ac.jp)
%%%
%%% You can freely distribute or modify this program.
%%%
:- dynamic
seq_system/2, threshold/1, output_form/1, logging/2,
output_count/1, output_result/2,
proved/3, not_proved/2, axiom/1.
%seq_system(cl,first).
%threshold(5).
%output_form(pretty).
%logging(no, _).
%output_count(1).
:- op(1200, xfx, [ -->, <--> ]).
:- op( 900, xfy, [ -> ]).
:- op( 850, xfy, [ /\, \/ ]).
:- op( 800, fy, [ ~ ]).
:- op( 750, xfy, [ @, # ]).
prover :-
writex('Sequent Calculus Prover ver 1.0 for SICStus Prolog'), nlx,
writex('by Naoyuki Tamura (tamura@kobe-u.ac.jp)'),nlx,
writex('and modified by Joseph Vidal-Rosset (joseph.vidal.rosset@gmail.com)'),nlx,
writex('regarding this prover for intuitionistic propositional logic.'),nlx,
% seq_init,
statistics(runtime, [T0,_]),
seq_prover,
statistics(runtime, [T1,_]),
T is T1-T0,
writex('Exit from Sequent Calculus Prover...'), nlx,
writex('Total CPU time = '), writex(T), writex(' msec.'), nlx,
log_end.
seq_init :-
set_system(cl,first),
set_threshold(5),
set_axioms([]),
set_output_form(pretty),
log_end,
reset_output_result.
seq_prover :-
current_input(STR),
seq_prover(STR).
seq_prover(STR) :-
repeat,
seq_system(Sys, Opt),
writex(Sys), writex('('), writex(Opt), writex(')'),
writex('> '),
readx(STR, X),
seq_command(X),
seq_quit(X),
close(STR).
seq_quit(X) :-
nonvar(X),
memberq(X, [quit, end, bye, halt, end_of_file]).
seq_command(X) :-
seq_execute(X),
!,
writex(yes), nlx.
seq_command(_) :-
writex(no), nlx.
seq_execute(X) :- var(X), !, fail.
seq_execute(X) :- seq_quit(X), !.
seq_execute(help) :- !, seq_help.
seq_execute(init) :- !, seq_init.
seq_execute([File]) :- !, seq_consult(File).
seq_execute(cl(Opt)) :- !, set_system(cl,Opt).
%seq_execute(il(Opt)) :- !, set_system(il,Opt).
seq_execute(threshold(N)) :- var(N), !,
threshold(N),
writex(threshold(N)), nlx.
seq_execute(threshold(N)) :- !,
set_threshold(N).
seq_execute(axioms(As)) :- var(As), !,
(bagof(A, axiom(([]-->[A])), As); As=[]), !,
writex(axioms(As)), nlx.
seq_execute(axioms(As)) :- !,
set_axioms(As).
seq_execute(output(Form)) :- var(Form), !,
output_form(Form),
writex(output(Form)), nlx.
seq_execute(output(Form)) :-
set_output_form(Form).
seq_execute(log(File)) :- var(File), !,
logging(File, _),
writex(log(File)), nlx.
seq_execute(log(no)) :- !,
log_end.
seq_execute(log(File)) :- !,
log_start(File).
seq_execute(N) :- integer(N), !,
get_output_result(N, N1, P),
print_output(N1, P).
seq_execute((Xs <--> Ys)) :- !,
seq_execute((Xs --> Ys)),
seq_execute((Ys --> Xs)).
seq_execute((Xs --> Ys)) :-
convert_to_seq((Xs --> Ys), Seq),
sequentq(Seq),
!,
seq_prove(Seq).
seq_execute(X) :-
writex('Error '),
writex(X),
writex(' is not a command nor a sequent.'), nlx.
seq_help :-
writex('A1,...,Am --> B1,...,Bn : Try to prove the sequent.'), nlx,
writex('A1,...,Am <--> B1,...,Bn : Try to prove the sequent '),
writex('in both directions.'), nlx,
writex('help : Help.'), nlx,
writex('init : Initialize the prover.'), nlx,
writex('[File] : Read from the file.'), nlx,
writex('Sys(Opt) : Select the system. '),
writex('Sys={cl}, Opt={first|prop}'), nlx,
writex('threshold(N) : Set/retrieve the threshold. N>=0'), nlx,
writex('axioms(Axioms) : Set/retrieve the axioms. '),
writex('Axioms=[A1,...,Am]'), nlx,
writex('output(Form) : Set/retrieve the output form. '),
writex('Form={pretty|tex|standard|term}'), nlx,
writex('log(L) : Start/stop/retrieve the output logging. '),
writex('L={yes|File|no}'), nlx,
writex('N : Display the N-th output.'), nlx,
writex('quit : Quit.'), nlx.
seq_consult(File) :-
open(File, read, STR),
seq_prover(STR).
seq_prove(Seq) :-
statistics(runtime,[_,_]),
prove(Seq, Proof),
statistics(runtime,[_,Time]),
writex('Succeed in proving '),
write_seq(Seq),
writex(' ('), writex(Time), writex(' msec.)'), nlx,
output_count(N),
assert_output_result(Proof),
!,
print_output(N, Proof).
seq_prove(Seq) :-
statistics(runtime,[_,Time]),
writex('Fail to prove '),
write_seq(Seq),
writex(' ('), writex(Time), writex(' msec.)'), nlx.
print_output(N, P) :-
output_form(Form), writex(Form), writex(':'),
writex(N), writex(' ='), nlx,
print_proof(P).
print_proof(P) :-
output_form(Form),
print_proof_form(Form, P).
print_proof_form(pretty, P) :- !,
pretty_print(P).
print_proof_form(tex, P) :- !,
tex_print(P).
print_proof_form(standard, P) :- !,
standard_print(P).
print_proof_form(term, P) :- !,
writex(P), nlx.
set_system(Sys, Opt) :-
memberq(Sys, [cl]),
memberq(Opt, [prop,first]),
retractall(seq_system(_,_)),
assert(seq_system(Sys,Opt)).
set_threshold(N) :-
integer(N), N >= 0,
retractall(threshold(_)),
assert(threshold(N)).
set_axioms(Axioms) :-
retractall(axiom(_)),
assert_axioms(Axioms).
assert_axioms([]).
assert_axioms([A|As]) :-
formulaq(A),
!,
assert(axiom(([]-->[A]))),
assert_axioms(As).
assert_axioms([A|As]) :-
writex('Error '), writex(A),
writex(' is not a formula.'), nlx,
assert_axioms(As).
set_output_form(Form) :-
memberq(Form, [pretty, tex, standard, term]),
retractall(output_form(_)),
assert(output_form(Form)).
reset_output_result :-
retractall(output_count(_)),
retractall(output_result(_,_)),
assert(output_count(1)).
assert_output_result(P) :-
output_count(N),
assert(output_result(N,P)),
retractall(output_count(_)),
N1 is N+1,
assert(output_count(N1)).
get_output_result(N, N, P) :- N>0, !,
output_result(N, P).
get_output_result(N, N1, P) :-
output_count(M),
N1 is M+N,
output_result(N1, P).
convert_to_seq((Xs --> Ys), (Xs1 --> Ys1)) :-
convert_to_list(Xs, Xs1), convert_to_list(Ys, Ys1).
convert_to_list(X, _) :- var(X), !, fail.
convert_to_list([], []) :- !.
convert_to_list([X|Xs], [X|Xs]) :- !.
convert_to_list((X,Xs), [X|Zs]) :- !, convert_to_list(Xs, Zs).
convert_to_list(X, [X]).
sequentq((X-->Y)) :- formula_listq(X), formula_listq(Y).
formula_listq([]).
formula_listq([A|As]) :- formulaq(A), formula_listq(As).
formulaq(A) :- var(A), !, fail.
formulaq((_-->_)) :- !, fail.
formulaq([]) :- !, fail.
formulaq([_|_]) :- !, fail.
formulaq(~A) :- !, formulaq(A).
formulaq(A/\B) :- !, formulaq(A), formulaq(B).
formulaq(A\/B) :- !, formulaq(A), formulaq(B).
formulaq(A->B) :- !, formulaq(A), formulaq(B).
formulaq(_X@A) :- !, formulaq(A).
formulaq(_X#A) :- !, formulaq(A).
formulaq(_).
%%
%% Sequent Calculus Prover
%%
%% seq_system( {cl}, {prop|first} ).
%% seq_system(cl,first).
%% Max number of cut and contraction rules: cut, r(all), l(exists)
%% threshold(5).
%% Axioms
%% axiom(Ax1). axiom(Ax2). ....
prove(S, P) :-
retractall(proved(_,_,_)),
retractall(not_proved(_,_)),
threshold(N),
writex('Trying to prove with threshold ='),
for(I, 0, N),
writex(' '), writex(I),
flush_out,
prove(S, P, I),
nlx,
!.
prove(_S, _P) :-
nlx,
fail.
prove(S, _P, N) :-
ground(S),
clause(not_proved(S,M), _),
N =< M,
!,
fail.
prove(S, P, N) :-
ground(S),
clause(proved(S,P,M), _),
M =< N,
!.
prove(S, P, _N) :-
clause(axiom(S), _),
P = [axiom,[[]],S],
!.
prove(S, P, N) :-
check_sequent(S),
select_rule(Rule, S, Ss, Pos),
P = [Rule,Pos,S|Ps],
set_sequents(Ss, Ps),
rule_constraint(Rule, Ps, M),
N1 is N-M, N1 >= 0,
prove_all(Ss, Ps, N1),
% !,
assert(proved(S,P,N)).
prove(S, _P, N) :-
ground(S),
assert(not_proved(S,N)),
!,
fail.
prove_all([], [], _N).
prove_all([S|Ss], [P|Ps], N) :-
prove(S, P, N),
prove_all(Ss, Ps, N).
check_sequent((X-->Y)) :-
length(X, N1), length(Y, N2),
N1 + N2 < 20.
%check_sequent(_) :- seq_system(cl,_), !.
%check_sequent((_X-->Y)) :- (Y=[]; Y=[_]), !.
select_rule(Rule, S, Ss, Pos) :-
rule(RuleSys, inv, Rule, S, Ss, Pos),
check_rule(RuleSys),
!.
select_rule(Rule, S, Ss, Pos) :-
rule(RuleSys, no, Rule, S, Ss, Pos),
check_rule(RuleSys).
check_rule([RSys,ROp]) :-
seq_system(Sys, Op),
check_rule1(Sys, RSys),
check_rule2(Op, ROp),
!.
check_rule1(Sys, Sys).
check_rule1(cl, _).
check_rule2(Op, Op).
check_rule2(first, _).
set_sequents([], []).
set_sequents([S|Ss], [[_,_,S|_]|Ps]) :- set_sequents(Ss, Ps).
rule_constraint(cut, [P1,_P2], 1) :- !,
axiom(S1),
P1 = [axiom,_,S1].
rule_constraint(l(all), [P1], 1) :- !,
P1 = [NextRule,_,_|_],
dif(NextRule, l(all)).
rule_constraint(r(exists), [P1], 1) :- !,
P1 = [NextRule,_,_|_],
dif(NextRule, r(exists)).
rule_constraint(_Rule, _, 0).
/*
* LOGICAL RULES of G4ip prover.
** Non-invertible rules.
*** Axioms
**** Identity axiom
The classical first axiom was in the classical case:
\begin{verbatim}
rule([cl,prop], no, ax, S, [], [[]]) :-
match(S, ([_X1,[A],_X2]-->[_Y1,[A],_Y2])).
\end{verbatim}
This rule is translated in G4ip by a /single conclusion/ sequent.
It is right to call it "the identity axiom":
*/
rule([cl,prop], no, ax, S, [], [[]]) :-
match(S, ([_X1,[A],_X2]-->[[A]])).
/*
**** Absurdity axiom
It translates the famous /Ex Falso Quodlibet/.
Thanks to the Prolog trick of anonymous variable, i.e. _ or here _Y, there is no need of Weakening rule.
This axiom is canceled in the minimal logic prover G4pm.
*/
rule([cl,prop], no, ax, S, [], [[]]) :-
match(S, ([_X1,[bot],_X2]-->[_Y])).
/*
**** Truth axiom.
Exactly the converse of the absurdity axiom.
*/
rule([cl,prop], no, ax, S, [], [[]]) :-
match(S, ([_X1,_X2]-->[[top]])).
/*
**** Rule of negation on the left: formulas move from the right to left.
Note that Only this rule of negation is non-invertible because the inversion means the classical double negation elimination (i.e. the classical /Reductio Ad Absurdum/.
*/
rule([cl,prop], no, l(~1), S, [S1], [l(N),r(0)]) :-
match(S, ([X1,[(~A)],X2]-->[[bot]])),
match(S1, ([X1,X2]-->[[A]])),
length(X1, N).
/*
**** Rules of disjunction on the right.
Note that these rules are not invertible in intuitionistic logic, by contrast with the classical case.
*/
rule([cl,prop], no, r(\/), S, [S1], [r(N),[r(N),r(N1)]]) :-
match(S, ([X1,X2]-->[[(A\/_B)]])),
match(S1, ([X1,X2]-->[[A]])),
length(X1, N), N1 is N+1.
rule([cl,prop], no, r(\/), S, [S1], [r(N),[r(N),r(N1)]]) :-
match(S, ([X1,X2]-->[[(_A\/B)]])),
match(S1, ([X1,X2]-->[[B]])),
length(X1, N), N1 is N+1.
/*
**** Usual rule of Conditional on the left.
For the completeness of the prover, this rule is /not/ dispensable.
*/
rule([cl,prop], no, l(->), S, [S1, S2], [l(N),r(0),l(N)]) :-
match(S, ([X1,[A->B],X2]-->[Y])),
match(S1, ([X1,X2]-->[[A]])),
match(S2, ([X1,[B],X2]-->[Y])),
length(X1, N).
/*
**** Fourth Roy Dyckoff's left rule (hence the label \(Lrd-4\)) : another left rule for conditional on the left.
I am indebted to Sara Negri and Jan von Plato for the expression of this rule (see in
/Structural Proof Theory/ p. 122 ) thanks to which an automated proof of the followin sequent is possible:
\[
\top \vdash_{i} \neg \neg (((p -> q) -> r) -> (((q -> p) -> r) -> r))
\].
*/
rule([cl,prop], no, l(rd-4), S, [S1, S2], [l(N),r(0),l(N)]) :-
match(S, ([X1,[((A->B)->C)],X2]-->[Y])),
match(S1, ([X1,[A,(B->C)],X2]-->[[B]])),
match(S2, ([X1,[C],X2]-->[Y])),
length(X1, N).
/*
** Invertible rules
*** Roy Dyckhoff's invertible rules
**** First Roy Dyckhoff's rule on the left (hence the label \(L~rd-1\))
Rule Lrd-1 is /modus ponens/+ /weakening on the left/; the add of the latter allows invertibility.
Proof: test the sequent
\begin{verbatim}
(p->q)/\p --> q
\end{verbatim}
with the prover and look at the output.
(The rule is expressed twice with a slight inversion owing Prolog constraints.)
*/
rule([cl,prop], inv, l(rd-1), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[A->B],[A],X2]-->[Y])),
match(S1, ([X1,[A],[B],X2]-->[Y])),
length(X1, N).
rule([cl,prop], inv, l(rd-1), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[A],[A->B],X2]-->[Y])),
match(S1, ([X1,[B],[A],X2]-->[Y])),
length(X1, N).
/*
**** Second Dyckhoff's rule
Test the input
\begin{verbatim}
(a/\b) -> c <--> a -> (b -> c).
\end{verbatim}
and note the interesting first sequent proof.
*/
rule([cl,prop], inv, l(rd-2), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[((A/\B)->C)],X2]-->[Y])),
match(S1, ([X1,[(A->(B->C))],X2]-->[Y])),
length(X1, N).
rule([cl,prop], inv, l(rd-2), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[((A/\B)->C)],X2]-->[Y])),
match(S1, ([X1,[(B->(A->C))],X2]-->[Y])),
length(X1, N).
/*
**** Third Dyckhoff's rule
This shows the meaning of disjunction when disjunction is on the left of the turnstile.
This rules allows the automated proof of the following sequent:
\((p \lor q) \to r \vdash (p \to r) \land (q \to r)\).
*/
rule([cl,prop], inv, l(rd-3), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[(A\/B)->C],X2]-->[Y])),
match(S1, ([X1,[(A->C)],[(B->C)],X2]-->[Y])),
length(X1, N).
rule([cl,prop], inv, l(rd-3), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[(B\/A)->C],X2]-->[Y])),
match(S1, ([X1,[(A->C)],[(B->C)],X2]-->[Y])),
length(X1, N).
rule([cl,prop], inv, l(rd-3-bis), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[(A\/B)->C],X2]-->[Y])),
match(S1, ([X1,[(B->C)],[(A->C)],X2]-->[Y])),
length(X1, N).
/*
**** Fifth Dyckhoff's rule
It is a rule easy to understand: \(\bot \to X\) is reducible to
\(\top\) and \(\top\) on the left of the turnstile adds no useful
information for inferences, therefore on can drop \(\bot \to X\)
when \(\bot \to X\) is on the left of the sequent.
Rule Lg4ip-5 is useful to give an automated proof of
the sequent
\(\neg \neg p \land \neg \bot \vdash \neg (p \to \bot) \) .
*Remark* : This rule is the second rule of G4ip which has to be deleted to make the prover G4mp: it is /not/ a rule of minimal logic, where \(\bot \to X\) is /not/ reducible to
\(\top\).
*/
rule([cl,prop], inv, l(rd-5), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[bot-> _A],X2]-->[Y])),
match(S1, ([X1,X2]-->[Y])),
length(X1, N).
/*
**** Sixth Dyckhoff's rule
Reason of this reduction rule: \(\top \to A\) is reducible to /A/.
*/
rule([cl,prop], inv, l(rd-6), S, [S1], [l(N),r(0),l(N)]) :-
match(S, ([X1,[top->A],X2]-->[Y])),
match(S1, ([X1,[A],X2]-->[Y])),
length(X1, N).
/*
*** Usual invertible rules of sequent calculus LJ
*/
/*
**** Negation definition on the left.
*/
rule([cl,prop], inv, l(~def), S, [S1], [r(N),l(0)]) :-
match(S, ([X1,[~A],X2]-->[Y])),
match(S1, ([X1,[A->bot],X2]-->[Y])),
length(X1, N).
/*
**** Rule of negation on the right: formulas move from the left to right.
It is the translation of negation introduction in natural deduction.
*/
rule([cl,prop], inv, r(~), S, [S1], [l(N),r(0)]) :-
match(S, ([X1,X2]-->[[~A]])),
match(S1, ([X1,[A],X2]-->[[bot]])),
length(X1, N).
/*
**** Negation definition on the right.
*/
rule([cl,prop], inv, r(~def), S, [S1], [r(N),l(0)]) :-
match(S, ([X1,X2]-->[[~A]])),
match(S1, ([X1,X2]-->[[A->bot]])),
length(X1, N).
/*
**** Conjunction on the left
*/
rule([cl,prop], inv, l(/\), S, [S1], [l(N),[l(N),l(N1)]]) :-
match(S, ([X1,[(A/\B)],X2]-->[Y])),
match(S1, ([X1,[A,B],X2]-->[Y])),
length(X1, N), N1 is N+1.
/*
**** Conjunction on the right
*/
rule([cl,prop], inv, r(/\), S, [S1, S2], [r(N),r(N),r(N)]) :-
match(S, ([X1,X2]-->[[(A/\B)]])),
match(S1, ([X1,X2]-->[[A]])),
match(S2, ([X1,X2]-->[[B]])),
length(X1, N).
/*
**** Disjunction on the left
*/
rule([cl,prop], inv, l(\/), S, [S1, S2], [l(N),l(N),l(N)]) :-
match(S, ([X1,[(A\/B)],X2]-->[Y])),
match(S1, ([X1,[A],X2]-->[Y])),
match(S2, ([X1,[B],X2]-->[Y])),
length(X1, N).
/*
**** Conditional on the right
*/
rule([cl,prop], inv, r(->), S, [S1], [r(N),[l(0),r(N)]]) :-
match(S, ([X1,X2]-->[[(A->B)]])),
match(S1, ([X1,[A],X2]-->[[B]])),
length(X1, N).
/*
END OF LOGICAL RULES
*/
match((X-->Y), (P-->Q)) :- append_all(P, X), append_all(Q, Y).
eigen_variable(V, X) :-
freeze(V, fail),
free_variables(X, Us),
dif_list(Us, V).
free_variables(X, Vs) :- free_vars(X, [], [], Vs).
free_vars(X, BVs, Vs0, Vs) :- var(X), !, free_vars1(X, BVs, Vs0, Vs).
free_vars(X, _BVs, Vs, Vs) :- ground(X), !.
free_vars([X|Y], BVs, Vs0, Vs) :- !,
free_vars(X, BVs, Vs0, Vs1), free_vars(Y, BVs, Vs1, Vs).
free_vars(all(X,A), BVs, Vs0, Vs) :- !,
free_vars(A, [X|BVs], Vs0, Vs).
free_vars(exists(X,A), BVs, Vs0, Vs) :- !,
free_vars(A, [X|BVs], Vs0, Vs).
free_vars(X, BVs, Vs0, Vs) :- X =.. Y, free_vars(Y, BVs, Vs0, Vs).
free_vars1(X, BVs, Vs, Vs) :- (memq(X, BVs); memq(X, Vs)), !.
free_vars1(X, _BVs, Vs, [X|Vs]).
dif_list([], _).
dif_list([U|Us], V) :- dif(U, V), dif_list(Us, V).
%%
%% Standard form printer
%%
standard_print(P) :-
standard_print(P, 0).
standard_print([Rule,_,S|Ps], Tab) :-
tabx(Tab),
write_rule_name(Rule), writex(': '),
write_seq(S), nlx,
Tab1 is Tab+2,
standard_print_list(Ps, Tab1).
standard_print_list([], _).
standard_print_list([P|Ps], Tab) :-
standard_print(P, Tab), standard_print_list(Ps, Tab).
%%
%% Pretty form printer
%%
pretty_print(P0) :-
name_variables(P0, P),
place_proof(P, [], Q, _, _),
print_placed_proof(Q),
fail.
pretty_print(_).
name_variables(X, Z) :-
name_variables(X, 0, _N, [], _Vs, Z).
name_variables(X, N, N, Vs, Vs, X) :- ground(X), !.
name_variables(X, N, N, Vs, Vs, Z) :- var(X), assoc(X, Z, Vs), !.
name_variables(X, N0, N, Vs0, [[X|Z]|Vs0], Z) :- var(X), !,
V is N0 mod 3, VN is N0//3,
name_var(V, VN, Z),
N is N0+1.
name_variables([X|Xs], N0, N, Vs0, Vs, [Z|Zs]) :- !,
name_variables(X, N0, N1, Vs0, Vs1, Z),
name_variables(Xs, N1, N, Vs1, Vs, Zs).
name_variables(X, N0, N, Vs0, Vs, Z) :-
X =.. Xs,
name_variables(Xs, N0, N, Vs0, Vs, Zs),
Z =.. Zs.
name_var(0, VN, X) :- !, name_var1("X", VN, X).
name_var(1, VN, X) :- !, name_var1("Y", VN, X).
name_var(2, VN, X) :- !, name_var1("Z", VN, X).
name_var1([V], 0, X) :- !, name(X, [V]).
name_var1([V], VN, X) :-
name(VN, Ns),
name(X, [V|Ns]).
%%
%% place_proof(+Proof, +Margins,
%% -Proof_with_pos, -LowerLeftPos, -NewMargins)
%%
place_proof([Rule,_,S|Ps1], Ms0, Q, LowerPos, Ms) :-
get_margins([M0,M1|Ms1], Ms0),
place_uppers(Ps1, Ms1, Ps2, UpperPos0, Ms2),
get_margins([M2|_], Ms2),
UpperWidth is M2-UpperPos0,
get_rule_name_width(Rule, W1),
get_seq_width(S, LowerWidth),
LowerOff is max(0,max(UpperPos0,max(M1,M0))-UpperPos0),
RulePos is UpperPos0+LowerOff,
RuleWidth is max(UpperWidth,LowerWidth),
LowerPos is RulePos+(RuleWidth-LowerWidth)//2,
UpperPos is max(UpperPos0,RulePos),
UpperOff is UpperPos-UpperPos0,
move_proof_list(Ps2, UpperOff, Ps3),
move_margins(Ms2, UpperOff, Ms3),
new_rule_width(Rule, RuleWidth, W1, RuleWidth1, W2),
Q = [RulePos+RuleWidth1,Rule,LowerPos+LowerWidth,S|Ps3],
M11 is RulePos+RuleWidth1+W2,
M01 is LowerPos+LowerWidth,
Ms = [M01,M11|Ms3].
new_rule_width([_Rule,_], _, W1, 0, W1) :- !.
new_rule_width(_Rule, RW, W1, RW, W2) :- W2 is W1+1.
place_uppers(Ps, Ms0, Qs, T, Ms) :-
place_proof_list(Ps, Ms0, Qs, T, Ms).
place_proof_list([], Ms0, [], T, Ms0) :- !,
get_margins([T|_], Ms0).
place_proof_list([P1], Ms0, [Q1], T, Ms) :- !,
place_proof(P1, Ms0, Q1, T, Ms).
place_proof_list([P1|Ps], Ms0, [Q1|Qs], T, Ms) :-
place_proof(P1, Ms0, Q1, T, Ms1),
move_margins(Ms1, 2, Ms2),
place_proof_list(Ps, Ms2, Qs, _T1, Ms).
move_proof_list([], _, []).
move_proof_list([P0|Ps0], Off, [P|Ps]) :-
move_proof(P0, Off, P),
move_proof_list(Ps0, Off, Ps).
move_proof([M0+W0,Rule,M1+W1,S|Ps0], Off, [N0+W0,Rule,N1+W1,S|Ps]) :-
N0 is M0+Off, N1 is M1+Off,
move_proof_list(Ps0, Off, Ps).
get_margins(Zs, Xs) :- var(Zs), !, Zs=Xs.
get_margins([], _).
get_margins([Z|Zs], []) :- !, Z=0, get_margins(Zs, []).
get_margins([Z|Zs], [Z|Xs]) :- get_margins(Zs, Xs).
move_margins([], _, []).
move_margins([M0|Ms0], Off, [M|Ms]) :-
M is M0+Off, move_margins(Ms0, Off, Ms).
%%
%% print_placed_proof(+Placed_Proof)
%%
print_placed_proof(P) :-
print_placed_proofs([P]).
print_placed_proofs([]).
print_placed_proofs(Ps) :- Ps=[_|_],
gather_uppers(Ps, Qs),
print_placed_proofs(Qs),
print_rules(Ps),
nlx,
print_lowers(Ps),
nlx.
gather_uppers([], []).
gather_uppers([P|Ps], Qs) :-
gather_uppers(Ps, Qs1),
P = [_,_Rule,_,_S|P0],
append(P0, Qs1, Qs).
print_rules([]).
print_rules([P|Ps]) :-
P = [M0+W0,Rule,_M1+_W1,_S|_],
goto_pos(M0),
print_rule_line(W0),
write_rule_name(Rule),
print_rules(Ps).
print_rule_line(0) :- !.
print_rule_line(N) :- N>0, n_writex(N, '-'), writex(' ').
print_lowers([]).
print_lowers([P|Ps]) :-
P = [_M0+_W0,_Rule,M1+_W1,S|_],
goto_pos(M1),
write_seq(S),
print_lowers(Ps).
get_width(X, W) :-
open_null(NULL, OldSTR, OldLog),
nlx,
writex(X),
line_position(W),
close_null(NULL, OldSTR, OldLog).
get_rule_name_width(R, W) :-
open_null(NULL, OldSTR, OldLog),
nlx,
write_rule_name(R),
line_position(W),
close_null(NULL, OldSTR, OldLog).
get_seq_width(S, W) :-
open_null(NULL, OldSTR, OldLog),
nlx,
write_seq(S),
line_position(W),
close_null(NULL, OldSTR, OldLog).
open_null(NULL, OldSTR, OldLog) :-
current_output(OldSTR),
open_null_stream(NULL),
set_output(NULL),
log_suspend(OldLog).
close_null(NULL, OldSTR, OldLog) :-
set_output(OldSTR),
close(NULL),
log_resume(OldLog).
write_rule_name(axiom) :- !, writex('Axiom').
write_rule_name(ax) :- !, writex('Ax').
write_rule_name(cut) :- !, writex('Cut').
write_rule_name(r(all)) :- !, writex('R@').
write_rule_name(r(exists)) :- !, writex('R#').
write_rule_name(r(R)) :- !, writex('R'), writex(R).
%write_rule_name(r(R,N)) :- !, writex('R'), writex(R), writex(N).
write_rule_name(l(all)) :- !, writex('L@').
write_rule_name(l(exists)) :- !, writex('L#').
write_rule_name(l(R)) :- !, writex('L'), writex(R).
%write_rule_name(l(R,N)) :- !, writex('L'), writex(R), writex(N).
write_seq((Xs-->Ys)) :-
write_list(Xs), writex(' --> '), write_list(Ys).
write_list([]).
write_list([X]) :- !, writex(X).
write_list([X|Xs]) :- writex(X), writex(','), write_list(Xs).
%%
%% Tex form printer
%%
tex_print(P) :-
tex_name_variables(P, Q),
tex_print(0, Q).
tex_name_variables(X, Z) :-
tex_name_variables(X, 0, _N, [], _Vs, Z).
tex_name_variables(X, N, N, Vs, Vs, X) :- ground(X), !.
tex_name_variables(X, N, N, Vs, Vs, Z) :- var(X), assoc(X, Z, Vs), !.
tex_name_variables(X, N0, N, Vs0, [[X|Z]|Vs0], Z) :- var(X), !,
V is N0 mod 3, VN is N0//3,
tex_name_var(V, VN, Z),
N is N0+1.
tex_name_variables([X|Xs], N0, N, Vs0, Vs, [Z|Zs]) :- !,
tex_name_variables(X, N0, N1, Vs0, Vs1, Z),
tex_name_variables(Xs, N1, N, Vs1, Vs, Zs).
tex_name_variables(X, N0, N, Vs0, Vs, Z) :-
X =.. Xs,
tex_name_variables(Xs, N0, N, Vs0, Vs, Zs),
Z =.. Zs.
tex_name_var(0, VN, X) :- !, tex_name_var1("x", VN, X).
tex_name_var(1, VN, X) :- !, tex_name_var1("y", VN, X).
tex_name_var(2, VN, X) :- !, tex_name_var1("z", VN, X).
tex_name_var1([V], 0, X) :- !, name(X, [V]).
tex_name_var1([V], VN, X) :-
[C1,C2]="_{",
name(VN, Ns), append(Ns, "}", Ns1),
name(X, [V,C1,C2|Ns1]).
tex_print(Tab, [[Rule,LN],_,S]) :- !,
tabx(Tab), writex('\\deduce{'),
tex_print_sequent(S), writex('}{'),
tex_print_rule_name([Rule,LN]), writex('}'), nlx.
tex_print(Tab, [Rule,_,S]) :- (Rule = ax; Rule = axiom), !,
tabx(Tab), tex_print_sequent(S).
tex_print(Tab, [Rule,_,S|Ss]) :-
tabx(Tab), writex('\\infer['),
tex_print_rule_name(Rule), writex(']{'),
tex_print_sequent(S),
writex('}{'),
tex_print_list(Ss, Tab),
writex('}'), nlx.
tex_print_list([], _Tab).
tex_print_list([S1], Tab) :- !,
nlx,
Tab1 is Tab+2,
tex_print(Tab1, S1),
tabx(Tab).
tex_print_list([S1|Ss], Tab) :- !,
nlx,
Tab1 is Tab+2,
tex_print(Tab1, S1),
tabx(Tab1), writex('&'),
tex_print_list(Ss, Tab).
tex_print_sequent((Xs-->Ys)) :-
tex_print_formulas(Xs),
writex(' \\lra '),
tex_print_formulas(Ys).
tex_print_formulas([]).
tex_print_formulas([A]) :- !,
tex_print_formula(A).
tex_print_formulas([A|As]) :-
tex_print_formula(A),
writex(', '),
tex_print_formulas(As).
tex_print_formula(A) :-
tex_print_formula(999, A).
tex_print_formula(Prec0, A) :- tex_quantifier_name(A, Q, X, B), !,
Prec = 999,
(Prec0 < Prec -> writex('('); true),
writex(Q), writex(' '), writex(X), writex('.'),
tex_print_formula(B),
(Prec0 < Prec -> writex(')'); true),
!.
tex_print_formula(Prec0, A) :- is_op(A, Prec, Type, Op, As), !,
(Prec0 < Prec -> writex('('); true),
tex_print_op_formula(Prec, Type, Op, As),
(Prec0 < Prec -> writex(')'); true),
!.
tex_print_formula(_Prec0, A) :- tex_unit_name(A, U), !,
writex(U).
tex_print_formula(_Prec0, A) :-
rename_functor(A, A1),
writex(A1).
rename_functor(X, Z) :-
X =.. [F0|As],
capitalize_atom(F0, F),
Z =.. [F|As].
tex_quantifier_name(X@A, '\\forall', X, A).
tex_quantifier_name(X#A, '\\exists', X, A).
tex_unit_name(_, _) :- fail.
tex_unit_name(bot, '\\bot').
tex_unit_name(top, '\\top').
%tex_print_op_formula(Prec, fy, Op, [A1]) :- Op = ~, !,
% tex_print_op(Op), writex('{'),
% tex_print_formula(Prec, A1), writex('}').
tex_print_op_formula(Prec, fx, Op, [A1]) :- !,
Prec1 is Prec - 1,
tex_print_op(Op), writex(' '),
tex_print_formula(Prec1, A1).
tex_print_op_formula(Prec, fy, Op, [A1]) :- !,
tex_print_op(Op), writex(' '),
tex_print_formula(Prec, A1).
tex_print_op_formula(Prec, xf, Op, [A1]) :- !,
Prec1 is Prec - 1,
tex_print_formula(Prec1, A1),
writex(' '), tex_print_op(Op).
tex_print_op_formula(Prec, yf, Op, [A1]) :- !,
tex_print_formula(Prec, A1),
writex(' '), tex_print_op(Op).
tex_print_op_formula(Prec, xfx, Op, [A1,A2]) :- !,
Prec1 is Prec - 1,
tex_print_formula(Prec1, A1),
writex(' '), tex_print_op(Op), writex(' '),
tex_print_formula(Prec1, A2).
tex_print_op_formula(Prec, xfy, Op, [A1,A2]) :- !,
Prec1 is Prec - 1,
tex_print_formula(Prec1, A1),
writex(' '), tex_print_op(Op), writex(' '),
tex_print_formula(Prec, A2).
tex_print_op_formula(Prec, yfx, Op, [A1,A2]) :- !,
Prec1 is Prec - 1,
tex_print_formula(Prec, A1),
writex(' '), tex_print_op(Op), writex(' '),
tex_print_formula(Prec1, A2).
is_op(A, Prec, Type, Op, As) :-
functor(A, Op, N), current_op(Prec, Type, Op),
is_op0(A, Type, N, As),
!.
is_op0(A, fx, 1, [A1]) :- arg(1, A, A1).
is_op0(A, fy, 1, [A1]) :- arg(1, A, A1).
is_op0(A, xf, 1, [A1]) :- arg(1, A, A1).
is_op0(A, yf, 1, [A1]) :- arg(1, A, A1).
is_op0(A, xfx, 2, [A1,A2]) :- arg(1, A, A1), arg(2, A, A2).
is_op0(A, xfy, 2, [A1,A2]) :- arg(1, A, A1), arg(2, A, A2).
is_op0(A, yfx, 2, [A1,A2]) :- arg(1, A, A1), arg(2, A, A2).
tex_print_op(Op) :-
tex_op_name(Op, OpName), !,
writex(OpName).
tex_op_name(~, '\\lnot').
tex_op_name(/\, '\\land').
tex_op_name(\/, '\\lor').
tex_op_name(->, '\\imp').
tex_print_rule_name([Rule,LN]) :- !,
tex_rule_name(Rule, RuleName),
!,
writex(RuleName),
writex('('), writex(LN), writex(')').
tex_print_rule_name(Rule) :-
tex_rule_name(Rule, RuleName),
!,
writex(RuleName).
tex_rule_name(ax, '({\\rm Ax})').
tex_rule_name(axiom, '({\\rm Axiom})').
tex_rule_name(l(top), '({\\rm L}\\top)').
tex_rule_name(r(top), '({\\rm R}\\top)').
tex_rule_name(l(bot), '({\\rm L}\\bot)').
tex_rule_name(r(bot), '({\\rm R}\\bot)').
tex_rule_name(l(~), '({\\rm L}\\lnot)').
tex_rule_name(r(~), '({\\rm R}\\lnot)').
tex_rule_name(l(/\), '({\\rm L}\\land)').
tex_rule_name(r(/\), '({\\rm R}\\land)').
tex_rule_name(l(\/), '({\\rm L}\\lor)').
tex_rule_name(r(\/), '({\\rm R}\\lor)').
tex_rule_name(l(->), '({\\rm L}\\imp)').
tex_rule_name(r(->), '({\\rm R}\\imp)').
tex_rule_name(l(all), '({\\rm L}\\forall)').
tex_rule_name(r(all), '({\\rm R}\\forall)').