build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '2.0.21'
    id 'org.jetbrains.intellij' version '1.15.0'
}

buildDir = 'gradle-build'
version = ext.PluginVersion

compileKotlin {
    kotlinOptions { jvmTarget = "17" }
}

intellij {
    type = 'RD'
    version = "${ProductVersion}"
    downloadSources = false
    instrumentCode = false
}

sourceSets {
    main {
        java.srcDir 'src/rider/main/kotlin'
        resources.srcDir 'src/rider/main/resources'
    }
}

repositories {
    maven { url 'https://cache-redirector.jetbrains.com/intellij-repository/snapshots' }
    maven { url 'https://cache-redirector.jetbrains.com/maven-central' }
}

prepareSandbox {
    def dotNetFiles = [
            "${DotNetOutputDirectory}/${DotNetProjectName}.dll",
            "${DotNetOutputDirectory}/${DotNetProjectName}.pdb",
    ]

    dotNetFiles.forEach({ f ->
        def file = file(f)
        from(file, { into "${rootProject.name}/dotnet" })
    })

    doLast {
        dotNetFiles.forEach({ f ->
            def file = file(f)
            if (!file.exists()) throw new RuntimeException("File ${file} does not exist")
        })
    }
}

wrapper {
    gradleVersion = '8.2.1'
    distributionType = Wrapper.DistributionType.ALL
    distributionUrl = "https://cache-redirector.jetbrains.com/services.gradle.org/distributions/gradle-${gradleVersion}-all.zip"
}