-
Notifications
You must be signed in to change notification settings - Fork 0
/
trtoepub.xsl
531 lines (484 loc) · 17.1 KB
/
trtoepub.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
<?xml version="1.0" encoding="utf-8"?>
<!--
trtoepub.xsl - translates Techrepv2 to EPUB.
Copyright © 2010 CESNET
Author: Ladislav Lhotka <Lhotka@cesnet.cz>
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>.
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:tr="http://cesnet.cz/ns/techrep/base/2.0"
version="1.0">
<xsl:include href="xhtml-common.xsl"/>
<xsl:output method="xml" encoding="UTF-8"/>
<xsl:template name="id-attribute">
<xsl:attribute name="id">
<xsl:apply-templates select="." mode="id"/>
</xsl:attribute>
</xsl:template>
<!-- Root element -->
<xsl:template match="/">
<html xmlns="http://www.w3.org/1999/xhtml">
<xsl:attribute name="xml:lang">
<xsl:choose>
<xsl:when test="tr:report/@xml:lang">
<xsl:value-of select="tr:report/@xml:lang"/>
</xsl:when>
<xsl:otherwise>en</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<head>
<meta http-equiv="Content-Type"
content="application/xhtml+xml; charset=utf-8"/>
<link rel="stylesheet" href="css/tr.css" type="text/css"/>
<xsl:element name="title" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="select-local">
<xsl:with-param name="cs">Technická zpráva – </xsl:with-param>
<xsl:with-param name="en">Technical report – </xsl:with-param>
</xsl:call-template>
<xsl:value-of select="tr:report/tr:title"/>
</xsl:element>
</head>
<body>
<xsl:apply-templates select="tr:report/tr:body"/>
<xsl:if test="tr:report//tr:footnote">
<xsl:element name="hr" namespace="http://www.w3.org/1999/xhtml"/>
<xsl:element name="p" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="strong" namespace="http://www.w3.org/1999/xhtml">
<xsl:text>Footnotes:</xsl:text>
</xsl:element>
</xsl:element>
<xsl:element name="table" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="tbody" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="valign">top</xsl:attribute>
<xsl:attribute name="border">0</xsl:attribute>
<xsl:apply-templates select="tr:report//tr:footnote"
mode="list"/>
</xsl:element>
</xsl:element>
</xsl:if>
</body>
</html>
</xsl:template>
<xsl:template match="tr:authors">
<xsl:element name="p" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates select="tr:author"/>
</xsl:element>
<xsl:element name="p" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates select="tr:affiliation"/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:author">
<xsl:element name="big" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="strong" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:element>
<xsl:if test="id(@affil)">
<xsl:if test="count(parent::*/tr:affiliation)>1
and count(parent::*/tr:author)>1">
<xsl:element name="sup" namespace="http://www.w3.org/1999/xhtml">
<xsl:for-each select="id(@affil)">
<xsl:number/>
<xsl:if test="position()!=last()">,</xsl:if>
</xsl:for-each>
</xsl:element>
</xsl:if>
</xsl:if>
<xsl:if test="following-sibling::tr:author">
<xsl:element name="big" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="strong" namespace="http://www.w3.org/1999/xhtml">
<xsl:text>, </xsl:text>
</xsl:element>
</xsl:element>
</xsl:if>
</xsl:template>
<xsl:template match="tr:affiliation">
<xsl:if test="count(parent::*/tr:affiliation)>1
and count(parent::*/tr:author)>1">
<xsl:element name="sup" namespace="http://www.w3.org/1999/xhtml">
<xsl:number/>
</xsl:element>
</xsl:if>
<xsl:element name="em" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
<xsl:element name="br" namespace="http://www.w3.org/1999/xhtml"/>
</xsl:template>
<xsl:template match="tr:title">
<xsl:element name="h1" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:abstract">
<xsl:element name="h2" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="select-local">
<xsl:with-param name="cs">Abstrakt</xsl:with-param>
<xsl:with-param name="en">Abstract</xsl:with-param>
</xsl:call-template>
</xsl:element>
<xsl:choose>
<xsl:when test="tr:p">
<xsl:apply-templates/>
</xsl:when>
<xsl:otherwise>
<xsl:element name="p" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="tr:keywords">
<xsl:element name="p" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="em" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="select-local">
<xsl:with-param name="cs">Klíčová slova</xsl:with-param>
<xsl:with-param name="en">Keywords</xsl:with-param>
</xsl:call-template>
<xsl:text>: </xsl:text>
</xsl:element>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:body">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="tr:h1">
<xsl:element name="h2" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="id-attribute"/>
<xsl:apply-templates select="." mode="number"/>
<xsl:text>  </xsl:text>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:h2">
<xsl:element name="h3" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="id-attribute"/>
<xsl:apply-templates select="." mode="number"/>
<xsl:text>  </xsl:text>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:h3">
<xsl:element name="h4" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="id-attribute"/>
<xsl:apply-templates select="." mode="number"/>
<xsl:text>  </xsl:text>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:appendix">
<xsl:element name="h2" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="id-attribute"/>
<xsl:call-template name="select-local">
<xsl:with-param name="cs">Dodatek</xsl:with-param>
<xsl:with-param name="en">Appendix</xsl:with-param>
</xsl:call-template>
<xsl:text> </xsl:text>
<xsl:apply-templates select="." mode="number"/>
<xsl:text>  </xsl:text>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:p|tr:pre|tr:ul|tr:dl|tr:dd|tr:li">
<xsl:element name="{local-name()}" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates select="@xml:id"/>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:ol">
<xsl:element name="ol" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates select="@xml:id"/>
<xsl:if test="@continue">
<xsl:variable name="cnt" select="id(@continue)"/>
<xsl:choose>
<xsl:when test="$cnt">
<xsl:attribute name="start">
<xsl:variable name="prev">
<xsl:apply-templates select="$cnt" mode="itemcount"/>
</xsl:variable>
<xsl:value-of select="$prev+1"/>
</xsl:attribute>
</xsl:when>
<xsl:otherwise>
<xsl:message terminate="no">
<xsl:text>Continued list not found: </xsl:text>
<xsl:value-of select="@continue"/>
</xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:if>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:ol" mode="itemcount">
<xsl:choose>
<xsl:when test="@continue">
<xsl:variable name="prev">
<xsl:apply-templates select="id(@continue)" mode="itemcount"/>
</xsl:variable>
<xsl:value-of select="$prev+count(tr:li)"/>
</xsl:when>
<xsl:otherwise>
<xsl:number value="count(tr:li)"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="tr:strong|tr:sup|tr:sub|tr:blockquote">
<xsl:element name="{local-name()}" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:dt">
<xsl:element name="dt" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="strong" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:element>
</xsl:template>
<xsl:template match="tr:em|tr:command|tr:file|tr:uri|tr:phrase">
<xsl:element name="em" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:tt|tr:input">
<xsl:element name="code" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:q">
<xsl:choose>
<xsl:when test="ancestor-or-self::*[@xml:lang='cs']">
<xsl:text>„</xsl:text>
<xsl:apply-templates/>
<xsl:text>“</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text>“</xsl:text>
<xsl:apply-templates/>
<xsl:text>”</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="tr:a">
<xsl:element name="a" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="href">
<xsl:value-of select="@href"/>
</xsl:attribute>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:footnote">
<xsl:variable name="fnnum">
<xsl:number level="any"/>
</xsl:variable>
<xsl:element name="sup" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="a" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="href">
<xsl:value-of select="concat('#fn_', $fnnum)"/>
</xsl:attribute>
<xsl:attribute name="name">
<xsl:value-of select="concat('fr_', $fnnum)"/>
</xsl:attribute>
<xsl:value-of select="$fnnum"/>
</xsl:element>
</xsl:element>
</xsl:template>
<xsl:template match="tr:footnote" mode="list">
<xsl:variable name="fnnum">
<xsl:number level="any"/>
</xsl:variable>
<xsl:element name="tr" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="td" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="a" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="name">
<xsl:value-of select="concat('fn_', $fnnum)"/>
</xsl:attribute>
<xsl:attribute name="href">
<xsl:value-of select="concat('#fr_', $fnnum)"/>
</xsl:attribute>
<xsl:number level="any"/>
<xsl:text>.</xsl:text>
</xsl:element>
<xsl:text> </xsl:text>
</xsl:element>
<xsl:element name="td" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:element>
</xsl:template>
<xsl:template match="tr:xref">
<xsl:variable name="notraw" select="not(@raw='true' or @raw=1)"/>
<xsl:variable name="reftext">
<xsl:choose>
<xsl:when test="id(@linkend)">
<xsl:if test="$notraw">
<xsl:apply-templates select="id(@linkend)" mode="label"/>
<xsl:text> </xsl:text>
</xsl:if>
<xsl:apply-templates select="id(@linkend)" mode="number"/>
</xsl:when>
<xsl:otherwise>
<xsl:message terminate="no">
<xsl:text>Cross-reference target not found: </xsl:text>
<xsl:value-of select="@linkend"/>
</xsl:message>
<xsl:element name="strong" namespace="http://www.w3.org/1999/xhtml">
<xsl:text>??</xsl:text>
</xsl:element>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:element name="a" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="href">
<xsl:value-of select="concat('#',@linkend)"/>
</xsl:attribute>
<xsl:choose>
<xsl:when test="descendant::text()">
<xsl:apply-templates/>
<xsl:choose>
<xsl:when test="$notraw">
<xsl:text> (</xsl:text>
<xsl:value-of select="$reftext"/>
<xsl:text>)</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text> </xsl:text>
<xsl:value-of select="$reftext"/>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$reftext"/>
</xsl:otherwise>
</xsl:choose>
</xsl:element>
</xsl:template>
<xsl:template match="tr:cite">
<xsl:element name="a" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="href">
<xsl:value-of select="concat('#', @bibref)"/>
</xsl:attribute>
<xsl:variable name="cit" select="id(@bibref)"/>
<xsl:choose>
<xsl:when test="$cit">
<xsl:apply-templates select="$cit" mode="number"/>
</xsl:when>
<xsl:otherwise>
<xsl:message terminate="no">
<xsl:text>Bibliographic reference not found: </xsl:text>
<xsl:value-of select="@bibref"/>
</xsl:message>
<xsl:text>[??]</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:element>
</xsl:template>
<xsl:template match="tr:biblist">
<xsl:element name="h2" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="id-attribute"/>
<xsl:call-template name="select-local">
<xsl:with-param name="cs">Literatura</xsl:with-param>
<xsl:with-param name="en">References</xsl:with-param>
</xsl:call-template>
</xsl:element>
<xsl:apply-templates select="tr:bibitem"/>
</xsl:template>
<xsl:template match="tr:bibitem">
<xsl:element name="table" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="border">0</xsl:attribute>
<xsl:element name="tbody" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="valign">top</xsl:attribute>
<xsl:element name="tr" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="td" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="a" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="name">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
<xsl:apply-templates select="." mode="number"/>
</xsl:element>
<xsl:text> </xsl:text>
</xsl:element>
<xsl:element name="td" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates/>
</xsl:element>
</xsl:element>
</xsl:element>
</xsl:element>
</xsl:template>
<xsl:template match="tr:tabular">
<xsl:element name="table" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="cellspacing">0</xsl:attribute>
<xsl:attribute name="class">sede blockcenter</xsl:attribute>
<xsl:apply-templates select="tr:tr"/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:tr">
<xsl:element name="tr" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates select="@bgcolor|tr:th|tr:td"/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:th|tr:td">
<xsl:element name="{local-name()}" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates select="@bgcolor|@align|@colspan"/>
<xsl:variable name="colnum">
<xsl:number/>
</xsl:variable>
<xsl:call-template name="col-align">
<xsl:with-param
name="code"
select="substring(ancestor::tr:tabular/@colspec, $colnum, 1)"/>
</xsl:call-template>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="@bgcolor|@align|@colspan">
<xsl:copy/>
</xsl:template>
<xsl:template match="tr:image">
<xsl:variable name="srcfile" select="tr:source[@format='JPEG' or
@format='PNG' or @format='GIF' or
@format='SVG']/@file"/>
<xsl:element name="img" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="src">
<xsl:choose>
<xsl:when test="$srcfile">
<xsl:value-of select="$srcfile[1]"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="tr:source[1]/@file"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:attribute name="alt">[Image]</xsl:attribute>
</xsl:element>
</xsl:template>
<xsl:template match="tr:table|tr:figure">
<xsl:element name="div" namespace="http://www.w3.org/1999/xhtml">
<xsl:attribute name="class">center</xsl:attribute>
<xsl:apply-templates select="@xml:id"/>
<xsl:apply-templates select="tr:p|tr:pre|tr:blockquote|tr:image|
tr:tabular|tr:ol|tr:ul|tr:dl"/>
<xsl:apply-templates select="tr:caption"/>
</xsl:element>
</xsl:template>
<xsl:template match="tr:caption">
<xsl:element name="p" namespace="http://www.w3.org/1999/xhtml">
<xsl:element name="em" namespace="http://www.w3.org/1999/xhtml">
<xsl:apply-templates select="parent::*" mode="label"/>
<xsl:text> </xsl:text>
<xsl:apply-templates select="parent::*" mode="number"/>
<xsl:text>. </xsl:text>
<xsl:apply-templates/>
</xsl:element>
</xsl:element>
</xsl:template>
</xsl:stylesheet>