-
Notifications
You must be signed in to change notification settings - Fork 0
/
PTx.a80
1359 lines (1256 loc) · 21 KB
/
PTx.a80
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; ProTracker3 Extreme (P3X) player for ZX Spectrum
; Copyright (c) 2004-2007 S.V.Bulba (http://bulba.untergrund.net)
; formatted for Pasmo by Gasman
; optimized by Cheveron
; sjasmplus adaptation by © 2013 z00m/SinDiKat
; improved by © 2016-2020 mborik/SinDiKat
device zxspectrum128
@NULL = 0
ifndef PUREPLAYER
org #8000
demo di
ld sp,demo
call music_init
demoloop ei
halt
call music_play
jr demoloop
endif
ifndef SINGLESETUP
; bit.0 if you want to play without looping
; bit.1 if you play looped but fadeout after few seconds
; bit.7 is set each time when loop or fadeout was passed
; ...or simplified: 2 - fadeout after loop
; 1 - no loop
; 0 - loop forever
music_setup: db 2
endif
music_init: ld hl,MDLADDR
music_init0: push hl
ld bc,#40 ; look for "by" identifier
add hl,bc
ld a,(hl)
cp 'y'
dec hl
ld a,(hl)
pop hl
jr z,pt3fmt_init
cp 'b'
jr z,pt3fmt_init
ld a,(hl) ; and first byte of PT2 is delay
cp c ; compared to PT3 text identifier
jp c,pt2fmt_init
pt3fmt_init call setmodaddr
push hl
ld de,100
add hl,de
ld a,(hl)
ld (delay),a
push hl
pop ix
add hl,de
ld (CrPsPtr+1),hl
ld e,(ix+2)
add hl,de
inc hl
ld (LPosPtr+1),hl
pop de
ld l,(ix+3)
ld h,(ix+4)
add hl,de
ld (PatsPtr+1),hl
ld hl,#A9
add hl,de
ld (OrnPtrs+1),hl
ld hl,#69
add hl,de
ld (SamPtrs+1),hl
ld a,(ix-87) ; extract version number
sub '0'
jr c,l20
cp 10
jr c,l21
l20: ld a,6
l21: ld (Version+1),a
push af
cp 4
ld a,(ix-1) ; tone table number
rla
and 7
push af
ld hl,#18 + ((smp_-SamCnv-2) << 8) ; jr smp_
ld (SamCnv),hl
ld a,#BA ; cp d
ld (OrnCP),a
ld (SamCP),a
ld a,#7B ; ld a,e
ld (OrnLD),a
ld (SamLD),a
ld a,#87 ; add a,a
ld (SamClc2),a
ld hl,0
ld de,PT3_EmptySmpOrn
ld a,pt3pattdc-ptdecode-2
jr ptx_initcommon
pt2fmt_init: ld (delay),a
push hl
push hl
push hl
inc hl
inc hl
ld a,(hl)
inc hl
ld (SamPtrs+1),hl
ld e,(hl)
inc hl
ld d,(hl)
pop hl
and a
sbc hl,de
call setmodaddr
pop hl
ld de,67
add hl,de
ld (OrnPtrs+1),hl
ld e,32
add hl,de
ld c,(hl)
inc hl
ld b,(hl)
ld e,30
add hl,de
ld (CrPsPtr+1),hl
ld e,a
inc hl
add hl,de
ld (LPosPtr+1),hl
pop hl
add hl,bc
ld (PatsPtr+1),hl
ld a,5
ld (Version+1),a
push af
ld a,2
push af
ld hl,#51CB ; bit 2,c
ld (SamCnv),hl
ld a,#BB ; cp e
ld (OrnCP),a
ld (SamCP),a
ld a,#7A ; ld a,d
ld (OrnLD),a
ld (SamLD),a
ld a,#80 ; add a,b
ld (SamClc2),a
ld hl,#8687 ; add a,a,(hl)
ld de,PT2_EmptySmpOrn
ld a,pt2pattdc-ptdecode-2
ptx_initcommon: ld (PsCalc),hl
ld (ptdecode+1),a
push de
; note table data depacker
ld de,T_PACK
ld bc,T1_+(2*49)-1
tp_0: ld a,(de)
inc de
cp 15*2
jr nc,tp_1
ld h,a
ld a,(de)
ld l,a
inc de
jr tp_2
tp_1: push de
ld d,0
ld e,a
add hl,de
add hl,de
pop de
tp_2: ld a,h
ld (bc),a
dec bc
ld a,l
ld (bc),a
dec bc
sub low (#F8*2)
jr nz,tp_0
ld (GlobalAttn+1),a
ld (chkfadeout+1),a
ld hl,music_setup
res 7,(hl)
ld hl,VARS
ld (hl),a
ld de,VARS+1
ld bc,VAR0END-VARS-1
ldir
inc hl
ld (AdInPtA+1),hl ; ptr to zero
inc a
ld (DelyCnt),a
ld hl,#F001 ; H - CHP.Volume, L - CHP.NtSkCn
ld (ChanA+CHP.NtSkCn),hl
ld (ChanB+CHP.NtSkCn),hl
ld (ChanC+CHP.NtSkCn),hl
pop hl
ld (ChanA+CHP.OrnPtr),hl ; ornament 0 is "0,1,0"
ld (ChanB+CHP.OrnPtr),hl ; in all versions from
ld (ChanC+CHP.OrnPtr),hl ; 3.xx to 3.6x and VTII
pop af
;NoteTableCreator (c) Ivan Roshin
;A - NoteTableNumber*2+VersionForNoteTable
; xx1b - 3.xx..3.4r
; xx0b - 3.4x..3.6x - VortexTracker II
ld hl,nt_data
push de
ld d,b
add a,a
ld e,a
add hl,de
ld e,(hl)
inc hl
srl e
sbc a,a
and #A7 ; #00 (NOP) or #A7 (AND A)
ld (l3),a
ex de,hl
pop bc ; bc = T1_
add hl,bc
ld a,(de)
add a,low T_
ld c,a
adc a,high T_
sub c
ld b,a
push bc
ld de,NT_
push de
ld b,12
l1: push bc
ld c,(hl)
inc hl
push hl
ld b,(hl)
push de
ex de,hl
ld de,#17
ld xh,8
l2: srl b
rr c
l3: add hl,de ; will be replaced by AND A or NOP apparently
ld a,c
adc a,d
ld (hl),a
inc hl
ld a,b
adc a,d
ld (hl),a
add hl,de
dec xh
jr nz,l2
pop de
inc de
inc de
pop hl
inc hl
pop bc
djnz l1
pop hl
pop de
ld a,e
cp low TCOLD_1
jr nz,corr_1
ld a,#FD
ld (NT_+#002E),a
corr_1: ld a,(de)
and a
jr z,tc_exit
rra
push af
add a,a
ld c,a
add hl,bc
pop af
jr nc,corr_2
dec (hl)
dec (hl)
corr_2: inc (hl)
and a
sbc hl,bc
inc de
jr corr_1
tc_exit: pop af
; VolTableCreator (c) Ivan Roshin
; A - VersionForVolumeTable
; (0..4 - v3.xx .. v3.4x
; (5.. - v2.x, v3.5x .. v3.6x (VT2) .. v3.7)
cp 5
ld hl,17
ld d,h
ld e,h
ld a,#17
jr nc,m1
dec l
ld e,l
xor a
m1: ld (m2),a
ld ix,VT_+16
ld c,16
initloop2: push hl
add hl,de
ex de,hl
sbc hl,hl
initloop1: ld a,l
m2: ld a,l
ld a,h
adc a,0
ld (ix+0),a
inc ix
add hl,de
inc c
ld a,c
and 15
jr nz,initloop1
pop hl
ld a,e
cp #77
jr nz,m3
inc e
m3: ld a,c
and a
jr nz,initloop2
jp rout_a0
setmodaddr: ld (modaddr+1),hl
ld (mdaddr1+1),hl
ld (mdaddr2+1),hl
ret
; PT2 pattern decoder ---------------------------------------------------------
pd2_sam call setsam
jr pd2_loop
pd2_eoff ld (ix-12+CHP.Env_En),a
jr pd2_loop
pd2_env ld (ix-12+CHP.Env_En),16
ld (AYREGS+AR_EnvTp),a
ld a,(bc)
inc bc
ld l,a
ld a,(bc)
inc bc
ld h,a
ld (EnvBase),hl
jr pd2_loop
pd2_orn call setorn
jr pd2_loop
pd2_skip inc a
ld (ix-12+CHP.NNtSkp),a
jr pd2_loop
pd2_vol rrca
rrca
rrca
rrca
ld (ix-12+CHP.Volume),a
jr pd2_loop
pd2_del call c_delay
jr pd2_loop
pd2_glis set 2,(ix-12+CHP.Flags)
inc a
ld (ix-12+CHP.TnSlDl),a
ld (ix-12+CHP.TSlCnt),a
ld a,(bc)
inc bc
ld (ix-12+CHP.TSlStp),a
add a,a
sbc a,a
ld (ix-12+CHP.TSlStp+1),a
scf
jr pd2_loop2
pd2_port: res 2,(ix-12+CHP.Flags)
ld a,(bc)
inc bc
inc bc ; ignoring precalc delta to right sound
inc bc
scf
jr pd2_loop2
pd2_stop: ld (ix-12+CHP.TSlCnt),a
jr pd2_loop
pt2pattdc: and a
pd2_loop2: ex af,af'
pd2_loop: ld a,(bc)
inc bc
add a,#20
jr z,pd2_rel
jr c,pd2_sam
add a,96
jr c,pd2_note
inc a
jr z,pd2_eoff
add a,15
jp z,pd_fin
jr c,pd2_env
add a,#10
jr c,pd2_orn
add a,#40
jr c,pd2_skip
add a,#10
jr c,pd2_vol
inc a
jr z,pd2_del
inc a
jr z,pd2_glis
inc a
jr z,pd2_port
inc a
jr z,pd2_stop
ld a,(bc)
inc bc
ld (ix-12+CHP.CrNsSl),a
jr pd2_loop
pd2_rel: ld (ix-12+CHP.Flags),a
jr pd2_exit
pd2_note: ld l,a
ld a,(ix-12+CHP.Note)
ld (PrNote+1),a
ld (ix-12+CHP.Note),l
xor a
ld (ix-12+CHP.TSlCnt),a
set 0,(ix-12+CHP.Flags)
ex af,af'
jr nc,pd2_noglis
bit 2,(ix-12+CHP.Flags)
jr nz,pd2_noport
ld (LoStep+1),a
add a,a
sbc a,a
ex af,af'
ld h,a
ld l,a
inc a
call setport
pd2_noport: ld (ix-12+CHP.TSlCnt),1
pd2_noglis: xor a
pd2_exit: ld (ix-12+CHP.PsInSm),a
ld (ix-12+CHP.PsInOr),a
ld (ix-12+CHP.CrTnSl),a
ld (ix-12+CHP.CrTnSl+1),a
jp pd_fin
ptdecode: jr pt3pattdc ; patter decoder fork
; PT3 pattern decoder ---------------------------------------------------------
PD_OrSm: ld (ix-12+CHP.Env_En),0
call setorn
pd_sam_: ld a,(bc)
inc bc
rrca
pd_sam: call setsam
jr pd_loop
pd_vol: rrca
rrca
rrca
rrca
ld (ix-12+CHP.Volume),a
jr pd_lp2
pd_eoff: ld (ix-12+CHP.Env_En),a
ld (ix-12+CHP.PsInOr),a
jr pd_lp2
pd_SorE: dec a
jr nz,pd_env
ld a,(bc)
inc bc
ld (ix-12+CHP.NNtSkp),a
jr pd_lp2
pd_env: call setenv
jr pd_lp2
pd_orn: call setorn
jr pd_loop
pd_esam: ld (ix-12+CHP.Env_En),a
ld (ix-12+CHP.PsInOr),a
call nz,setenv
jr pd_sam_
pt3pattdc: ld a,(ix-12+CHP.Note)
ld (PrNote+1),a
ld l,(ix-12+CHP.CrTnSl)
ld h,(ix-12+CHP.CrTnSl+1)
ld (PrSlide+1),hl
pd_loop: ld de,#2010
pd_lp2: ld a,(bc)
inc bc
add a,e
jr c,PD_OrSm
add a,d
jr z,pd_fin
jr c,pd_sam
add a,e
jr z,pd_rel
jr c,pd_vol
add a,e
jr z,pd_eoff
jr c,pd_SorE
add a,#60
jr c,pd_note
add a,e
jr c,pd_orn
add a,d
jr c,pd_nois
add a,e
jr c,pd_esam
add a,a
ld e,a
ld hl,spccoms-#20E0
add hl,de
ld e,(hl)
inc hl
ld d,(hl)
push de
jr pd_loop
pd_nois: ld (Ns_base),a
jr pd_lp2
pd_rel: res 0,(ix-12+CHP.Flags)
jr pd_res
pd_note: ld (ix-12+CHP.Note),a
set 0,(ix-12+CHP.Flags)
xor a
pd_res: ld (pdsp_+1),sp
ld sp,ix
ld h,a
ld l,a
push hl
push hl
push hl
push hl
push hl
push hl
pdsp_: ld sp,NULL
pd_fin: ld a,(ix-12+CHP.NNtSkp)
ld (ix-12+CHP.NtSkCn),a
ret
c_portm: ld a,(bc)
inc bc
inc bc ; skip precalculated tone delta
inc bc ; (because cannot be right after pt3 compilation)
ex af,af'
ld a,(bc) ; signed tone step
inc bc
ld (LoStep+1),a
ld a,(bc)
inc bc
and a
ex af,af'
ld l,(ix-12+CHP.CrTnSl)
ld h,(ix-12+CHP.CrTnSl+1)
; Set portamento variables
; A - Delay; A' - Hi(Step); ZF' - (A'=0); HL - CrTnSl
setport res 2,(ix-12+CHP.Flags)
ld (ix-12+CHP.TnSlDl),a
ld (ix-12+CHP.TSlCnt),a
push hl
ld de,NT_
ld a,(ix-12+CHP.Note)
ld (ix-12+CHP.SlToNt),a
add a,a
ld l,a
ld h,0
add hl,de
ld a,(hl)
inc hl
ld h,(hl)
ld l,a
push hl
PrNote: ld a,NULL
ld (ix-12+CHP.Note),a
add a,a
ld l,a
ld h,0
add hl,de
ld e,(hl)
inc hl
ld d,(hl)
pop hl
sbc hl,de
ld (ix-12+CHP.TnDelt),l
ld (ix-12+CHP.TnDelt+1),h
pop de
Version: ld a,NULL
cp 6
jr c,LoStep ; old 3xxx for PT v3.5-
PrSlide: ld de,NULL
ld (ix-12+CHP.CrTnSl),e
ld (ix-12+CHP.CrTnSl+1),d
LoStep: ld a,0 ; signed tone step
ex af,af'
jr z,nosig
ex de,hl
nosig: sbc hl,de
jp p,set_stp
cpl
ex af,af'
neg
ex af,af'
set_stp: ld (ix-12+CHP.TSlStp+1),a
ex af,af'
ld (ix-12+CHP.TSlStp),a
ld (ix-12+CHP.COnOff),0
ret
c_gliss: set 2,(ix-12+CHP.Flags)
ld a,(bc)
inc bc
ld (ix-12+CHP.TnSlDl),a
and a
jr nz,gl36
ld a,(Version+1) ;AlCo PT3.7+
cp 7
sbc a,a
inc a
gl36: ld (ix-12+CHP.TSlCnt),a
ld a,(bc)
inc bc
ex af,af'
ld a,(bc)
inc bc
jr set_stp
c_smpos: ld a,(bc)
inc bc
ld (ix-12+CHP.PsInSm),a
ret
c_orpos: ld a,(bc)
inc bc
ld (ix-12+CHP.PsInOr),a
ret
c_vibrt: ld a,(bc)
inc bc
ld (ix-12+CHP.OnOffD),a
ld (ix-12+CHP.COnOff),a
ld a,(bc)
inc bc
ld (ix-12+CHP.OffOnD),a
xor a
ld (ix-12+CHP.TSlCnt),a
ld (ix-12+CHP.CrTnSl),a
ld (ix-12+CHP.CrTnSl+1),a
ret
c_engls: ld a,(bc)
inc bc
ld (Env_Del+1),a
ld (CurEDel),a
ld a,(bc)
inc bc
ld l,a
ld a,(bc)
inc bc
ld h,a
ld (ESldAdd+1),hl
ret
c_delay: ld a,(bc)
inc bc
ld (delay),a
ld (DelyCnt),a ; bugfix by Lee_dC
ret
setenv: ld (ix-12+CHP.Env_En),e
ld (AYREGS+AR_EnvTp),a
ld a,(bc)
inc bc
ld h,a
ld a,(bc)
inc bc
ld l,a
ld (EnvBase),hl
xor a
ld (ix-12+CHP.PsInOr),a
ld (CurEDel),a
ld h,a
ld l,a
ld (CurESld),hl
c_nop: ret
setorn: add a,a
ld e,a
ld d,0
ld (ix-12+CHP.PsInOr),d
OrnPtrs: ld hl,NULL
add hl,de
ld e,(hl)
inc hl
ld d,(hl)
mdaddr2: ld hl,NULL
add hl,de
ld (ix-12+CHP.OrnPtr),l
ld (ix-12+CHP.OrnPtr+1),h
ret
setsam: add a,a
ld e,a
ld d,0
SamPtrs: ld hl,NULL
add hl,de
ld e,(hl)
inc hl
ld d,(hl)
mdaddr1: ld hl,NULL
add hl,de
ld (ix-12+CHP.SamPtr),l
ld (ix-12+CHP.SamPtr+1),h
ret
; all 16 addresses filled to protect from broken pt3 modules
spccoms: dw c_nop
dw c_gliss
dw c_portm
dw c_smpos
dw c_orpos
dw c_vibrt
dw c_nop
dw c_nop
dw c_engls
dw c_delay
dw c_nop
dw c_nop
dw c_nop
dw c_nop
dw c_nop
dw c_nop
chregs: xor a
ld (Ampl),a
bit 0,(ix+CHP.Flags)
push hl
jp z,ch_exit
ld (csp_+1),sp
ld l,(ix+CHP.OrnPtr)
ld h,(ix+CHP.OrnPtr+1)
ld sp,hl
pop de
ld h,a
ld a,(ix+CHP.PsInOr)
ld l,a
add hl,sp
inc a ; PT2 | PT3
OrnCP: cp d ; cp e | cp d
jr c,ch_orps
OrnLD: ld a,e ; a,d | a,e
ch_orps: ld (ix+CHP.PsInOr),a
ld a,(ix+CHP.Note)
add a,(hl)
jp p,ch_ntp
xor a
ch_ntp: cp 96
jr c,ch_nok
ld a,95
ch_nok: add a,a
ex af,af'
ld l,(ix+CHP.SamPtr)
ld h,(ix+CHP.SamPtr+1)
ld sp,hl
pop de
ld h,0
ld a,(ix+CHP.PsInSm)
ld b,a
add a,a ; PT2 | PT3
SamClc2: add a,a ; a,b | a,a
ld l,a
add hl,sp
ld sp,hl
ld a,b
inc a
SamCP: cp d ; cp e | cp d
jr c,ch_smps
SamLD: ld a,e ; a,d | a,e
ch_smps: ld (ix+CHP.PsInSm),a
pop bc
pop hl
; PT2 | PT3
SamCnv: jr smp_ ; bit 2,c | jr smp_
ld h,b ; Convert PT2 sample to PT3
jr nz,SamCnv1
ex de,hl
and a
sbc hl,hl
sbc hl,de
SamCnv1: ld d,c
rr c
sbc a,a
cpl
and #3E
rr c
rr b
and c
ld c,a
ld a,b
rra
rra
rr d
rra
and #9F
ld b,a
smp_: ld e,(ix+CHP.TnAcc)
ld d,(ix+CHP.TnAcc+1)
add hl,de
bit 6,b
jr z,ch_noac
ld (ix+CHP.TnAcc),l
ld (ix+CHP.TnAcc+1),h
ch_noac: ex de,hl
ex af,af'
ld l,a
ld h,0
ld sp,NT_
add hl,sp
ld sp,hl
pop hl
add hl,de
ld e,(ix+CHP.CrTnSl)
ld d,(ix+CHP.CrTnSl+1)
add hl,de
csp_: ld sp,NULL
ex (sp),hl
xor a
or (ix+CHP.TSlCnt)
jr z,ch_amp
dec (ix+CHP.TSlCnt)
jr nz,ch_amp
ld a,(ix+CHP.TnSlDl)
ld (ix+CHP.TSlCnt),a
ld l,(ix+CHP.TSlStp)
ld h,(ix+CHP.TSlStp+1)
ld a,h
add hl,de
ld (ix+CHP.CrTnSl),l
ld (ix+CHP.CrTnSl+1),h
bit 2,(ix+CHP.Flags)
jr nz,ch_amp
ld e,(ix+CHP.TnDelt)
ld d,(ix+CHP.TnDelt+1)
and a
jr z,ch_stpp
ex de,hl
ch_stpp: sbc hl,de
jp m,ch_amp
ld a,(ix+CHP.SlToNt)
ld (ix+CHP.Note),a
xor a
ld (ix+CHP.TSlCnt),a
ld (ix+CHP.CrTnSl),a
ld (ix+CHP.CrTnSl+1),a
ch_amp: ld a,(ix+CHP.CrAmSl)
bit 7,c
jr z,ch_noam
bit 6,c
jr z,ch_amin
cp 15
jr z,ch_noam
inc a
jr ch_svam
ch_amin: cp -15
jr z,ch_noam
dec a
ch_svam: ld (ix+CHP.CrAmSl),a
ch_noam: ld l,a
ld a,b
and 15
add a,l
jp p,ch_apos
xor a
ch_apos: cp 16
jr c,ch_vol
ld a,15
ch_vol: or (ix+CHP.Volume)
ld l,a
ld h,0
ld de,VT_
add hl,de
ld e,(hl)
GlobalAttn: ld a,0 ; GLOBAL ATTENUATION
cp 8 ; if value of attenuation is higher
jr c,ch_globvol ; then this value we will stop
set 0,c ; also envelopes (bit.0 in flags)...
ch_globvol: sub e
jr c,ch_env
xor a
ch_env: neg
bit 0,c
jr nz,ch_noen
or (ix+CHP.Env_En)
ch_noen: ld (Ampl),a
bit 7,b
ld a,c
jr z,no_ensl
rla
rla
sra a
sra a
sra a
add a,(ix+CHP.CrEnSl)
bit 5,b
jr z,no_enac
ld (ix+CHP.CrEnSl),a
no_enac: ld hl,AddToEn+1
add a,(hl)
ld (hl),a
jr ch_mix
no_ensl: rra
add a,(ix+CHP.CrNsSl)
ld (AddToNs),a
bit 5,b
jr z,ch_mix
ld (ix+CHP.CrNsSl),a
ch_mix: ld a,b
rra
and #48
ch_exit: ld hl,AYREGS+AR_Mixer
or (hl)
rrca
ld (hl),a
pop hl
xor a
or (ix+CHP.COnOff)
ret z
dec (ix+CHP.COnOff)
ret nz
xor (ix+CHP.Flags)
ld (ix+CHP.Flags),a
rra
ld a,(ix+CHP.OnOffD)
jr c,ch_ondl
ld a,(ix+CHP.OffOnD)
ch_ondl: ld (ix+CHP.COnOff),a
ret
;------------------------------------------------------------------------------
music_play: xor a
ld (AddToEn+1),a
ld (AYREGS+AR_Mixer),a
dec a
ld (AYREGS+AR_EnvTp),a
ld hl,DelyCnt
dec (hl)
jp nz,pl2
call chkfadeout
ld hl,ChanA+CHP.NtSkCn
dec (hl)
jr nz,pl1b
AdInPtA: ld bc,NULL
ld a,(bc)
and a
jr nz,pl1a
ld d,a
ld (Ns_base),a
CrPsPtr: ld hl,NULL
inc hl
ld a,(hl)