Tips for working with EXWM

[harmonymjb]

Hello everybody I’ve been using meow for a little while now with exwm and I wanted to share a couple of tips/suggestions.

First of all, I suggest you bind meow-keypad to a non-useful key in exwm-input-global-keys:

In my case, I use F18/XF86Launch9, which I have made a convenient key for me. I think the important thing here is that the key you choose isn’t one that you would normally use in an X application.

(setq exwm-input-global-keys
          `((,(kbd "<XF86Launch9>") . meow-keypad)))

If the key you're using isn't already set to meow-keypad-self-insert, you'll probably want to do that, or bind it to something useful.
Otherwise, spamming <leader> can cause a bad state of nested keypads.

(use-package meow
  :bind
  (:map meow-keypad-state-keymap ("<XF86Launch9>" . meow-keypad-self-insert))
  …)

Second, set the configurations in exwm to always be char-mode.
This makes it so that X windows always take the input, with the exception of being able to launch meow-keypad with our shortcut set above.

(setq exwm-manage-configurations '((t char-mode t)))

And with that, you’ll need a hook like this to allow meow-keypad to take inputs when it’s started.

(add-hook 'meow-keypad-mode-hook
  (lambda ()
    (when (derived-mode-p 'exwm-mode)
      (if meow-keypad-mode
          (exwm-input-grab-keyboard exwm--id)
        (exwm-input-release-keyboard exwm--id)))))

Finally, here is a fix for previews of windows in consult-buffer which I find to be a useful addition, even though this override is needed.
I attempted before with an :after hook, but I found it only worked as expected when I could do the exwm check inside the returned function. Happy to take advice to simplify this. (but at the end of the day it’s an issue in exwm, but I haven’t found a fix on that end yet.)

(defun consult-exwm-preview-fix ()
  "Buffer preview function."
  (let ((orig-buf (current-buffer))
        (orig-prev (copy-sequence (window-prev-buffers)))
        (orig-next (copy-sequence (window-next-buffers)))
        other-win)
    (lambda (action cand)
      (pcase action
        ('exit
         (set-window-prev-buffers other-win orig-prev)
         (set-window-next-buffers other-win orig-next))
        ('preview
         (when (and (eq consult--buffer-display #'switch-to-buffer-other-window)
                    (not other-win))
           (switch-to-buffer-other-window orig-buf)
           (setq other-win (selected-window)))
         (let ((win (or other-win (selected-window)))
               (buf (or (and cand (get-buffer cand)) orig-buf)))
           (when (and (window-live-p win) (buffer-live-p buf))
             (with-selected-window win
               (unless (or orig-prev orig-next)
                 (setq orig-prev (copy-sequence (window-prev-buffers))
                       orig-next (copy-sequence (window-next-buffers))))
               (switch-to-buffer buf 'norecord)
               (when (derived-mode-p 'exwm-mode)
                 (select-window (active-minibuffer-window)))))))))))

  (advice-add
   #'consult--buffer-preview :override #'consult-exwm-preview-fix)

Finally, if you want to run Emacs as an X window in exwm you might try a hack like this:
This allows meow-keypad to run inside a nested Emacs by passing it the leader key with
exwm-input--fake-key. I like to pair with C-<leader> also bound to meow-keypad meaning
with a nested Emacs, <leader> will work on the inner Emacs and C-<leader> will work on the
outer Emacs.

(defun meow-keypad-maybe ()
  (interactive)
  (if (string-match "^e:.*GNU Emacs.*" (buffer-name))
      (exwm-input--fake-key 'XF86Launch9)
    (call-interactively 'meow-keypad)))

(setq exwm-input-global-keys
          `((,(kbd "<XF86Launch9>") . meow-keypad-maybe)
            (,(kbd "C-<XF86Launch9>") . meow-keypad)))

I know this is all a little scrappy, but I wanted to share in case there are others using exwm with meow
and might find these tips useful or want to share some of their own.

[eval-on-point]

Exwm doesn't reliably send my keypad-mode inputs to Emacs with this configuration, especially if Hydras are part of the key sequence or my minibuffer is active and waiting for a completion (using Consult). Have you experienced anything similar? I can attempt to find a reproducible error if not.