From 1a715c8a6380e443e8a47b9aaeec07e86e645372 Mon Sep 17 00:00:00 2001
From: Ian Macalinao <github@igm.pub>
Date: Fri, 23 Feb 2024 11:42:20 +0800
Subject: [PATCH] get stockfish working

---
 nix/home/common.nix                         |  2 +
 nix/nixpkgs/overlays/10-basic.nix           |  2 +
 nix/nixpkgs/overlays/packages/stockfish.nix | 68 +++++++++++++++++++++
 3 files changed, 72 insertions(+)
 create mode 100644 nix/nixpkgs/overlays/packages/stockfish.nix

diff --git a/nix/home/common.nix b/nix/home/common.nix
index 9de17af..53ac554 100644
--- a/nix/home/common.nix
+++ b/nix/home/common.nix
@@ -57,6 +57,8 @@
 
     # formatting
     shfmt
+
+    stockfish
   ];
 
   home.stateVersion = "22.05";
diff --git a/nix/nixpkgs/overlays/10-basic.nix b/nix/nixpkgs/overlays/10-basic.nix
index ba84adc..1fc9c27 100644
--- a/nix/nixpkgs/overlays/10-basic.nix
+++ b/nix/nixpkgs/overlays/10-basic.nix
@@ -6,6 +6,8 @@ self: super: rec {
     sha256 = "1zxgy3znw0i6h1lxhmnx001c1pdcyszwqj8f0d0092nmnngdzsrl";
   };
 
+  stockfish = self.callPackage ./packages/stockfish.nix { };
+
   # cargo-workspaces = self.callPackage ./packages/cargo-workspaces.nix { };
 
   # kitty = super.kitty.overrideAttrs (existing: {
diff --git a/nix/nixpkgs/overlays/packages/stockfish.nix b/nix/nixpkgs/overlays/packages/stockfish.nix
new file mode 100644
index 0000000..ddc662b
--- /dev/null
+++ b/nix/nixpkgs/overlays/packages/stockfish.nix
@@ -0,0 +1,68 @@
+{ lib, stdenv, fetchurl, fetchFromGitHub }:
+
+let
+  # The x86-64-modern may need to be refined further in the future
+  # but stdenv.hostPlatform CPU flags do not currently work on Darwin
+  # https://discourse.nixos.org/t/darwin-system-and-stdenv-hostplatform-features/9745
+  archDarwin = if stdenv.isx86_64 then "x86-64-modern" else "apple-silicon";
+  arch = if stdenv.isDarwin then archDarwin else
+  if stdenv.isx86_64 then "x86-64" else
+  if stdenv.isi686 then "x86-32" else
+  if stdenv.isAarch64 then "armv8" else
+  "unknown";
+
+  nnueFile = "nn-5af11540bbfe.nnue";
+  nnue = fetchurl {
+    name = nnueFile;
+    url = "https://tests.stockfishchess.org/api/nn/${nnueFile}";
+    sha256 = "sha256-WvEVQLv+/LVOOMXdAAyrS0ad+nWZodVb5dJyLCCokps=";
+  };
+in
+
+stdenv.mkDerivation rec {
+  pname = "stockfish";
+  version = "16";
+
+  src = fetchFromGitHub {
+    owner = "official-stockfish";
+    repo = "Stockfish";
+    rev = "sf_${version}";
+    sha256 = "sha256-ASy2vIP94lnSKgxixK1GoC84yAysaJpxeyuggV4MrP4=";
+  };
+
+  # This addresses a linker issue with Darwin
+  # https://github.com/NixOS/nixpkgs/issues/19098
+  preBuild = lib.optionalString stdenv.isDarwin ''
+    sed -i.orig '/^\#\#\# 3.*Link Time Optimization/,/^\#\#\# 3/d' Makefile
+  '';
+
+  postUnpack = ''
+    sourceRoot+=/src
+    echo ${nnue}
+    cp "${nnue}" "$sourceRoot/${nnueFile}"
+  '';
+
+  makeFlags = [ "PREFIX=$(out)" "ARCH=${arch}" "CXX=${stdenv.cc.targetPrefix}c++" ];
+  buildFlags = [ "build" ];
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    homepage = "https://stockfishchess.org/";
+    description = "Strong open source chess engine";
+    longDescription = ''
+      Stockfish is one of the strongest chess engines in the world. It is also
+      much stronger than the best human chess grandmasters.
+    '';
+    maintainers = with maintainers; [ luispedro siraben ];
+    platforms = [
+      "x86_64-linux"
+      "i686-linux"
+      "x86_64-darwin"
+      "aarch64-linux"
+      "aarch64-darwin"
+    ];
+    license = licenses.gpl3Only;
+  };
+
+}