build.gradle

buildscript {
  ext.kotlinVersion = '1.6.21'
  repositories {
    google()
    mavenCentral()
  }
  dependencies {
    classpath 'com.android.tools.build:gradle:7.2.0'
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
  }
}

allprojects {
  repositories {
    google()
    mavenCentral()
  }
}

subprojects { project ->
  group = GROUP
  version = VERSION_NAME

  apply plugin: 'checkstyle'

  task checkstyle(type: Checkstyle) {
    configFile rootProject.file('checkstyle.xml')
    source 'src/main/java'
    ignoreFailures false
    showViolations true
    include '**/*.java'

    classpath = files()
  }

  afterEvaluate {
    if (project.tasks.findByName('check')) {
      check.dependsOn('checkstyle')
    }
  }
}

task clean(type: Delete) {
  delete rootProject.buildDir
}

ext {
  minSdkVersion = 8
  targetSdkVersion = 32
  compileSdkVersion = 32
  buildToolsVersion = '33.0.0-rc4'
}

ext.deps = [
    junit             : 'junit:junit:4.13.2',
    truth             : 'com.google.truth:truth:1.1.3',
    robolectric       : 'org.robolectric:robolectric:4.8.1',
    mockito           : "org.mockito:mockito-core:4.5.1",
    json              : "org.json:json:20220320",
    supportAnnotations: 'androidx.annotation:annotation:1.3.0',
    kotlin            : "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlinVersion"
]