pacman.txt

DelVar KClrDraw
10
For(J,1,17
    For(I,−1,0
        Line(8abs(sum(J>{5,8,10,12,14})+AnsI),Ansexpr(sub("00256134241524135",J,1)),8abs(expr(sub("05115443223455555",J,1))+AnsI),Ansexpr(sub("50256134352524246",J,1
    End
End
StorePic 1
Text(−1,34,23,"PA<MAN
Pause 
Repeat I>4
    ClrDraw
    RecallPic 1
    While not(fPart(K/128
        K+1→K
        For(A,1,19
            For(B,1,11
                Pt-On(4A,5B
            End
        End
    End
    Text(57,82,sub(">>>---",I,3
    DelVar B1→A
    34→C
    C→D
    randInt(4,54→E
    D+int(32-randabs(C-E))(1-2int(2rand→F
    StorePic 1
    While abs(C-E)+abs(D-F)>5 and fPart(K/128
        C+(A-3)(A≠1→L
        D+(A-2)(A≠4→M
        not(B→B
        If pxl-Test(5L-4C+3,D
            C→L
        If pxl-Test(C,4M-3D+2
            D→M
        Text(−1,E,F," 
        RecallPic 1
        If B
        Then
            E-(C<E)+(E<C→E
            F-(D<F)+(F<D→F
        End
        Text(−1,C,D," 
        K+pxl-Test(5L-4C+3,4M-3D+2→K
        Text(1,82,K
        StorePic 1
        Text(−1,E,F,"O
        2+remainder(72+M,74→D
        Text(−1,L,D,sub("-!-!>v<^",A+4B,1
        L→C
        0
        If not(fPart(.1C+D/8-.65
            getKey-30
        Ans+7(Ans≤3
        If Ans=75
            Pause 
        If 1≤Ans and Ans≤4
            Ans→A
    End
    I+not(not(fPart(K/128→I
End