Extension points ppx_metaocaml

[lukstafi]

Maybe someone finds this useful: extension points behave a bit better than the original MetaOCaml syntax wrt. editor integration. Example content of ppx_metaocaml.ml:

open Ppxlib

let meta_bracket ~loc ~path:_ (expr: expression) =
   {expr with pexp_attributes=({attr_name={txt="metaocaml.bracket"; loc=loc};
                                attr_loc=loc; attr_payload= PStr []}::expr.pexp_attributes)}
let meta_escape ~loc ~path:_ expr =
   {expr with pexp_attributes=({attr_name={txt="metaocaml.escape"; loc=loc};
                                attr_loc=loc; attr_payload= PStr []}::expr.pexp_attributes)}

let expr_rule name extender =
  Context_free.Rule.extension  @@
  Extension.declare name Extension.Context.expression Ast_pattern.(single_expr_payload __) extender
let rules = [expr_rule "c" meta_bracket; expr_rule "e" meta_escape]

let () =
  Driver.register_transformation
    ~rules
    "ppx_metaocaml"

Dune file:

(library
 (name ppx_metaocaml)
 (kind ppx_rewriter)
 (modules ppx_metaocaml)
 (libraries ppxlib))

Usage e.g. let sum = [%c [%e a_code] + [%e b_code]]
Dune use sites:

(library
 ...
 (preprocess (pps ppx_metaocaml ...))
 ...)

[rr0gi]

Maybe someone finds this useful: extension points behave a bit better than the original MetaOCaml syntax wrt. editor integration.

afaik with .merlin file with EXT meta merlin understands metaocaml code out of the box