Failed to install two version of the same package (collision), is it known issue/limitation?

[amalgame21]

I want to install two version of a package (say hello), one is the standard, the other one is a fork of the standard one (actually just an unmerged pull request).
I use overlays to change the src to the fork repo with overrideAttrs, and change the binary name by
postInstall = "mv $out/bin/hello $out/bin/modified-hello"; with the overrideAttrs
I made a flake to apply this overlay and expose it with the output packages.aarch64-linux.packages.modified-hello

I then use this flake as input (with input name "hello" ) of nix-on-droid's flake, then install it with

environment.packages = [ 
pkgs.hello 
input.hello.packages.aarch64-linux.modified-hello 
];

Then the nix store paths collide with same error code in this issus.
I can install it in this way in other machine running NixOS with no problem.

[Gerschtli]

Please share a minimal reproducible example.

[amalgame21]

The actual packages is yt-dlp.
The flake.nix that I am using:

{
  description = "yt-dlp with threads.net support and instagram fix";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ self.overlays.default ];
        };
      in
      {
        packages = {
          yt-dlp-threads = pkgs.yt-dlp-threads;
          yt-dlp-instagram = pkgs.yt-dlp-instagram;
        };
        apps = {
          yt-dlp-threads = {
            type = "app";
            program = "${pkgs.yt-dlp-threads}/bin/yt-dlp-threads";
          };
          yt-dlp-instagram = {
            type = "app";
            program = "${pkgs.yt-dlp-instagram}/bin/yt-dlp-instagram";
          };
        };
      }
    ))
    // {
      overlays.default = final: prev: {
        # https://github.com/yt-dlp/yt-dlp/pull/9852
        yt-dlp-threads = prev.yt-dlp.overrideAttrs {
          src = prev.fetchFromGitHub {
            owner = "renandecarlo";
            repo = "yt-dlp";
            rev = "6abf89a9c73d171d496ee68091bc0e0c5286d963";
            hash = "sha256-veZA51rXX/zB90B3hMFd36OwCl2otLX8JSHbi1Xr/U4=";
          };
          postInstall = ''
            mv $out/bin/yt-dlp $out/bin/yt-dlp-threads
          '';
        };
        # https://github.com/yt-dlp/yt-dlp/pull/11156
        yt-dlp-instagram = prev.yt-dlp.overrideAttrs {
          src = prev.fetchFromGitHub {
            owner = "tetra-fox";
            repo = "yt-dlp";
            rev = "95581b5b838348ec939a7d8340c6f5c1ebdf54f8";
            hash = "sha256-guDrybg2JYAAwEWodoBD+7nyakeqjFlrb4IWHIjOInY=";
          };
          postInstall = ''
            mv $out/bin/yt-dlp $out/bin/yt-dlp-instagram
          '';
        };
      };
    };
}

I put it in the ~/.config/nix-on-droid/flake.nix as input with name yt-dlp
I install both of them along with the original yt-dlp with

{ inputs, pkgs, system, ... }:

{
  environment.packages = [
  inputs.yt-dlp.packages.${system}.yt-dlp-threads
  inputs.yt-dlp.packages.${system}.yt-dlp-instagram
  pkgs.yt-dlp
];
  system.stateVersion = "24.05";
}

[t184256]

mv $out/bin/yt-dlp $out/bin/yt-dlp-instagram

Yeah, no, that's likely not enough, bin/yt-dlp is not the only contents of that derivation. Please post the actual error message, it probably contains specific paths that collide. One way to avoid that would be wrap it into a wrapper that'd contain just the bin/yt-dlp-renamed thing.

[amalgame21]

One way to avoid that would be wrap it into a wrapper that'd contain just the bin/yt-dlp-renamed thing.

Yes! Thank you so much for your hint!
I didn't notice that even in the NixOS nixos-rebuild, there are tons of paths colliding warning, but NixOS just let me install anyway.
I found the way to wrap only and "exposing" the binary and "hiding" all the dependencies with writeShellScriptBin in nixos discourse, and this is the solution:

{
  description = "yt-dlp with threads.net support and instagram fix";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ self.overlays.default ];
        };
      in
      {
        packages = {
          yt-dlp-threads = pkgs.writeShellScriptBin "yt-dlp-threads" ''
            exec ${pkgs.yt-dlp-threads}/bin/yt-dlp "$@"
          '';
          yt-dlp-instagram = pkgs.writeShellScriptBin "yt-dlp-instagram" ''
            exec ${pkgs.yt-dlp-instagram}/bin/yt-dlp "$@"
          '';
        };
      }
    ))
    // {
      overlays.default = final: prev: {
        # https://github.com/yt-dlp/yt-dlp/pull/9852
        yt-dlp-threads = prev.yt-dlp.overrideAttrs {
          src = prev.fetchFromGitHub {
            owner = "renandecarlo";
            repo = "yt-dlp";
            rev = "6abf89a9c73d171d496ee68091bc0e0c5286d963";
            hash = "sha256-veZA51rXX/zB90B3hMFd36OwCl2otLX8JSHbi1Xr/U4=";
          };
        };
        # https://github.com/yt-dlp/yt-dlp/pull/11156
        yt-dlp-instagram = prev.yt-dlp.overrideAttrs {
          src = prev.fetchFromGitHub {
            owner = "tetra-fox";
            repo = "yt-dlp";
            rev = "95581b5b838348ec939a7d8340c6f5c1ebdf54f8";
            hash = "sha256-guDrybg2JYAAwEWodoBD+7nyakeqjFlrb4IWHIjOInY=";
          };
        };
      };
    };
}

[t184256]

And also your expectations. Like, which one is supposed to get invoked when you run `hello` and why.