-
Notifications
You must be signed in to change notification settings - Fork 11
/
ARRAYLIST.RPGLE
766 lines (592 loc) · 23.5 KB
/
ARRAYLIST.RPGLE
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
//***********************************************************************
// MIT License
//
// Copyright (c) 2017 Edoardo Luppi
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to deal
// in the Software without restriction, including without limitation the rights
// to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
// copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in all
// copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
// SOFTWARE.
//
// Original idea by Mihael Schmidt.
// https://github.com/OSSILE
//
// @author Edoardo Luppi
// @description RPG implementation of an ArrayList
//***********************************************************************
ctl-opt nomain option(*srcstmt) bnddir('QC2LE':'UTILS');
dcl-c ARRAY_SIZE %size(arrayTpl);
dcl-c ENTRY_SIZE %size(entryTpl);
dcl-c DEFAULT_SIZE 16;
/include qcopysrc,memcpy
/include qcopysrc,quicksort
/include qcopysrc,utils
dcl-ds arrayTpl qualified template align;
data pointer;
size uns(10);
allocatedSize uns(10);
modCount uns(10);
sortDirection ind;
end-ds;
dcl-ds entryTpl qualified template align;
parentPtr pointer;
objectPtr pointer;
objectSize uns(10);
reservedForAlignment char(12);
end-ds;
//***********************************************************************
// arrayNew
//***********************************************************************
dcl-proc arrayNew export;
dcl-pi *n pointer;
initialSize uns(10) const options(*nopass);
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-s arrayPtr pointer inz(*null);
dcl-s initialSize_ uns(10) inz;
if (%parms > 0);
initialSize_ = initialSize;
else;
initialSize_ = DEFAULT_SIZE;
endif;
allocSpace(arrayPtr:ARRAY_SIZE);
allocSpace(array.data:ENTRY_SIZE * initialSize_);
array.allocatedSize = initialSize_;
array.size = 0;
return arrayPtr;
end-proc;
//***********************************************************************
// arrayDispose
//***********************************************************************
dcl-proc arrayDispose export;
dcl-pi *n;
arrayPtr pointer;
end-pi;
if (arrayPtr <> *null);
arrayClear(arrayPtr);
deallocSpace(arrayPtr);
endif;
end-proc;
//***********************************************************************
// arraySort
//***********************************************************************
dcl-proc arraySort export;
dcl-pi *n;
arrayPtr pointer;
compareProcedure pointer(*proc) const;
direction ind const options(*nopass);
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-s direction_ ind inz(*on);
if (%parms > 2);
direction_ = direction;
endif;
array.sortDirection = direction_;
quickSort(array.data:array.size:ENTRY_SIZE:compareProcedure);
end-proc;
//***********************************************************************
// arraySortNumbers
//***********************************************************************
dcl-proc arraySortNumbers export;
dcl-pi *n;
arrayPtr pointer;
direction ind const options(*nopass);
end-pi;
arraySort(arrayPtr:%paddr(compareNumbers):direction);
end-proc;
//***********************************************************************
// arraySortStrings
//***********************************************************************
dcl-proc arraySortStrings export;
dcl-pi *n;
arrayPtr pointer;
direction ind const options(*nopass);
end-pi;
arraySort(arrayPtr:%paddr(compareStrings):direction);
end-proc;
//***********************************************************************
// arrayTrimToSize
//***********************************************************************
dcl-proc arrayTrimToSize export;
dcl-pi *n;
arrayPtr pointer const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-s allocatedSize uns(10) inz;
if (array.size = 0);
deallocSpace(array.data);
else;
allocSpace(array.data:ENTRY_SIZE * array.size);
endif;
array.allocatedSize = array.size;
end-proc;
//***********************************************************************
// arrayClear
//***********************************************************************
dcl-proc arrayClear export;
dcl-pi *n;
arrayPtr pointer const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
dcl-s i uns(10) inz;
for i = 1 to array.size;
disposeEntryObject(arrayPtr:i);
endfor;
deallocSpace(array.data);
array.size = 0;
array.allocatedSize = 0;
end-proc;
//***********************************************************************
// arraySize
//***********************************************************************
dcl-proc arraySize export;
dcl-pi *n uns(10);
arrayPtr pointer const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
return array.size;
end-proc;
//***********************************************************************
// arrayIsEmpty
//***********************************************************************
dcl-proc arrayIsEmpty export;
dcl-pi *n ind;
arrayPtr pointer const;
end-pi;
return arraySize(arrayPtr) = 0;
end-proc;
//***********************************************************************
// arraySet
//***********************************************************************
dcl-proc arraySet export;
dcl-pi *n;
arrayPtr pointer;
objectPtr pointer const;
objectSize uns(10) const;
index uns(10) const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
entryPtr = getEntry(arrayPtr:index);
allocSpace(entry.objectPtr:objectSize);
memcpy(entry.objectPtr:objectPtr:objectSize);
end-proc;
//***********************************************************************
// arraySetNumber
//***********************************************************************
dcl-proc arraySetNumber export;
dcl-pi *n;
arrayPtr pointer;
numberObject packed(22:7) value;
index uns(10) const;
end-pi;
arraySet(arrayPtr:%addr(numberObject):%size(numberObject):index);
end-proc;
//***********************************************************************
// arraySetString
//***********************************************************************
dcl-proc arraySetString export;
dcl-pi *n;
arrayPtr pointer;
stringObject varchar(32767) value;
index uns(10) const;
end-pi;
arraySet(arrayPtr:%addr(stringObject):%size(stringObject):index);
end-proc;
//***********************************************************************
// arrayRemove
//***********************************************************************
dcl-proc arrayRemove export;
dcl-pi *n;
arrayPtr pointer;
index uns(10) const;
toIndex uns(10) const options(*nopass);
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-s toIndex_ uns(10) inz;
dcl-s positions int(10) inz;
if (%parms > 2);
toIndex_ = toIndex;
else;
toIndex_ = index;
endif;
positions = %int(index) - %int(toIndex_) - 1;
moveEntries(arrayPtr:toIndex_ + 1:positions);
array.size += positions;
end-proc;
//***********************************************************************
// arrayAddAll
//***********************************************************************
dcl-proc arrayAddAll export;
dcl-pi *n;
arrayPtr pointer;
fromArrayPtr pointer const;
index uns(10) const options(*nopass);
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-ds fromArray likeds(arrayTpl) based(fromArrayPtr);
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
dcl-s i uns(10) inz;
if (%parms > 2);
for i = fromArray.size downto 1;
entryPtr = getEntry(fromArrayPtr:i);
arrayAdd(arrayPtr:entry.objectPtr:entry.objectSize:index);
endfor;
else;
for i = 1 to fromArray.size;
entryPtr = getEntry(fromArrayPtr:i);
arrayAdd(arrayPtr:entry.objectPtr:entry.objectSize);
endfor;
endif;
end-proc;
//***********************************************************************
// arrayAdd
//***********************************************************************
dcl-proc arrayAdd export;
dcl-pi *n;
arrayPtr pointer;
objectPtr pointer const;
objectSize uns(10) const;
index uns(10) const options(*nopass);
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
dcl-s index_ uns(10) inz;
dcl-s newSize uns(10) inz;
newSize = array.size + 1;
// Verifico se l'array e' in grado di contenere il nuovo elemento.
// In caso lo ridimensiono.
ensureCapacity(arrayPtr:newSize);
if (%parms > 3);
index_ = index;
else;
index_ = newSize;
endif;
// Verifico se devo inserire l'elemento nel "mezzo" dell'array, e in caso
// traslo gli elementi che vengono dopo.
if (index_ < newSize);
moveEntries(arrayPtr:index_:1);
endif;
// Costruisco il nuovo elemento. A questo punto il dato dovrebbe essere nullo.
entryPtr = getEntry(arrayPtr:index_);
allocSpace(entry.objectPtr:objectSize);
memcpy(entry.objectPtr:objectPtr:objectSize);
entry.objectSize = objectSize;
entry.parentPtr = arrayPtr;
array.size = newSize;
end-proc;
//***********************************************************************
// arrayAddNumber
//***********************************************************************
dcl-proc arrayAddNumber export;
dcl-pi *n;
arrayPtr pointer;
numberObject packed(22:7) value;
index uns(10) const options(*nopass);
end-pi;
if (%parms > 2);
arrayAdd(arrayPtr:%addr(numberObject):%size(numberObject):index);
else;
arrayAdd(arrayPtr:%addr(numberObject):%size(numberObject));
endif;
end-proc;
//***********************************************************************
// arrayAddString
//***********************************************************************
dcl-proc arrayAddString export;
dcl-pi *n;
arrayPtr pointer;
stringObject varchar(32767) value;
index uns(10) const options(*nopass);
end-pi;
if (%parms > 2);
arrayAdd(
arrayPtr:
%addr(stringObject:*data):
%len(stringObject):
index
);
else;
arrayAdd(arrayPtr:%addr(stringObject:*data):%len(stringObject));
endif;
end-proc;
//***********************************************************************
// arrayGet
//***********************************************************************
dcl-proc arrayGet export;
dcl-pi *n pointer;
arrayPtr pointer const;
index uns(10) const;
end-pi;
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
entryPtr = getEntry(arrayPtr:index);
return entry.objectPtr;
end-proc;
//***********************************************************************
// arrayGetNumber
//***********************************************************************
dcl-proc arrayGetNumber export;
dcl-pi *n packed(22:7);
arrayPtr pointer const;
index uns(10) const;
end-pi;
dcl-s object packed(22:7) based(objectPtr);
dcl-s objectPtr pointer inz(*null);
objectPtr = arrayGet(arrayPtr:index);
return object;
end-proc;
//***********************************************************************
// arrayGetString
//***********************************************************************
dcl-proc arrayGetString export;
dcl-pi *n varchar(32767);
arrayPtr pointer const;
index uns(10) const;
end-pi;
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
entryPtr = getEntry(arrayPtr:index);
return %str(entry.objectPtr:entry.objectSize);
end-proc;
//***********************************************************************
// getEntry
//***********************************************************************
dcl-proc getEntry;
dcl-pi *n pointer;
arrayPtr pointer const;
index uns(10) const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
return array.data + (ENTRY_SIZE * (index - 1));
end-proc;
//***********************************************************************
// disposeEntryObject
//***********************************************************************
dcl-proc disposeEntryObject;
dcl-pi *n;
arrayPtr pointer const;
index uns(10) const;
end-pi;
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
entryPtr = getEntry(arrayPtr:index);
if (entry.objectPtr <> *null);
deallocSpace(entry.objectPtr);
endif;
end-proc;
//***********************************************************************
// moveEntries
// IMPORTANT: do not update the size of the array here!
//***********************************************************************
dcl-proc moveEntries;
dcl-pi *n;
arrayPtr pointer;
startIndex uns(10) const;
positions int(10) const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-ds entry likeds(entryTpl) based(entryPtr);
dcl-s entryPtr pointer inz(*null);
dcl-s tempPtr pointer inz(*null);
dcl-s destinationIndex int(10) inz;
dcl-s bytesToCopy uns(10) inz;
dcl-s i uns(10) inz;
// Calcolo l'indice di destinazione;
destinationIndex = startIndex + positions;
select;
when (positions < 0);
// Sto rimuovendo elementi.
// Dealloco gli oggetti che non servono piu'.
for i = destinationIndex to startIndex - 1;
disposeEntryObject(arrayPtr:i);
endfor;
if (startIndex > array.size);
// Ho gia' deallocato tutto e dato che sono gli elementi terminanti dell'array
// quelli con cui ho lavorato, non devo fare altro.
return;
else;
// Elimino (sovrascrivo) elementi all'interno dell'array.
exsr copyBytes;
endif;
// Imposto a null i riferimenti non piu' utilizzabili.
// Non dealloco perche' gli oggetti a cui puntano sono ancora utilizzati.
for i = array.size downto array.size + positions + 1;
entryPtr = getEntry(arrayPtr:i);
entry.objectPtr = *null;
endfor;
when (positions > 0);
// Inserisco nuovi elementi all'interno dell'array.
exsr copyBytes;
// Imposto a null i riferimenti non piu' utilizzabili.
// Non dealloco perche' gli oggetti a cui puntano sono ancora utilizzati.
for i = startIndex to destinationIndex - 1;
entryPtr = getEntry(arrayPtr:i);
entry.objectPtr = *null;
endfor;
other;
endsl;
//*********************************************************************
// copyBytes
//*********************************************************************
begsr copyBytes;
bytesToCopy = ENTRY_SIZE * (array.size - startIndex + 1);
// Alloco uno spazio di memoria temporaneo per copiare gli elementi da spostare.
allocSpace(tempPtr:bytesToCopy);
memcpy(tempPtr:getEntry(arrayPtr:startIndex):bytesToCopy);
// Copio l'area temporanea alla posizione desiderata.
memcpy(
getEntry(arrayPtr:destinationIndex):
tempPtr:
bytesToCopy
);
deallocSpace(tempPtr);
endsr;
end-proc;
//***********************************************************************
// ensureCapacity
//***********************************************************************
dcl-proc ensureCapacity;
dcl-pi *n;
arrayPtr pointer;
elements uns(10) const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
dcl-s allocatedSize int(10) inz;
allocatedSize = array.allocatedSize;
if (elements <= allocatedSize);
return;
endif;
dow (allocatedSize - elements < 0);
allocatedSize += (allocatedSize / 2 * (1 + array.modCount / 10)) + 1;
array.modCount += 1;
enddo;
array.allocatedSize = allocatedSize;
allocSpace(array.data:ENTRY_SIZE * allocatedSize);
end-proc;
//***********************************************************************
// compareNumbers
//***********************************************************************
dcl-proc compareNumbers;
dcl-pi *n int(10);
element1 likeds(entryTpl) const;
element2 likeds(entryTpl) const;
end-pi;
dcl-ds array likeds(arrayTpl) based(element1.parentPtr);
dcl-s number1 packed(22:7) based(element1.objectPtr);
dcl-s number2 packed(22:7) based(element2.objectPtr);
dcl-s result int(3) inz;
if (number1 > number2);
result = 1;
elseif (number1 < number2);
result = -1;
endif;
return getSortResult(result:array.sortDirection);
end-proc;
//***********************************************************************
// compareString
//***********************************************************************
dcl-proc compareStrings;
dcl-pi *n int(10);
element1 likeds(entryTpl) const;
element2 likeds(entryTpl) const;
end-pi;
dcl-ds array likeds(arrayTpl) based(element1.parentPtr);
dcl-s string1 varchar(32767) inz;
dcl-s string2 varchar(32767) inz;
dcl-s result int(3) inz;
string1 = %str(element1.objectPtr:element1.objectSize);
string2 = %str(element2.objectPtr:element2.objectSize);
if (string1 > string2);
result = 1;
elseif (string1 < string2);
result = -1;
endif;
return getSortResult(result:array.sortDirection);
end-proc;
//***********************************************************************
// getSortResult
//***********************************************************************
dcl-proc getSortResult;
dcl-pi *n int(3);
result int(3) const;
direction ind const;
end-pi;
if (direction);
return result;
else;
return -result;
endif;
end-proc;
//***********************************************************************
// rangeCheck
//***********************************************************************
dcl-proc rangeCheck;
dcl-pi *n;
arrayPtr pointer const;
index uns(10) const;
end-pi;
dcl-ds array likeds(arrayTpl) based(arrayPtr);
if (index < 1 or index > array.size + 1);
throwError(
'CPF9999':
'*ESCAPE':
'Index out of bounds exception: ' + %char(index)
);
endif;
end-proc;
//***********************************************************************
// throwError
//***********************************************************************
dcl-proc throwError;
dcl-pi *n;
messageId char(7) const;
messageType char(10) const;
messageText char(250) const options(*varsize);
end-pi;
dcl-pr error extpgm('QMHSNDPM');
messageId char(7) const;
messageFile char(20) const;
messageData char(32767) const options(*varsize);
messageDataLength int(10) const;
messageType char(10) const;
stackEntry char(10) const;
stackCount int(10) const;
messageKey char(4);
errorDs char(32767) options(*varsize);
end-pr;
dcl-ds errorDs qualified inz;
bytesProvided int(10);
bytesAvailable int(10);
end-ds;
dcl-s messageKey char(4) inz;
error(
messageId:
'QCPFMSG *LIBL':
%trim(messageText):
%len(%trim(messageText)):
messageType:
'*':
0:
messageKey:
errorDs
);
end-proc;