justfile

#!/usr/bin/env -S just --justfile
# ^ A shebang isn't required, but allows a justfile to be executed
#   like a script, with `./justfile test`, for example.

set windows-shell := ["powershell.exe", "-NoLogo", "-Command"]
set dotenv-load := true

docker-stack-name := "wasmcloud-playground"

# Show available commands
default:
    @just --list --justfile {{justfile()}}

# Start wasmCloud
up:
    cd ./docker && docker compose up -d

# Start wasmCloud with OpenFGA
up-fga:
    cd ./docker && docker compose -p {{ docker-stack-name }} -f compose.yaml -f compose.openfga.yaml up -d

# Restart the wasmCloud stack with OpenFGA
restart: down up

# Restart the wasmCloud stack
restart-fga: down up-fga

# Stop wasmCloud stack
down:
    cd ./docker && docker compose -p {{ docker-stack-name }}  down

# Run the wash (wasmCloud Shell) UI dashboard:
ui:
    wash ui

# Test the Go component
test-go:
    curl localhost:8062

# Test the Rust component
test-rust:
    curl localhost:8061

create-cluster: init-local-cluster  install-k8s-dash && view-k8s-dash

# Create local K8s cluster using kind
[private]
init-local-cluster: && install-prometheus-operator install-kind-registry
    # Create local k8s cluster (based on kind)
    kind create cluster --config deployment/k8s/kind-config.yaml

prometheus_operator_latest := `curl -s https://api.github.com/repos/prometheus-operator/prometheus-operator/releases/latest | jq -cr .tag_name`
[private]
install-prometheus-operator:
    # Install Prometheus Operator
    curl -sL https://github.com/prometheus-operator/prometheus-operator/releases/download/{{prometheus_operator_latest}}/bundle.yaml | kubectl create -f -
    # Wait for Kubernetes Operator to deploy
    kubectl rollout status deployment prometheus-operator -n default --timeout=90s

[private]
install-kind-registry:
    chmod +x ./deployment/kind-registry.sh && ./deployment/kind-registry.sh

# Install Kubectl Dashboard
[private]
install-k8s-dash:
    helm repo add kubernetes-dashboard https://kubernetes.github.io/dashboard/
    helm upgrade --install kubernetes-dashboard kubernetes-dashboard/kubernetes-dashboard --create-namespace --namespace kubernetes-dashboard \
    --set=extraArgs={--enable-skip-login} --wait
    kubectl apply -k ./deployment/argocd/apps/kubernetes-dashboard/

kubectl-dashboard-default-port := "8443"
# Open Kubectl Dashboard
view-k8s-dash port=kubectl-dashboard-default-port:
    #!/usr/bin/env bash
    export POD_NAME=$(kubectl get pods -n kubernetes-dashboard -l "app.kubernetes.io/name=kubernetes-dashboard,app.kubernetes.io/instance=kubernetes-dashboard" \
    -o jsonpath="{.items[0].metadata.name}")
    kubectl -n kubernetes-dashboard port-forward $POD_NAME {{port}}:8443

port-forward-nats:
    kubectl port-forward service/nats-cluster-headless 4222:4222 4223:4223