setFloat sets always 0

[mayio]

Hi,

I have difficutlties to set a float value to firebase. Any value I set results in a "0". Doing the same for "Int" values works fine.

This is the sligtly modified example:

 /**
 * Created by K. Suwatchai (Mobizt)
 *
 * Email: k_suwatchai@hotmail.com
 *
 * Github: https://github.com/mobizt/Firebase-ESP8266
 *
 * Copyright (c) 2023 mobizt
 *
 */

/** This example will show how to access the RTDB in Test Mode (no authentication).
 */

#include <Arduino.h>
#include <WiFi.h>
#include <FirebaseESP32.h>

// Provide the RTDB payload printing info and other helper functions.
#include <addons/RTDBHelper.h>

/* 1. Define the WiFi credentials */
#define WIFI_SSID ""*********"
#define WIFI_PASSWORD ""*********"

/* 2. Define the RTDB URL */
#define DATABASE_URL "*********.europe-west1.firebasedatabase.app" //<databaseName>.firebaseio.com or <databaseName>.<region>.firebasedatabase.app

/* 3. Define the Firebase Data object */
FirebaseData fbdo;

/* 4, Define the FirebaseAuth data for authentication data */
FirebaseAuth auth;

/* Define the FirebaseConfig data for config data */
FirebaseConfig config;

unsigned long dataMillis = 0;
int count = 0;

void setup()
{

    Serial.begin(115200);

    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    Serial.print("Connecting to Wi-Fi");
    while (WiFi.status() != WL_CONNECTED)
    {
        Serial.print(".");
        delay(300);
    }
    Serial.println();
    Serial.print("Connected with IP: ");
    Serial.println(WiFi.localIP());
    Serial.println();

    Serial.printf("Firebase Client v%s\n\n", FIREBASE_CLIENT_VERSION);

    /* Assign the certificate file (optional) */
    // config.cert.file = "/cert.cer";
    // config.cert.file_storage = StorageType::FLASH;

    /* Assign the database URL(required) */
    config.database_url = DATABASE_URL;

    config.signer.test_mode = true;

    /**
     Set the database rules to allow public read and write.

       {
          "rules": {
              ".read": true,
              ".write": true
          }
        }

    */

    // Comment or pass false value when WiFi reconnection will control by your code or third party library e.g. WiFiManager
    Firebase.reconnectNetwork(true);

    // Since v4.4.x, BearSSL engine was used, the SSL buffer need to be set.
    // Large data transmission may require larger RX buffer, otherwise connection issue or data read time out can be occurred.
    fbdo.setBSSLBufferSize(4096 /* Rx buffer size in bytes from 512 - 16384 */, 1024 /* Tx buffer size in bytes from 512 - 16384 */);

    /* Initialize the library with the Firebase authen and config */
    Firebase.begin(&config, &auth);
}

void loop()
{
    const float floatValue = 2.f;

    if (millis() - dataMillis > 5000)
    {
        dataMillis = millis();
        Serial.printf("Set int... %s\n", Firebase.setInt(fbdo, "/test/int", count++) ? "ok" : fbdo.errorReason().c_str());
        Serial.printf("Set float... %s\n", Firebase.setFloat(fbdo, "/test/float", floatValue) ? "ok" : fbdo.errorReason().c_str());
    }
}

The serial console says

Connected with IP: *.*.*.*

Firebase Client v4.4.12

Set int... ok
Set float... ok

But the value in firebase remains 0.

Can someone help me here?

[mobizt]

It is not possible in any way that will be the issue.
And I don't see any issue from my test.

You have to debug your code.

[mobizt]

I see that you are using library incorrectly.

Please read the examples comments carefully and follow.
https://github.com/mobizt/Firebase-ESP32/blob/master/examples/Basic/Basic.ino

[mobizt]

Firebase-ESP32/examples/Basic/Basic.ino

Lines 138 to 143 in 891b780

	void loop()
	{
	// Firebase.ready() should be called repeatedly to handle authentication tasks.
	if (Firebase.ready() && (millis() - sendDataPrevMillis > 15000 || sendDataPrevMillis == 0))

[mayio]

Thank you for your quick reply. Firebase.ready() is not the issue. I tried that. But it didn't help.

I tried may other things so far without luck.

• setDouble
• creating a Json that store the float and setting then the Json
• setting only one float member in the entire database (without the int)

But nope. It overwrites always with a zero. By the way I am using a ESP32C3 (I don't think that is related to the error, but in case)

Setting an

• int
• string
  works nicely.

Do you know any firebase setting that might prevent setting floats? Also unlikely to be the case, but I am clueless by now.

I'll investigate. Again, thanks for looking into it.

[mobizt]

Your code above is the wrong usage. Why it's not relevant?

You should try the basic example first.

And post the result.

Library works on other compiler for other Arduino devices, the float or double is not the issue.

[mayio]

Mh, I think you got me wrong. I tried the example. "Int" works fine. "Float" doesn't. To be more specific. If there is a number stored in firebase, it gets overwritten with a 0, if I use setFloat or setDouble.

Here is the screenshot from firebase of the basic example. The floating point numbers are set to zero

Here is the Serial Monitor output

Set int... ok
Get int... 2
Get int ref... 2
Set float... ok
Get float... 0.00
Set double... ok
Get double... 0.00
Set string... ok
Get string... Hello World!
Update node... ok

I tried setting the float in firebase and reading it with getFloat. This works also nicely.

So only sending floating point numbers doesn't work.

Arduino IDE
Version: 2.2.1
Date: 2023-08-31T14:16:33.536Z
CLI Version: 0.34.0

[mobizt]

I don't get anything wrong because of your post doesn't clear.

And the test result of the basic example is enough to show that is the bug or C++ incompatibility in GCC in ESP32C2 environment that converts float to string incorrectly.

I don't have plan to fix this because it works for almost platforms, but you can try a better new library.

[mayio]

I found the issue in

Firebase-ESP32/src/json/MB_String.h

Line 1521 in 891b780

char *toFloatStr(long double value, int type, int precision)

The trouble is that sprintf always needs "%Lf" formatting when you use a long double parameter. I changed your code like this.

    char *toFloatStr(long double value, int type, int precision)
    {
        int width = type == 0 ? 32 : 64;

        char *t = (char *)newP(width);

        if (t)
        {
            MB_String fmt = MBSTRING_FLASH_MCR("%.");
            fmt += precision;

            if (type < 2)
            {
                fmt += MBSTRING_FLASH_MCR("f");
                sprintf(t, fmt.c_str(), static_cast<double>(value));
            }
            else
            {
                fmt += MBSTRING_FLASH_MCR("Lf");
                sprintf(t, fmt.c_str(), value);
            }

            trim(t);
        }

        return t;
    }

[mayio]

Could you please review it and bring it into the main branch. Thanks a lot.

[mobizt]

Thanks for the fix. I will test this on C3 and other devices too.

I will update and inform you when it was done.

[mayio]

thank you.