build.gradle

buildscript {
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath "io.micronaut.build.internal:micronaut-gradle-plugins:4.0.0"
    }
}

subprojects { Project subproject ->
    group "io.micronaut.rabbitmq"
    apply plugin: "io.micronaut.build.internal.common"
    apply plugin: "io.micronaut.build.internal.dependency-updates"

    repositories {
        maven { url "https://s01.oss.sonatype.org/content/repositories/snapshots/" }
    }

    if (subproject.parent.name == "docs-examples" || subproject.name == "docs-examples") {
        return
    }

    apply plugin: "io.micronaut.build.internal.publishing"
}

apply plugin: "io.micronaut.build.internal.docs"
apply plugin: "io.micronaut.build.internal.dependency-updates"

def prepareGuideHotfix = tasks.register("prepareGuideHotfix") {
    doLast {
        file("${buildDir}/doc-resources").mkdirs()
    }
}

tasks.named('publishGuide') {
    dependsOn(prepareGuideHotfix)
    dependsOn(tasks.javadoc)
}