build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

plugins {
    alias libs.plugins.android.application apply false
    alias libs.plugins.android.library apply false
    alias libs.plugins.kotlin.android apply false
    alias libs.plugins.benManes.versions apply true
}

// load secrets.properties for properties that should be part of app but not in source control
// maybe shouldn't be done in-line but somewhere else.
def secretProperties = new Properties()
def secretPropertiesFile = file('secrets.properties')
if (!secretPropertiesFile.exists()) {
    logger.error("App will not work as expected. Please copy-paste 'secrets.example.properties'" +
            " to a new file called 'secrets.properties' and add API keys to it")
} else {
    secretProperties.load(secretPropertiesFile.newReader())
}

ext {
    // set keys from secretProperties
    keys = [

            google: [
                    /*
                     * must define Google Maps API Debug Key in gradle.properties by adding google_maps_api_debug=<KEY>
                     * must have a project in Google Console Developers and add the correct key: https://console.developers.google.com
                     * The SHA1 key from Android Studio's debug keystore. Find this in by the following in the command line:
                     * `keytool -list -v -keystore ~/.android/debug.keystore -alias androiddebugkey -storepass android -keypass android`
                     */
                    maps: [
                            debug: "\"${System.getenv("GOOGLE_MAPS_API_DEBUG") ?: secretProperties['google_maps_api_debug']}\"" ?: '"Define Google Maps Debug API Key in secrets.properties#google_maps_api_debug"',
                            release: "\"${System.getenv("GOOGLE_MAPS_API_RELEASE") ?: secretProperties['google_maps_api_release']}\"" ?: '"Define Google Maps Release API Key in secrets.properties#google_maps_api_release"'
                    ]
            ],
            /*
             * must define PAT_API_KEY in gradle.properties by adding pat_api=<KEY>
             */
            truetime: [
                    debug: System.getenv("PAT_API_DEBUG") ?: secretProperties['pat_api_debug'] ?: 'Define Port Authority TrueTime API Key in secrets.properties#pat_api_debug',
                    release: System.getenv("PAT_API_RELEASE") ?: secretProperties['pat_api'] ?: 'Define Port Authority TrueTime API Key in secrets.properties#pat_api'
            ]
    ]

    // versions not defined in gradle/libs.versions.toml
    versions = [
            java: [
                    languageVersion: JavaLanguageVersion.of(8),
                    target: JavaVersion.VERSION_1_8,
                    version: "1.8",
            ],
            android: [
                    buildTools: '33.0.2',
                    minSdk: 21,
                    targetSdk: 33
            ],

    ]
}