How to define "platform-like" postprocessing steps?

[nils-werner]

I would like to build a Qt binary using meson, and compile it for Linux, Windows using MXE, and AppImage using linuxdeployqt. How should I structure my build files to achieve that?

Right now I have

# meson.build
project('gui-qt', 'cpp',)

qt5 = import('qt5')
qt5_dep = dependency('qt5')

gui = executable(
    'gui', [ 'src/gui.cpp' ], dependencies : qt5_dep,
)

and for MXE I have

# mxe-win32.ini
[host_machine]
system = 'windows'
cpu_family = 'x86'
cpu = 'x86_64'
endian = 'little'

[binaries]
ar = 'x86_64-w64-mingw32.static-ar'
c = 'x86_64-w64-mingw32.static-gcc'
cpp = 'x86_64-w64-mingw32.static-g++'
ld = 'x86_64-w64-mingw32.static-ld.bfd'
pkgconfig = 'x86_64-w64-mingw32.static-pkg-config'
strip = 'x86_64-w64-mingw32.static-strip'

What would be the best way to also implement linuxdeployqt? I could add

linuxdeployqt = find_program('./linuxdeployqt-x86_64.AppImage')

appimage = custom_target(
    'appimage',
    input : gui,
    output : 'GUI-x86_64.AppImage',
    command : [linuxdeployqt, '--appimage-extract-and-run', 'appdir/gui', '-unsupported-allow-new-glibc', '-appimage', '-verbose=2'],
)

to my meson.build, but I don't really like it...

1. It requires linuxdeployqt to be available and executable, even if I don't want to use it
2. If I make it optional behind a build option, I would switch to Windows using --cross-file and linuxdeployqt using an entirely different flag --enable-linuxdeployqt, and I would like to keep it more "homogeneous".

Does anyone have an alternative idea?

[eli-schwartz]

• It requires linuxdeployqt to be available and executable, even if I don't want to use it

• If I make it optional behind a build option, I would switch to Windows using --cross-file and linuxdeployqt using an entirely different flag --enable-linuxdeployqt, and I would like to keep it more "homogeneous".

You could make it optional behind:

linuxdeployqt = find_program('linuxdeployqt-x86_64.AppImage', required: false)

if linuxdeployqt.found()
    custom_target(........)
endif

No option needed, but instead it allows running *deployqt iff you have it preinstalled, which for the sake of argument we assume someone intending to do app installer bundles would indeed have it preinstalled.

You may also want to use an alias_target() to allow running ninja deployqt under the same name regardless of OS and output filename.

[nils-werner]

Ah, that's a good hint, thanks! But I also just realized that the *deployqt step is actually a packaging step, so it should be integrated somewhere after meson install. I'll investigate further...

[nils-werner]

I realized that what I'm trying to do is actually packaging, not building, so I ended up with the following structure:

# meson.build
project('gui-qt', 'cpp',)

qt5 = import('qt5')
qt5_dep = dependency('qt5')

gui = executable(
    'gui',
    [ 'src/gui.cpp' ],
    dependencies : qt5_dep,
    install: true,
    install_dir : '/usr/bin/',
)

install_data(
    'appdir/gui.desktop',
    install_dir : '/usr/share/applications/'
)

install_data(
    'appdir/gui.png',
    install_dir : '/usr/share/icons/hicolor/128x128/apps/'
)

and then running

env DESTDIR=appdir meson install
./linuxdeployqt-x86_64.AppImage --appimage-extract-and-run appdir/usr/bin/gui -unsupported-allow-new-glibc -appimage -verbose=2

which neatly separates building and packaging.

[eli-schwartz]

The absolute paths seem unusual. I think you want to use the default executable and install the data to get_option('datadir') / 'applications' etc. Then configure with --prefix=/usr and install to DESTDIR=appdir.

It is mostly the same but also allows users to build and install for local use without using AppImage and without getting issues when --prefix isn't respected.

[nils-werner]

Ah, thanks!

Right now linuxdeployqt is seemingly not even accepting it's own layout and the only layout that's working is

appdir/
├── gui
├── gui.desktop
└── gui.png

so I'm enabling that now with another (ugly) custom option, i.e.

gui = executable(
    'gui',
    [ 'src/gui.cpp', ],
    install: true,
    install_dir : get_option('appdir_layout') ? '/' : get_option('bindir'),
    dependencies : qt5_dep,
)

But thanks for letting me know about option('datadir'), option('bindir') and --prefix, that should make it all much cleaner once that aforementioned bug gets fixed.