build.gradle

plugins {
    id 'base'
    id 'nebula.ospackage' version '9.1.1'
}

apply from: "${projectDir}/version-info.gradle"

group 'com.martiansoftware'

def appVersion, appRelease, appDescription
(appVersion, appRelease, appDescription) = getVersionInfo()
project.version = "$appVersion.$appRelease"
project.description = appDescription

tasks.register('installDist', Copy) {
    final target = "$buildDir/install/nailgun"
    dependsOn 'nailgun-server:installDist'
    dependsOn 'nailgun-client:build'
    group 'distribution'
    into target
    from(new File(project('nailgun-server').buildDir, 'install/nailgun-server')) {
        into '.'
    }
    from(new File(project('nailgun-client').buildDir, 'exe/ng/ng')) {
        into './bin'
        fileMode 0755
    }
    from(new File(projectDir, 'pynailgun/ng.py')) {
        into './bin'
        fileMode 0755
    }
    outputs.dir(target)
}

tasks.register('distTar', Tar) {
    group 'distribution'
    from installDist
    into 'nailgun'
    compression Compression.GZIP
}

tasks.register('distZip', Zip) {
    group 'distribution'
    from installDist
    into 'nailgun'
    entryCompression ZipEntryCompression.DEFLATED
}

clean {
    delete buildDir
}

ospackage {

    packageName = 'nailgun'
    
    version = appVersion
    release = appRelease
    description = appDescription
    os = LINUX
    user = 'root'

    requires 'lsof'

    into "/opt/nailgun"

    from("$buildDir/install/nailgun/bin") {
        into 'bin'
        user project.name
        fileMode 0755
    }

    from("$buildDir/install/nailgun/lib") {
        into 'lib'
        user project.name
        fileMode 0644
    }

    from("$buildDir/install/nailgun/etc") {
        into 'etc'
        user project.name
        fileType CONFIG | NOREPLACE
        fileMode 0644
    }

    final systemdDir = "${project(':nailgun-server').buildDir}/resources/main/systemd"
    from("$systemdDir/nailgun.service") {
        into '/etc/systemd/system'
        fileMode 0644
    }
    from("$systemdDir/nailgun.conf") {
        into '/etc/sysconfig'
        fileType CONFIG | NOREPLACE
        fileMode 0644
    }

    preInstall """
        #!/usr/bin/sh
        if ! getent passwd nailgun >/dev/null; then
            sudo useradd -d /opt/nailgun -s /sbin/nologin nailgun
        fi
    """

    // The conditions are reversed because of the RC that the whole command exits with if the condition fails
    postInstall "/bin/systemctl daemon-reload"
}

buildRpm {
    dependsOn installDist
    arch = 'x86_64'

    final onCleanInstall = '[ "$1" != 1 ] ||'
    final onUpgradeInstall = '[ "$1" != 2 ] ||'
    final onCleanRemove = '[ "$1" != 0 ] ||'

    // Enable only after clean installing
    postInstall "$onCleanInstall /bin/systemctl enable 'nailgun.service'"
    // Start only after clean installing
    postInstall "$onCleanInstall /bin/systemctl start 'nailgun.service'"
    // Restart only after upgrade
    postInstall "$onUpgradeInstall /bin/systemctl restart 'nailgun.service'"
    // Stop only before complete uninstalling
    preUninstall "$onCleanRemove /bin/systemctl stop 'nailgun.service'"
    // Disable only before complete uninstalling
    preUninstall "$onCleanRemove /bin/systemctl disable 'nailgun.service'"
}

buildDeb {
    dependsOn installDist
    arch = 'amd64'

    postInstall "/bin/systemctl enable 'nailgun.service'"
    postInstall "/bin/systemctl start 'nailgun.service'"
    preUninstall "/bin/systemctl stop 'nailgun.service'"
    preUninstall "/bin/systemctl disable 'nailgun.service'"
}

afterEvaluate {
    println "\n#\n# Nailgun v${project.version}\n#"
}