From 00af9dc96c913df6d67fb473e12d64a8c626bd73 Mon Sep 17 00:00:00 2001
From: "Rick Farina (Zero_Chaos)" <zerochaos@gentoo.org>
Date: Fri, 7 Jun 2024 08:58:20 -0400
Subject: [PATCH] chirp: add python 3.12 basically untested

---
 media-radio/chirp/Manifest              |  1 +
 media-radio/chirp/chirp-20240404.ebuild | 61 +++++++++++++++++++++++++
 media-radio/chirp/metadata.xml          | 11 +++++
 3 files changed, 73 insertions(+)
 create mode 100644 media-radio/chirp/Manifest
 create mode 100644 media-radio/chirp/chirp-20240404.ebuild
 create mode 100644 media-radio/chirp/metadata.xml

diff --git a/media-radio/chirp/Manifest b/media-radio/chirp/Manifest
new file mode 100644
index 0000000000..02d5b2d010
--- /dev/null
+++ b/media-radio/chirp/Manifest
@@ -0,0 +1 @@
+DIST chirp-20240404.tar.gz 1973257 BLAKE2B 566c0ed4ff9b0fe03bb1863e402b27b1b9a29c50b5467ca22bedf62e3b5584e82cde0c8cd430b92a223e0720e6b8c4ed5aa6b6632f660d7a01fc2f8dc7c78af9 SHA512 fc975eca574f2a230caeae7479675749b9d74340ebd7352069e4c51410b4c7c082f6fa3c027c499cdd58eed40479d1c4bfef75d29f2c4f809c88b4f8018f1feb
diff --git a/media-radio/chirp/chirp-20240404.ebuild b/media-radio/chirp/chirp-20240404.ebuild
new file mode 100644
index 0000000000..c9efe31165
--- /dev/null
+++ b/media-radio/chirp/chirp-20240404.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# py3.12 blocked by wxpython
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="A free, open-source tool for programming your radio"
+HOMEPAGE="https://chirpmyradio.com/"
+SRC_URI="https://archive.chirpmyradio.com/${PN}_next/next-${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gui radioreference"
+
+RDEPEND="$(python_gen_cond_dep '
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	gui? (
+		dev-python/wxpython:4.0[${PYTHON_USEDEP}]
+		dev-python/yattag[${PYTHON_USEDEP}]
+	)
+	radioreference? ( dev-python/suds-community[${PYTHON_USEDEP}] )
+')"
+BDEPEND="test? ( $(python_gen_cond_dep '
+	dev-python/ddt[${PYTHON_USEDEP}]
+	dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+') )"
+
+distutils_enable_tests pytest
+
+# The alias map is an internal developer file not included in release tarballs.
+# Other disabled tests require Internet access.
+EPYTEST_DESELECT=(
+	tests/unit/test_directory.py::TestAliasMap
+	tests/unit/test_network_sources.py
+	tests/unit/test_repeaterbook.py
+)
+
+python_test() {
+	# From the contents of tests/ upstream currently only runs unit and driver
+	# tests, and the latter can take so long that they have even got a special
+	# script for only running them on drivers whose code has changed
+	# with respect to origin/master.
+	epytest tests/unit/
+}
+
+src_install() {
+	distutils-r1_src_install
+	if ! use gui; then
+		rm "${ED}"/usr/bin/${PN} || die
+	fi
+}
diff --git a/media-radio/chirp/metadata.xml b/media-radio/chirp/metadata.xml
new file mode 100644
index 0000000000..335c391230
--- /dev/null
+++ b/media-radio/chirp/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<stabilize-allarches/>
+	<use>
+		<flag name="radioreference">pull in optional deps for query of radioreference</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">kk7ds/chirp</remote-id>
+	</upstream>
+</pkgmetadata>