build.gradle

// create a runnable jar with jar dependencies stored in lib subdirectory
tasks.whenTaskAdded { task ->
    ['startScripts', 'distTar'].each { String skipTaskName ->
        if (task.name.contains(skipTaskName)) {
            task.enabled = false
        }
    }
}
apply plugin: 'java'
apply plugin: 'application'

java {
    sourceCompatibility = 17
    targetCompatibility = 17
}
mainClassName = 'edu.mcw.rgd.pipelines.QtlRsoAnnotation'
String myAppName = 'qtl-rso-annotation-pipeline'

project.archivesBaseName = myAppName

repositories {
    mavenCentral()
}

dependencies {
    implementation ('org.apache.commons:commons-dbcp2:2.11.0') {
        exclude group: 'commons-logging', module: 'commons-logging'
    }
    implementation 'org.apache.logging.log4j:log4j-core:2.23.0'
    implementation 'com.oracle.database.jdbc:ojdbc10:19.23.0.0'
    implementation 'org.springframework:spring-jdbc:6.1.4'

    implementation fileTree(dir: 'lib', include: '*.jar')
}

jar {
    manifest {
        attributes(
            'Built-By': System.getProperty('user.name'),
            'Built-Date': new Date(),
            'Built-JDK': System.getProperty('java.version'),
            'Class-Path': configurations.runtimeClasspath.collect { it.getName() }.join(' '),
            'Main-Class': mainClassName
        )
    }
}

distributions {
    main {
        distributionBaseName = myAppName
    }
}

task createDistro(type: Copy) {
    def zipFile = file('build/distributions/'+myAppName+'.zip')
    def outputDir = file("build/install")

    from zipTree(zipFile)
    into outputDir
}
createDistro.dependsOn assembleDist