How do I use vcpkg with bazel on windows?

[benitogf]

Tried looking for some sample of using a vcpkg installed library from a bazel project but no luck, has anyone tried this?

[igormcoelho]

I haven't yet found good documentation on bazel+vcpkg, so I'll share my working example (for linux and windows).
Please see this repo, for demonstration of usage for GMP library (GMP on linux and MPIR on windows): https://github.com/manydeps/manydeps-gmp
The process is quite simple (example for windows):

1. I have a submodule for vcpkg in my project, under folder "tools/vcpkg"
2. script vcpkg-install.sh will install vcpkg gmp (or mpir) dependencies (vcpkg install --triplet=x64-windows-static)
3. on my WORKSPACE I create a local repository pointing at vcpkg packages folder:

new_local_repository(
    name = "gmp",
    path = "./tools/vcpkg/packages",
    build_file = "gmp.BUILD",
)

3. take a look at the provided gmp.BUILD file, as it provides build recipes for files located at "@gmp://mpir_x64-windows-static/"... I provide example with linkstatic=1 and other locations for linux and osx

cc_library(
    name = "lib",
    srcs = select({
        "@bazel_tools//src/conditions:windows": glob(["mpir_x64-windows-static/lib/**/mpir.lib"]),
        "@bazel_tools//src/conditions:darwin": glob(["gmp_x64-osx/lib/**/*.a"]),
        "//conditions:default": glob(["gmp_x64-linux/lib/**/*.a"]),
    }),
    hdrs = select({
        "@bazel_tools//src/conditions:windows": glob(["mpir_x64-windows-static/include/**/*.h"]),
        "@bazel_tools//src/conditions:darwin": glob(["gmp_x64-osx/include/**/*.h"]),
        "//conditions:default": glob(["gmp_x64-linux/include/**/*.h"]),
    }),
    includes = select({
        "@bazel_tools//src/conditions:windows": ["mpir_x64-windows-static/include/"],
        "@bazel_tools//src/conditions:darwin": ["gmp_x64-osx/include/"],
        "//conditions:default": ["gmp_x64-linux/include/"],
    }),
    visibility = ["//visibility:public"],
    linkstatic = 1
)

4. finally, my dependency just points to target "@gmp//:lib" and that's it!

cc_test(
    name = "my_test",
    srcs = ["manydeps_gmp.test.cpp"],  
    deps = ["@catch2//:catch2_main", "@gmp//:lib"]
)

5. to compile and test:

bazel build ... --config windows
bazel test ... --config windows

I also provide working example with CMake, for a comparison. Good luck!