build.gradle

buildscript {
    repositories {
        mavenCentral()
        jcenter()
        maven { url "http://oss.sonatype.org/content/repositories/snapshots/" }
    }
    dependencies {
        classpath 'com.bmuschko:gradle-nexus-plugin:2.3.1'
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.21.0"
    }
}

apply plugin: 'maven'
apply plugin: 'java-library'
apply plugin: 'com.bmuschko.nexus'
apply plugin: 'io.codearte.nexus-staging'
apply from: 'publish.gradle'

sourceCompatibility = 1.8

def projectName = 'pie-menu'
version '5.0.0'
group 'com.payne.games'

def gdxVersion = '1.9.10'
def shapedrawerVersion = '2.3.0'

// Disable JDK 8's doclint
// http://blog.joda.org/2014/02/turning-off-doclint-in-jdk-8-javadoc.html
if (JavaVersion.current().isJava8Compatible()) {
    allprojects {
        tasks.withType(Javadoc) {
            // The -quiet is because of some sort of weird JDK JavaCompiler bug:
            // https://discuss.gradle.org/t/passing-arguments-to-compiler-and-javadoc/1661
            options.addStringOption('Xdoclint:all,-missing', '-quiet')
        }
    }
}

jar {
    baseName = projectName
    manifest {
        attributes 'Implementation-Title': projectName, 'Implementation-Version': version
    }
}

repositories {
    mavenLocal()    // you might want to remove this if you have issues resolving deps
    mavenCentral()
    maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
    maven { url 'https://jitpack.io' }
    jcenter()       // always last, due to potential for spoofing otherwise
}

dependencies {
    api "com.badlogicgames.gdx:gdx:$gdxVersion"
    api "space.earlygrey:shapedrawer:$shapedrawerVersion"
    testImplementation "com.badlogicgames.gdx:gdx-backend-lwjgl:$gdxVersion"
    testImplementation "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
}