build.gradle

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'idea'

group = 'com.CSV'
version = '1.1'
ext.packaging = 'jar'

def isDevBuild
def isCiBuild
def isReleaseBuild

def sonatypeRepositoryUrl

//set build variables based on build type (release, continuous integration, development)
if(hasProperty("release")) {
    isReleaseBuild = true
    sonatypeRepositoryUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
} else if (hasProperty("ci")) {
    isCiBuild = true
    version += "-SNAPSHOT"
    sonatypeRepositoryUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
} else {
    isDevBuild = true
}


repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    compile fileTree(dir: 'csvreaderwriter', include: ['*.jar'])
    compile "au.com.bytecode:opencsv:2.4"
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}

task sourceJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allJava
}

artifacts {
    archives jar
    archives javadocJar
}

//********* artifact signing *********
if(isReleaseBuild) {
    signing {
        sign configurations.archives
    }
} else {
    task signArchives {
        // do nothing
    }
}

uploadArchives {
    repositories {
        if (isDevBuild) {
            mavenLocal() //publish artifacts to local maven repo
        } else {
            mavenDeployer {
                if (isReleaseBuild) {
                    beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
                }

                repository(url: sonatypeRepositoryUrl) {
                    authentication(userName: sonatypeUsername, password: sonatypePassword)
                }

                pom.project {
                    name 'csvreaderwriter'
                    packaging 'jar'
                    description 'csvreaderwriter is a utility library allowing users to read and write to/from tab separated csv values.'
                    url ''

                    scm {
                        url 'scm:git@github.com:rahulmcs/csvreaderwriter.git'
                        connection 'scm:git@github.com:rahulmcs/csvreaderwriter.git'
                        developerConnection 'scm:git@github.com:rahulmcs/csvreaderwriter.git'
                    }

                    licenses {
                        license {
                            name 'The Apache Software License, Version 2.0'
                            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                            distribution 'repo'
                        }
                    }

                    developers {
                        developer {
                            id 'rahulmcs'
                            name 'Rahul Chaudhari'
                        }
                    }
                }
            }
        }
    }
}