build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
}

group 'com.github.pvriel'
version '1.2.1'

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

repositories {
    mavenLocal()
    mavenCentral()

    maven {
        url = uri("https://maven.pkg.github.com/pvriel/mpcutils4j")
        credentials {
            username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
            password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
        }
    }
}

dependencies {
    implementation 'com.github.pvriel:mpcutils4j:1.3.2'

    testImplementation "org.apache.commons:commons-lang3:3.+"
    testImplementation "org.junit.jupiter:junit-jupiter-api:5.+"
    testImplementation "org.junit.jupiter:junit-jupiter:5.+"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.+"
}

test {
    useJUnitPlatform()
}

java {
    withSourcesJar()
    withJavadocJar()
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/pvriel/PRF4J")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
                password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
            }
        }
    }
    publications {
        gpr(MavenPublication) {
            from(components.java)
        }
    }
}