Twin-Baston.AMOS.asc

'
'                     Twin Baston "Plus" 
'                    ~~~~~~~~~~~~~~~~~~~~
'  ©1992-1993 PowerMob Productions & Ronan Amicel ( Mr Reed )
'
'
'       < < < < < <   H I S T O R I Q U E   > > > > > >
'
'
' 10.01.93 - v1.00 - Mise sur 2 disks, exploitation de la RAM supplémentaire 
'                    Adaptation aux machines rapides.
' 10.02.93 - v1.02 - Début d'implémentation des tableaux 6.0 
' 11.02.93 - v1.02 - Débuggage 
' 12.02.93 - v1.03 - Accéléré la boucle principale ( Forbid )
' 14.02.93 - v1.04 - Utilisation des tableaux au format 6.1
' 25.02.93 - v1.05 - Relevé la limite du nb de tableaux, supprimé deux bugs. 
' 13.03.93 - v1.06 - Sélection après une partie. Remis aff. mémoire et 
'                    ajouté listbank ( F9 et F8 )
' 14.03.93 - v1.07 - Optimisé un peu la boucle principale. ( certains tests
'                    étaient effectués inutilement ) 
' 19.03.93 - v1.08 - Réorganisé les options ( on doit gagner du temps de 
'                    de chargement ) 
' 21.03.93 - v1.08 - Fini de trafiquer les options. Mode user ( B )
' 24.03.93 - v1.09 - Débuggé: les icônes des modes A et B étaient inversées
'                    Réorganisé les banques: plus de chrg pour les options.
' 30.03.93 - v1.10 - Débuggage. En espérant que tout marche maintenant...
' 31.03.93 - v1.10 - Juste un petit bug dans les options enlevé! 
'
' 03.04.93 - v1.11 - Rajouté Super-Tennis 1982 ( génial! ) et mis en place 
'                    une pro pour SF3 ( affiche juste images ) 
' 07.04.93 - v1.12 - Code spécial "GAME", et détecte "Plus de tableaux"
' 14.04.93 - v1.13 - Intégré mon nouveau Pak-Man. Génial. ( non ? )
' 02.05.93 - v1.13 - Débuggé le Pak-Man. Il plantait assez zarbiment.
'                    Commencé Lemmingsator II
' 06.05.93 - v1.14 - Continué Lemm... - Changé le Pak-Man aussi. 
' 09.05.93 - v1.14 - Bricolage...  Commencé Hyper Aleste.
' 17.05.93 - v1.15 - Rajouté nouveaux bonus. 
'
' 21.05.93 - v1.20 - Suite à des demandes, rajouté contrôle au clavier.
' 22.05.93 - v1.21 - Changé de méthode ( des caractères sautaient )
' 02.06.93 - v1.22 - Plein de nouveaux sons ajoutés !
' 11.06.93 - v1.23 - Oh putain! 5 mois! Rajouté image dans l'intro 
'                    et contrôle clavier dans les mini-jeux. 
'
Set Buffer 30
Dim C(14,14),C2(14,14)
Global C(),C2()
Dim HISCORE(10),HISCORE$(10),HIMODE(10)
Dim SQ$(30),NBSQ(5)
Dim MX(5),MY(5),MA(5,20),MH(5,20),MV(5,20),MT(5,20)
Dim ENNEMI(5),DANSLESPOMMES(5)
Dim TRESOR(5),TRESOR_TOMBE(5)
Dim JOUEUR(2),TIR(2),SCORE(2),VICT(2)
Dim TEMPS(2),MXTEMPS(2),LONGTEMPS(2)
Dim STATE(2),FASTX(2),FASTY(2),INV(2),SUPER(2),PANOU(2),FBALL(2),MVT(2)
Dim SECRET1$(19),SECRET2$(19)
Dim QB(205),BON_DEL(3),BON_RES(3)

If Upper$(Command Line$)="SPEED" Then A1200=True Else A1200=False

Restore DT
For I=1 To 30
   Read SQ$(I)
Next I

Restore BON
I=1
Do 
   Read N
   Exit If N=-1
   Read B
   For J=I To I+N-1
      QB(J)=B
   Next J
   Add I,N
Loop 

Restore SECRET1
For I=0 To 9
   Read SECRET1$(I)
Next I

Restore SECRET2
For I=0 To 10
   Read SECRET2$(I)
Next I

C$="0000"
LEVMAX=100

JOUEUR(1)=1
JOUEUR(2)=2
TIR(1)=3
TIR(2)=4
ENNEMI(1)=5
ENNEMI(2)=6
ENNEMI(3)=7
ENNEMI(4)=8
ENNEMI(5)=9
TRESOR(1)=10
TRESOR(2)=11
TRESOR(3)=12
TRESOR(4)=13
TRESOR(5)=14
BONUS=15
STANDING=0
WALKING=1
JUMPING=2
FALLING=3
GAUCHE=-1
DROITE=1
MSG_OH_NO=1
MSG_GAME_OVER=2
MSG_GET_READY=3
MSG_WINNER=4
MSG_EGALITE=5
MSG_BONUS=6
MSG_GOOD_JOB=7
MSG_SELECT=8
MSG_SCORES=9
DEPART=21
FLAGCODE=1
BON_DEL(1)=50
BON_DEL(2)=100
BON_DEL(3)=200
BON_RES(1)=100
BON_RES(2)=250
BON_RES(3)=420

Proc INIT
If Screen>=0
   Fade 1
   Wait 16
   For X=320 To 0 Step -8
      Screen Offset 1,X,0
      Wait Vbl 
   Next X
   For X=0 To 320 Step 8
      Screen Offset 0,X,0
      Wait Vbl 
   Next X
   Screen Close 0
   Screen Close 1
   Screen Close 2
End If 
Auto View Off 
Wait Vbl 
Screen Open 0,320,256,32,Lowres
Screen Display 0,128,40,320,256
Curs Off 
Flash Off 
Hide On 
Cls 0
Double Buffer 
Auto View On 
Wait Vbl 
Make Mask 
'         Boucle principale
PROUT:
Autoback 2
Proc PRESENTATION
Erase 9
Erase 10

PROUT2:
Do 
   SPEND
   Proc OPTIONS
   Exit If C$<>"GAME"
   GAME
Loop 

PROUT3:
If FLAGCODE=PARTIE Then LEVEL=DEPART Else LEVEL=21

MEMORY=0
CREDITS=3
SCORE(1)=0
SCORE(2)=0
VICT(1)=0
VICT(2)=0
For I=1 To 5
   DANSLESPOMMES(I)=0
Next I

Proc MUSIQUE[2,0]
Music Off 
QUELLEZIK=2
_LOAD["Twin2:Samples-Jeu1.Abk",5]

Proc VERIF[LEVEL]
If Param=False
   WELLDONE
   CREDITS=0
   Goto FINI
End If 
Proc _MESSAGE[MSG_GET_READY,0]
Proc CH61[LEVEL]
If MEMORY<>IMGBACK
   _LOAD[("Twin2:Img-Back"+Str$(IMGBACK)+".Abk")-" ",9]
   MEMORY=IMGBACK
End If 
SP[3]
Wait 100
Timer=0
Clear Key 
Repeat 
   Multi Wait 
Until Fire(1) or Fire(0) or(Len(Inkey$)>0) or(Timer>=400)
Fade 1
Wait 15
Volume 0
Sam Bank 5
SPEND
Bob Off 
Cls 0
'    Boucle de jeu (tant que crédits)
DEBUT:

PASSE=0
HURRY=0
BONUSWAIT=0
CLAVIER=0
K=0
If PARTIE=1
   If LEVEL>=45
      CHEAT=False
   End If 
End If 

MORT1=0
PARALIZED1=0
STATE(1)=STANDING
SENS1=DROITE
LONGTEMPS(1)=0
RAMENE1=0
CARRY1=0
EMPJP1=0
GLOUGLOU1=0
POUM1=0
PANOU(1)=0
FASTX(1)=0
FASTY(1)=0
INV(1)=0
SUPER(1)=0
FBALL(1)=0
MVT(1)=0
LOCK1=0

MORT2=0
PARALIZED2=0
STATE(2)=STANDING
SENS2=GAUCHE
LONGTEMPS(2)=0
RAMENE2=0
CARRY2=0
EMPJP2=0
GLOUGLOU2=0
POUM2=0
PANOU(2)=0
FASTX(2)=0
FASTY(2)=0
INV(2)=0
SUPER(2)=0
FBALL(2)=0
MVT(2)=0
LOCK2=0

Proc INIT_TABLEAU

_FORBID

VOIX1=%1
VOIX2=%10

Wait Vbl 
For I=1 To NBMONSTRES+4
   Amal On I
Next I
Synchro Off 
Randomize Timer
Timer=0
TEMPSTOTAL=0

If PARTIE=2
   '  Mode 2 joueurs
   Repeat 
      ' Sticks & Clavier 
      Gosub CONTROLE
      
      ' JOUEUR 1 
      If MORT1=False
         
         Gosub J1
         
         If Bob Col(JOUEUR(1),BONUS To BONUS)
            Proc EFFET_BONUS[1]
            Bob BONUS,,300,
            BONUSWAIT=-BON_DEL(BONUSDELAI)
         End If 
         
         If CARRY1=0
            If Bob Col(JOUEUR(1),TRESOR(1) To TRESOR(NBTRESORS))
               For I=1 To NBTRESORS
                  Exit If Col(TRESOR(I))
               Next I
               CARRY1=I
               TRESOR_TOMBE(CARRY1)=0
               Bob Off TRESOR(CARRY1)
               Proc UPDSCORE[1,500]
               Sam Play VOIX1,2
            End If 
         End If 
         
         If X1=16 and Y1=223
            
            If CARRY1>0
               CARRY1=0
               Inc RAMENE1
               Proc UPDSCORE[1,1500]
               If RAMENE1+RAMENE2=NBTRESORS
                  PASSE=True
               End If 
               Sam Play VOIX1*8,2
            End If 
            
            If MVT(1)=2
               If PARALIZED1=0
                  If GLOUGLOU1=0
                     Limit Bob 1,0,0 To 256,224
                     Sam Play VOIX1,3
                     GLOUGLOU1=1
                     Amal 1,"Anim 0,(209,2)(210,2)(211,2)(210,2);"
                     Amal On 1
                     Amal 12,"Pause;Pause;Let X=-100;"
                     Amal On 12
                     SENS1=GAUCHE
                  End If 
                  If HURRY=False
                     Inc TEMPS(1)
                     TEMPS(1)=Min(TEMPS(1),MXTEMPS(1))
                     Ink 4
                     TP=208-TEMPS(1)
                     Draw 1,TP+1 To 14,TP+1
                     Draw 1,TP To 14,TP
                     If MEMETEMPS
                        Draw 241,TP+1 To 254,TP+1
                        Draw 241,TP To 254,TP
                     End If 
                  End If 
               End If 
            Else 
               If GLOUGLOU1=1
                  J1_ANIM
               End If 
            End If 
         End If 
         
         If Bob Col(TIR(1),ENNEMI(1) To ENNEMI(NBMONSTRES))
            For I=ENNEMI(1) To ENNEMI(NBMONSTRES)
               Exit If Col(I)
            Next I
            If DANSLESPOMMES(I-4)=False
               DANSLESPOMMES(I-4)=200
               Amal Freeze I
               Bob TIR(1),,320,
               Shoot 
               Proc UPDSCORE[1,10]
            End If 
         End If 
         
         If MORT2=False
            If(PARALIZED2=0) or((PARALIZED2>0) and(PANOU(2)=True))
               If Bob Col(TIR(1),JOUEUR(2) To JOUEUR(2))
                  PARALIZED2=1
                  PANOU(2)=False
                  Amal Freeze 2
                  Amal On 11
                  Bob TIR(1),,320,
                  Sam Play VOIX2,5
                  Proc UPDSCORE[1,50]
               End If 
            End If 
         End If 
         
         If SUPER(1)=False
            If Bob Col(JOUEUR(1),ENNEMI(1) To ENNEMI(NBMONSTRES))
               Gosub BUTE1
            End If 
         End If 
         
         If TEMPS(1)=0
            Gosub BUTE1
         End If 
      End If 
      ' JOUEUR 2 
      If MORT2=False
         X2=X Bob(2)
         Y2=Y Bob(2)
         X=X2/16
         Y=Y2/16
         
         If PARALIZED2>0
            Inc PARALIZED2
            If PARALIZED2=200
               PARALIZED2=0
               PANOU(2)=False
               Amal Freeze 11
               J2_ANIM
               UPDSCORE[0,0]
            End If 
            ' Saut en cours
            If STATE(2)=JUMPING
               If FASTY(2)=True
                  Add JUMP2,2
               Else 
                  Inc JUMP2
               End If 
               If Y2 mod 16=15
                  If Y>=1
                     If(C(X,Y)=13) or(C((X2+15)/16,Y)=13)
                        JUMP2=17
                     End If 
                  End If 
               End If 
               If JUMP2<17
                  If FASTY(2)=True
                     Add Y2,-4
                  Else 
                     Add Y2,-2
                  End If 
               Else 
                  If FASTY(2)=1
                     FASTY(2)=True
                  End If 
                  If Y2<10
                     STATE(2)=FALLING
                     FALL2=0
                     LONGTEMPS(2)=1
                  Else 
                     If(C(X,Y+1)>0) or(C((X2+15)/16,Y+1)>0)
                        STATE(2)=FALLING
                        FALL2=0
                        LONGTEMPS(2)=1
                     Else 
                        If(C(X,Y+2)>0) or(C((X2+15)/16,Y+2)>0)
                           STATE(2)=STANDING
                        Else 
                           STATE(2)=FALLING
                           FALL2=0
                           LONGTEMPS(2)=1
                        End If 
                     End If 
                  End If 
               End If 
            Else 
               ' Tombe
               If STATE(2)=FALLING
                  Inc FALL2
                  If FALL2<9
                     Add Y2,2
                  Else 
                     If Y2=223
                        STATE(2)=STANDING
                        LONGTEMPS(2)=0
                     Else 
                        If(C(X,Y+2)>0) or(C((X2+15)/16,Y+2)>0)
                           STATE(2)=STANDING
                           LONGTEMPS(2)=0
                        Else 
                           FALL2=0
                           Inc LONGTEMPS(2)
                        End If 
                     End If 
                  End If 
               End If 
            End If 
         Else 
            ' Pas paralizé 
            If(STATE(2)=STANDING) or(STATE(2)=WALKING)
               ' Test Collision : On Tombe ?
               If Y2<223
                  If((C(X,Y+2)=0) and(C((X2+15)/16,Y+2)=0)) or(Y2<10)
                     STATE(2)=FALLING
                     FALL2=0
                     LONGTEMPS(2)=1
                     J2_ANIM
                  End If 
               End If 
               If STATE(2)<>FALLING
                  If(MVT(2)=0) or(MVT(2)=2)
                     If STATE(2)<>STANDING
                        STATE(2)=STANDING
                        J2_ANIM
                     End If 
                     EMPJP2=0
                  Else 
                     ' On saute 
                     If(MVT(2) and 1)=1
                        If EMPJP2=0
                           STATE(2)=JUMPING
                           JUMP2=0
                           J2_ANIM
                           EMPJP2=1
                        End If 
                     Else 
                        EMPJP2=0
                        ' Dépl gauche
                        If(((MVT(2) and 4)=4) and INV(2)=False) or(((MVT(2) and 8)=8) and INV(2)=True)
                           If(STATE(2)=STANDING) or(SENS2=DROITE)
                              STATE(2)=WALKING
                              SENS2=GAUCHE
                              J2_ANIM
                           End If 
                           If Y2>=0
                              If X2>16
                                 If X2 mod 16=0
                                    If C(X-1,Y+1)=0
                                       If FASTX(2)=True
                                          Add X2,-4
                                       Else 
                                          Add X2,-2
                                       End If 
                                    End If 
                                 Else 
                                    If FASTX(2)=True
                                       Add X2,-4
                                    Else 
                                       Add X2,-2
                                    End If 
                                 End If 
                              Else 
                                 X2=16
                              End If 
                           End If 
                        Else 
                           ' Dépl droite
                           If(((MVT(2) and 8)=8) and INV(2)=False) or(((MVT(2) and 4)=4) and INV(2)=True)
                              If(STATE(2)=STANDING) or(SENS2=GAUCHE)
                                 STATE(2)=WALKING
                                 SENS2=DROITE
                                 J2_ANIM
                              End If 
                              If Y2>=0
                                 If X2<224
                                    If C(X+1,Y+1)=0
                                       If FASTX(2)=True
                                          Add X2,4
                                       Else 
                                          Add X2,2
                                       End If 
                                    End If 
                                 Else 
                                    X2=224
                                 End If 
                              End If 
                           End If 
                        End If 
                     End If 
                  End If 
               End If 
            End If 
            ' Saut en cours
            If STATE(2)=JUMPING
               If FASTY(2)=True
                  Add JUMP2,2
               Else 
                  Inc JUMP2
               End If 
               If Y2 mod 16=15
                  If Y>=1
                     If(C(X,Y)=13) or(C((X2+15)/16,Y)=13)
                        JUMP2=17
                     End If 
                  End If 
               End If 
               If JUMP2<17
                  If FASTY(2)=True
                     Add Y2,-4
                  Else 
                     Add Y2,-2
                  End If 
                  ' Dep. gauche
                  If(((MVT(2) and 4)=4) and INV(2)=False) or(((MVT(2) and 8)=8) and INV(2)=True)
                     If SENS2=DROITE
                        SENS2=GAUCHE
                        J2_ANIM
                     End If 
                     If Y2>=0
                        If X2>16
                           If X2 mod 16=0
                              If C(X-1,(Y2/16)+1)=0
                                 If FASTX(2)=True
                                    Add X2,-4
                                 Else 
                                    Add X2,-2
                                 End If 
                              End If 
                           Else 
                              If FASTX(2)=True
                                 Add X2,-4
                              Else 
                                 Add X2,-2
                              End If 
                           End If 
                        Else 
                           X2=16
                        End If 
                     End If 
                  Else 
                     ' Dep droite 
                     If(((MVT(2) and 8)=8) and INV(2)=False) or(((MVT(2) and 4)=4) and INV(2)=True)
                        If SENS2=GAUCHE
                           SENS2=DROITE
                           J2_ANIM
                        End If 
                        If Y2>=0
                           If X2<224
                              If Y2>=0
                                 If C(X+1,(Y2/16)+1)=0
                                    If FASTX(2)=True
                                       Add X2,4
                                    Else 
                                       Add X2,2
                                    End If 
                                 End If 
                              End If 
                           Else 
                              X2=224
                           End If 
                        End If 
                     End If 
                  End If 
               Else 
                  ' En haut du saut, doit-on retomber ?
                  If Y2<10
                     STATE(2)=FALLING
                     FALL2=0
                     LONGTEMPS(2)=1
                     J2_ANIM
                  Else 
                     If(C(X,Y+1)>0) or(C((X2+15)/16,Y+1)>0)
                        STATE(2)=FALLING
                        FALL2=0
                        LONGTEMPS(2)=1
                        J2_ANIM
                     Else 
                        If Y=13
                           STATE(2)=STANDING
                           J2_ANIM
                        Else 
                           If(C(X,Y+2)>0) or(C((X2+15)/16,Y+2)>0)
                              STATE(2)=STANDING
                              J2_ANIM
                           Else 
                              STATE(2)=FALLING
                              FALL2=0
                              LONGTEMPS(2)=1
                              J2_ANIM
                           End If 
                        End If 
                     End If 
                  End If 
               End If 
            Else 
               ' On tombe 
               If STATE(2)=FALLING
                  Inc FALL2
                  If FALL2<9
                     If FALL2>1
                        ' Dep gauche 
                        If(((MVT(2) and 4)=4) and INV(2)=False) or(((MVT(2) and 8)=8) and INV(2)=True)
                           If SENS2=DROITE
                              SENS2=GAUCHE
                              Amreg(2,1)=SENS2
                           End If 
                           If Y2>=0
                              If X2>16
                                 If X2 mod 16=0
                                    If C(X-1,Y+1)=0
                                       If FASTX(2)=True
                                          Add X2,-4
                                       Else 
                                          Add X2,-2
                                       End If 
                                    End If 
                                 Else 
                                    If FASTX(2)=True
                                       Add X2,-4
                                    Else 
                                       Add X2,-2
                                    End If 
                                 End If 
                              Else 
                                 X2=16
                              End If 
                           End If 
                        Else 
                           ' Droite 
                           If(((MVT(2) and 8)=8) and INV(2)=False) or(((MVT(2) and 4)=4) and INV(2)=True)
                              If SENS2=GAUCHE
                                 SENS2=DROITE
                                 Amreg(2,1)=SENS2
                              End If 
                              If Y2>=0
                                 If X2<224
                                    If Y2>=0
                                       If C(X+1,Y+1)=0
                                          If FASTX(2)=True
                                             Add X2,4
                                          Else 
                                             Add X2,2
                                          End If 
                                       End If 
                                    End If 
                                 Else 
                                    X2=224
                                 End If 
                              End If 
                           End If 
                        End If 
                     End If 
                     Add Y2,2
                  Else 
                     ' Redescendu d'une case: continuer à tomber ?
                     If Y2=223
                        STATE(2)=STANDING
                        LONGTEMPS(2)=0
                        J2_ANIM
                     Else 
                        If(C(X,Y+2)>0) or(C((X2+15)/16,Y+2)>0)
                           STATE(2)=STANDING
                           LONGTEMPS(2)=0
                           J2_ANIM
                        Else 
                           FALL2=0
                           Inc LONGTEMPS(2)
                        End If 
                     End If 
                  End If 
               End If 
            End If 
            ' Poum ! 
            If((MVT(2) and 16)=16) and(GLOUGLOU2=False)
               If Amreg(5)=0
                  Amreg(5)=1
                  Amreg(7)=X2
                  Amreg(8)=Y2
                  Amreg(9)=SENS2
                  If STATE(2)<>JUMPING
                     If STATE(2)<>FALLING
                        If SENS2=DROITE
                           Amal 2,"Let A=166;"
                        Else 
                           Amal 2,"Let A=167;"
                        End If 
                        Amal On 2
                        POUM2=1
                        PARALIZED2=180
                        PANOU(2)=True
                     End If 
                  End If 
               End If 
            Else 
               If POUM2=1
                  POUM2=0
                  J2_ANIM
               End If 
            End If 
         End If 
         
         If Bob Col(JOUEUR(2),BONUS To BONUS)
            Proc EFFET_BONUS[2]
            Bob BONUS,,300,
            BONUSWAIT=-BON_DEL(BONUSDELAI)
         End If 
         
         If CARRY2=0
            If Bob Col(JOUEUR(2),TRESOR(1) To TRESOR(NBTRESORS))
               For I=1 To NBTRESORS
                  Exit If Col(TRESOR(I))
               Next I
               CARRY2=I
               TRESOR_TOMBE(CARRY2)=0
               Bob Off TRESOR(CARRY2)
               Proc UPDSCORE[2,500]
               Sam Play VOIX2,2
            End If 
         End If 
         
         If X2=224 and Y2=223
            
            If CARRY2>0
               CARRY2=0
               Inc RAMENE2
               Proc UPDSCORE[2,1500]
               If RAMENE1+RAMENE2=NBTRESORS
                  PASSE=True
               End If 
               Sam Play VOIX2*2,2
            End If 
            
            If MVT(2)=2
               If PARALIZED2=False
                  If GLOUGLOU2=0
                     Limit Bob 2,0,0 To 256,224
                     Sam Play VOIX2,3
                     GLOUGLOU2=1
                     Amal 2,"Anim 0,(200,2)(201,2)(202,2)(201,2);"
                     Amal On 2
                     Amal 13,"Pause;Pause;Let X=-100;"
                     Amal On 13
                     SENS2=DROITE
                  End If 
                  If HURRY=False
                     If MEMETEMPS
                        Inc TEMPS(1)
                        TEMPS(1)=Min(TEMPS(1),MXTEMPS(1))
                        Ink 4
                        TP=208-TEMPS(1)
                        Draw 241,TP+1 To 254,TP+1
                        Draw 241,TP To 254,TP
                        Draw 1,TP+1 To 14,TP+1
                        Draw 1,TP To 14,TP
                     Else 
                        Inc TEMPS(2)
                        TEMPS(2)=Min(TEMPS(2),MXTEMPS(2))
                        Ink 4
                        TP=208-TEMPS(2)
                        Draw 241,TP+1 To 254,TP+1
                        Draw 241,TP To 254,TP
                     End If 
                  End If 
               End If 
            Else 
               If GLOUGLOU2=1
                  J2_ANIM
               End If 
            End If 
         End If 
         
         If Bob Col(TIR(2),ENNEMI(1) To ENNEMI(NBMONSTRES))
            For I=ENNEMI(1) To ENNEMI(NBMONSTRES)
               Exit If Col(I)
            Next I
            If DANSLESPOMMES(I-4)=False
               DANSLESPOMMES(I-4)=200
               Amal Freeze I
               Bob TIR(2),,320,
               Shoot 
               Proc UPDSCORE[2,10]
            End If 
         End If 
         
         If MORT1=False
            If(PARALIZED1=0) or((PARALIZED1>0) and(PANOU(1)=True))
               If Bob Col(TIR(2),JOUEUR(1) To JOUEUR(1))
                  PANOU(1)=False
                  PARALIZED1=1
                  Amal Freeze 1
                  Amal On 10
                  Bob TIR(2),,320,
                  Sam Play VOIX2,4
                  Proc UPDSCORE[2,50]
               End If 
            End If 
         End If 
         
         If SUPER(2)=False
            If Bob Col(JOUEUR(2),ENNEMI(1) To ENNEMI(NBMONSTRES))
               Gosub BUTE2
            End If 
         End If 
         
         If(TEMPS(2)=0) or(TEMPS(1)=0 and MEMETEMPS)
            Gosub BUTE2
         End If 
      End If 
      ' - - - - - - -
      Inc BONUSWAIT
      If BONUSWAIT=0
         BONUS
      End If 
      If BONUSWAIT=BON_RES(BONUSRESTE)
         Bob BONUS,,300,
         BONUSWAIT=-BON_DEL(BONUSDELAI)
      End If 
      
      For I=1 To NBTRESORS
         If TRESOR_TOMBE(I)=True
            T=TRESOR(I)
            X=X Bob(T)
            Y=Y Bob(T)
            If Y mod 16<15
               Bob T,,Y+1,
            Else 
               If Y=223
                  TRESOR_TOMBE(I)=0
               Else 
                  If C(X/16,Y/16+2)>0
                     TRESOR_TOMBE(I)=0
                  Else 
                     Bob T,,Y+1,
                  End If 
               End If 
            End If 
         End If 
      Next I
      
      If CHEAT=False
         If Timer>12
            Ink 0
            If MORT1=False
               Dec TEMPS(1)
               If TEMPS(1)>0
                  Draw 1,207-TEMPS(1) To 14,207-TEMPS(1)
                  Draw 1,208-TEMPS(1) To 14,208-TEMPS(1)
               End If 
            End If 
            If MORT2=False
               If MEMETEMPS
                  If TEMPS(1)>0
                     Draw 241,207-TEMPS(1) To 254,207-TEMPS(1)
                     Draw 241,208-TEMPS(1) To 254,208-TEMPS(1)
                  End If 
               Else 
                  Dec TEMPS(2)
                  If TEMPS(2)>0
                     Draw 241,207-TEMPS(2) To 254,207-TEMPS(2)
                     Draw 241,208-TEMPS(2) To 254,208-TEMPS(2)
                  End If 
               End If 
            End If 
            Timer=0
         End If 
      End If 
      Add TEMPSTOTAL,2
      If HURRY=False
         If TEMPSTOTAL>=MXTEMPSTOTAL
            Tempo 25
            HURRY=True
            UPDSCORE[0,0]
         End If 
      End If 
      
      For I=ENNEMI(1) To ENNEMI(NBMONSTRES)
         If DANSLESPOMMES(I-4)=1
            Amal On I
         End If 
         If DANSLESPOMMES(I-4)>0
            Dec DANSLESPOMMES(I-4)
         End If 
      Next I
      Synchro 
      If MORT1=0
         Bob 1,X1,Y1,
      Else 
         If A1200=False
            Wait Vbl 
         End If 
      End If 
      If MORT2=0
         Bob 2,X2,Y2,
      Else 
         If A1200=False
            Wait Vbl 
         End If 
      End If 
      Wait Vbl 
   Until((MORT1=True) and(MORT2=True)) or(PASSE=True)
Else 
   ' Mode 1 joueur
   Repeat 
      Gosub CONTROLE
      Gosub J1
      If Bob Col(JOUEUR(1),BONUS To BONUS)
         Proc EFFET_BONUS[1]
         Bob BONUS,,300,
         BONUSWAIT=-BON_DEL(BONUSDELAI)
      End If 
      If CARRY1=0
         If Bob Col(JOUEUR(1),TRESOR(1) To TRESOR(NBTRESORS))
            For I=1 To NBTRESORS
               Exit If Col(TRESOR(I))
            Next I
            CARRY1=I
            TRESOR_TOMBE(CARRY1)=0
            Bob Off TRESOR(CARRY1)
            Proc UPDSCORE[1,500]
            Sam Play VOIX1,2
         End If 
      End If 
      If X1=16 and Y1=223
         If CARRY1>0
            CARRY1=0
            Inc RAMENE1
            Proc UPDSCORE[1,1500]
            If RAMENE1=NBTRESORS
               PASSE=True
            End If 
            Sam Play VOIX1*8,2
         End If 
         If MVT(1)=2
            If PARALIZED1=0
               If GLOUGLOU1=0
                  Limit Bob 1,0,0 To 256,224
                  Sam Play VOIX1,3
                  GLOUGLOU1=1
                  Amal 1,"Anim 0,(209,2)(210,2)(211,2)(210,2);"
                  Amal On 1
                  Amal 12,"Pause;Pause;Let X=-100;"
                  Amal On 12
                  SENS1=GAUCHE
               End If 
               If HURRY=False
                  Inc TEMPS(1)
                  TEMPS(1)=Min(TEMPS(1),MXTEMPS(1))
                  Ink 4
                  TP=208-TEMPS(1)
                  Draw 1,TP+1 To 14,TP+1
                  Draw 1,TP To 14,TP
               End If 
            End If 
         Else 
            If GLOUGLOU1=1
               Bob 16,0,208,46
               J1_ANIM
            End If 
         End If 
      End If 
      If Bob Col(TIR(1),ENNEMI(1) To ENNEMI(NBMONSTRES))
         For I=ENNEMI(1) To ENNEMI(NBMONSTRES)
            Exit If Col(I)
         Next I
         If DANSLESPOMMES(I-4)=False
            DANSLESPOMMES(I-4)=200
            Amal Freeze I
            Bob TIR(1),,320,
            Shoot 
            Proc UPDSCORE[1,10]
         End If 
      End If 
      If SUPER(1)=False
         If Bob Col(JOUEUR(1),ENNEMI(1) To ENNEMI(NBMONSTRES))
            Gosub BUTE1
         End If 
      End If 
      If TEMPS(1)=0
         Gosub BUTE1
      End If 
      
      Inc BONUSWAIT
      If BONUSWAIT=0
         BONUS
      End If 
      If BONUSWAIT=BON_RES(BONUSRESTE)
         Bob BONUS,,300,
         BONUSWAIT=-BON_DEL(BONUSDELAI)
      End If 
      
      For I=1 To NBTRESORS
         If TRESOR_TOMBE(I)=True
            T=TRESOR(I)
            X=X Bob(T)
            Y=Y Bob(T)
            If Y mod 16<15
               Bob T,,Y+1,
            Else 
               If Y=223
                  TRESOR_TOMBE(I)=0
               Else 
                  If C(X/16,Y/16+2)>0
                     TRESOR_TOMBE(I)=0
                  Else 
                     Bob T,,Y+1,
                  End If 
               End If 
            End If 
         End If 
      Next I
      If CHEAT=False
         If Timer>12
            Ink 0
            If MORT1=False
               Dec TEMPS(1)
               If TEMPS(1)>0
                  Draw 1,207-TEMPS(1) To 14,207-TEMPS(1)
                  Draw 1,208-TEMPS(1) To 14,208-TEMPS(1)
               End If 
            End If 
            Timer=0
         End If 
      End If 
      Add TEMPSTOTAL,2
      T=MXTEMPSTOTAL-TEMPSTOTAL
      If(T mod 78)=0
         If T>0
            Ink 0
            T=207-(T/78)
            Draw 241,T To 254,T
            Inc T
            Draw 241,T To 254,T
         End If 
      End If 
      If HURRY=False
         If TEMPSTOTAL>=MXTEMPSTOTAL
            Tempo 25
            HURRY=True
            UPDSCORE[0,0]
         End If 
      End If 
      For I=ENNEMI(1) To ENNEMI(NBMONSTRES)
         If DANSLESPOMMES(I-4)=1
            Amal On I
         End If 
         If DANSLESPOMMES(I-4)>0
            Dec DANSLESPOMMES(I-4)
         End If 
      Next I
      Synchro 
      Bob 1,X1,Y1,
      Wait Vbl 
   Until(MORT1=True) or(PASSE=True)
End If 
'****************
Shift Off 
Fade 4
For I=1 To 63
   Synchro 
   Volume Max(0,ZIKVOL-I)
   Wait Vbl 
Next I
Volume SFXVOL
Wait Vbl 
Amal Off 
MUSIQUE_OFF
Wait 4
Bob Off 
Wait Vbl 
_PERMIT
If PASSE
   If CHEAT=True
      SP[1]
   Else 
      If PARTIE=2
         If(LEVEL=1) or(LEVEL=21) or(LEVEL mod 5=3)
            SP[2]
         End If 
      End If 
   End If 
   TIMEBO=Max(0,(MXTEMPSTOTAL-TEMPSTOTAL)/178*100)
   If PARTIE=2
      If RAMENE1>RAMENE2
         Inc VICT(1)
         Proc _MESSAGE[MSG_WINNER,1]
         Add SCORE(1),TIMEBO
      Else 
         If RAMENE2>RAMENE1
            Inc VICT(2)
            Proc _MESSAGE[MSG_WINNER,2]
            Add SCORE(2),TIMEBO
         Else 
            Proc _MESSAGE[MSG_EGALITE,0]
         End If 
      End If 
   Else 
      Proc _MESSAGE[MSG_GOOD_JOB,0]
      Add SCORE(1),TIMEBO
   End If 
   If LEVEL mod 5=0
      If PARTIE=2
         SPEND
         SP[3]
         _MESSAGE[MSG_BONUS,0]
         Proc JEU[LEVEL/5]
      End If 
      If PUBON
         Proc PUB
      End If 
   End If 
   Inc LEVEL
   VERIF[LEVEL]
   If Param=False
      WELLDONE
      CREDITS=0
      Goto FINI
   End If 
   _MESSAGE[MSG_GET_READY,0]
   CH61[LEVEL]
   If IMGBACK<>MEMORY
      _LOAD[("Twin2:Img-Back"+Str$(IMGBACK)+".Abk")-" ",9]
      MEMORY=IMGBACK
   End If 
   Timer=0
   Clear Key 
   Repeat 
      Multi Wait 
   Until Fire(1) or Fire(0) or(Len(Inkey$)>0) or(Timer>=400)
   Fade 1
   Wait 15
   Cls 0
Else 
   Dec CREDITS
   If CREDITS>0
      _LOAD["Twin2:Samples-AhAh1.Abk",6]
      Sam Bank 6
      Sam Play 1
      _MESSAGE[MSG_OH_NO,0]
      Sam Bank 5
      Erase 6
   End If 
End If 
FINI:
Wait Vbl 
SPEND
Sam Bank 5

If CREDITS>0 Then Goto DEBUT

Erase 5
_LOAD["Twin2:Samples-AhAh2.Abk",6]
Sam Bank 6
Sam Play 1
Proc _MESSAGE[MSG_GAME_OVER,0]
Sam Bank 5
Erase 6
Erase 9

For I=1 To 10
   If SCORE(1)>HISCORE(I)
      For J=10 To I+1 Step -1
         HISCORE(J)=HISCORE(J-1)
         HISCORE$(J)=HISCORE$(J-1)
         HIMODE(J)=HIMODE(J-1)
      Next J
      HISCORE(I)=SCORE(1)
      HISCORE$(I)=NAME1$
      HIMODE(I)=USER
      Exit 
   End If 
Next I
CLI1=I
If PARTIE=2
   For I=1 To 10
      If SCORE(2)>HISCORE(I)
         For J=10 To I+1 Step -1
            HISCORE(J)=HISCORE(J-1)
            HISCORE$(J)=HISCORE$(J-1)
            HIMODE(J)=HIMODE(J-1)
         Next J
         HISCORE(I)=SCORE(2)
         HISCORE$(I)=NAME2$
         HIMODE(I)=USER
         Exit 
      End If 
   Next I
   CLI2=I
Else 
   CLI2=-1
End If 

Cls 0
HALL_OF_FAME
Fade 1,0,$FFF,$AAA,$555,$FFF
Wait 15
Flash 4,"(FFF,20)(000,20)"

While Fire(1) or Fire(0)
   Multi Wait 
Wend 
Clear Key 
Repeat 
   Multi Wait 
Until Fire(1) or Fire(0) or(Len(Inkey$)>0)
Flash Off 
Fade 1
Wait 15

SAUVE_SCORES

SELECT
PS=Param
If PS=1 Then Goto PROUT3

Erase 3
If PS=2 Then Goto PROUT2 Else Goto PROUT

'----------------------------------------------------

CONTROLE:

' On lit le clavier
_PERMIT
_KL=Key State(79)
_KR=Key State(78)
_KU=Key State(76)
_KD=Key State(77)
_KF=Key State(64)
KS=Key Shift
K$=Inkey$
_FORBID

K$=Upper$(K$)
K=Asc(K$)
SC=Scancode

' On évite les aberrations 
If _KL
   If _KR
      _KL=False
      _KR=False
   End If 
End If 

If _KD
   If _KU
      _KU=False
      _KD=False
   End If 
End If 

' Les sticks 
If PARTIE=1
   J=Joy(1)
Else 
   MVT(1)=Joy(1)
   J=Joy(0)
End If 

' Si on touche pas au stick
If J=0
   MVT(PARTIE)=0
   If _KU
      Bset 0,MVT(PARTIE)
   End If 
   If _KD
      Bset 1,MVT(PARTIE)
   End If 
   If _KL
      Bset 2,MVT(PARTIE)
   End If 
   If _KR
      Bset 3,MVT(PARTIE)
   End If 
   If _KF
      Bset 4,MVT(PARTIE)
   End If 
Else 
   MVT(PARTIE)=J
End If 


' Esc
If K=27
   MORT1=True
   MORT2=True
   CREDITS=1
End If 

'P ou F10
If(K$="P") or(SC=89)
   T=Timer
   Ink 15,0
   Text 4,242,"    G A M E    "
   Text 132,242,"  P A U S E D  "
   _PERMIT
   Repeat 
      Multi Wait 
      K2$=Upper$(Inkey$)
      SC2=Scancode
   Until(K2$=K$) and(SC2=SC)
   _FORBID
   Timer=T
   UPDSCORE[0,0]
End If 

' F9 
If SC=88
   Ink 1,0
   Text 0,7,"Chip ="+Str$(Chip Free)+"  / Fast ="+Str$(Fast Free)+"   "
End If 

' F8 
If SC=87
   Paper 0
   Pen 1
   Home 
   List Bank 
End If 

' Touche magique (£) 
If K=163
   If(PARTIE=2) or(LEVEL<45)
      CHEAT= Not(CHEAT)
   End If 
End If 

If CHEAT=True
   'F1
   If SC=80
      SUPER(1)= Not(SUPER(1))
      UPDSCORE[0,0]
   End If 
   'F2
   If SC=81
      SUPER(2)= Not(SUPER(2))
      UPDSCORE[0,0]
   End If 
   'F3
   If SC=82
      CREDITS=Min(99,CREDITS+1)
      L$=Str$(CREDITS)-" "
      If Len(L$)=1
         L$="0"+L$
      End If 
      Ink 10,0
      Text 280,218,L$
   End If 
   'F4
   If SC=83
      FASTX(1)=True
      If(STATE(1)=JUMPING) and(FASTY(1)=0)
         FASTY(1)=1
      Else 
         FASTY(1)=True
      End If 
      X1=X1-X1 mod 4
      Bob 1,X1,,
   End If 
   'F5
   If SC=84
      FASTX(2)=True
      If(STATE(2)=JUMPING) and(FASTY(2)=0)
         FASTY(2)=1
      Else 
         FASTY(2)=True
      End If 
      X2=X2-X2 mod 4
      Bob 2,X2,,
   End If 
   ' +
   If K=43
      PASSE=True
   End If 
   ' 1
   If(SC=29) or(SC=1)
      If LOCK1=False
         If MORT1=False
            Gosub BUTE1
         End If 
      End If 
   End If 
   ' 2
   If(SC=30) or(SC=2)
      If LOCK2=False
         If MORT2=False
            Gosub BUTE2
         End If 
      End If 
   End If 
   ' A
   If SC=16
      LOCK1=True
   End If 
   ' Z
   If SC=17
      LOCK2=True
   End If 
End If 

' Help!
If SC=95
   If(MORT1=False) and(LOCK1=False)
      Gosub BUTE1
   End If 
   If PARTIE=2
      If(MORT2=False) and(LOCK2=False)
         Gosub BUTE2
      End If 
   End If 
End If 

Return 

J1:
X1=X Bob(1)
Y1=Y Bob(1)
X=X1/16
Y=Y1/16

If PARALIZED1>0
   Inc PARALIZED1
   If PARALIZED1=200
      PARALIZED1=0
      PANOU(1)=False
      Amal Freeze 10
      J1_ANIM
      UPDSCORE[0,0]
   End If 
   If STATE(1)=JUMPING
      Inc JUMP1
      If(Y1 mod 16)=15
         If Y>=1
            If(C(X,Y)=13) or(C((X1+15)/16,Y)=13)
               JUMP1=17
            End If 
         End If 
      End If 
      If JUMP1<17
         Add Y1,-2
      Else 
         If Y1<10
            STATE(1)=FALLING
            FALL1=0
            LONGTEMPS(1)=1
         Else 
            If(C(X,Y+1)>0) or(C((X1+15)/16,Y+1)>0)
               STATE(1)=FALLING
               FALL1=0
               LONGTEMPS(1)=1
            Else 
               If Y=13
                  STATE(1)=STANDING
               Else 
                  If(C(X,Y+2)>0) or(C((X1+15)/16,Y+2)>0)
                     STATE(1)=STANDING
                  Else 
                     STATE(1)=FALLING
                     FALL1=0
                     LONGTEMPS(1)=1
                  End If 
               End If 
            End If 
         End If 
      End If 
   Else 
      If STATE(1)=FALLING
         Inc FALL1
         If FALL1<9
            Add Y1,2
         Else 
            If Y1=223
               STATE(1)=STANDING
               LONGTEMPS(1)=0
            Else 
               If(C(X,Y+2)>0) or(C((X1+15)/16,Y+2)>0)
                  STATE(1)=STANDING
                  LONGTEMPS(1)=0
               Else 
                  FALL1=0
                  Inc LONGTEMPS(1)
               End If 
            End If 
         End If 
      End If 
   End If 
Else 
   ' Que fais tu ?
   If(STATE(1)=STANDING) or(STATE(1)=WALKING)
      If Y1<223
         ' Test collision: tombe-t-on ? 
         If((C(X,Y+2)=0) and(C((X1+15)/16,Y+2)=0)) or(Y1<10)
            STATE(1)=FALLING
            FALL1=0
            LONGTEMPS(1)=1
            J1_ANIM
         End If 
      End If 
      ' Ca bouge pas 
      If STATE(1)<>FALLING
         If(MVT(1)=0) or(MVT(1)=2)
            If STATE(1)<>STANDING
               STATE(1)=STANDING
               J1_ANIM
            End If 
            EMPJP1=0
         Else 
            ' On veut sauter 
            If(MVT(1) and 1)=1
               If EMPJP1=0
                  STATE(1)=JUMPING
                  JUMP1=0
                  J1_ANIM
                  EMPJP1=1
               End If 
            Else 
               EMPJP1=0
               ' Gauche 
               If(((MVT(1) and 4)=4) and INV(1)=False) or(((MVT(1) and 8)=8) and INV(1)=True)
                  If(STATE(1)=STANDING) or(SENS1=DROITE)
                     STATE(1)=WALKING
                     SENS1=GAUCHE
                     J1_ANIM
                  End If 
                  If Y1>=0
                     If X1>16
                        If X1 mod 16=0
                           If C(X-1,Y+1)=0
                              If FASTX(1)
                                 Add X1,-4
                              Else 
                                 Add X1,-2
                              End If 
                           End If 
                        Else 
                           If FASTX(1)
                              Add X1,-4
                           Else 
                              Add X1,-2
                           End If 
                        End If 
                     Else 
                        X1=16
                     End If 
                  End If 
               Else 
                  ' Droite 
                  If(((MVT(1) and 8)=8) and INV(1)=False) or(((MVT(1) and 4)=4) and INV(1)=True)
                     If(STATE(1)=STANDING) or(SENS1=GAUCHE)
                        STATE(1)=WALKING
                        SENS1=DROITE
                        J1_ANIM
                     End If 
                     If Y1>=0
                        If X1<224
                           If C(X+1,Y+1)=0
                              If FASTX(1)=True
                                 Add X1,4
                              Else 
                                 Add X1,2
                              End If 
                           End If 
                        Else 
                           X1=224
                        End If 
                     End If 
                  End If 
               End If 
            End If 
         End If 
      End If 
   End If 
   ' En train de sauter 
   If STATE(1)=JUMPING
      If FASTY(1)=True
         Add JUMP1,2
      Else 
         Inc JUMP1
      End If 
      If(Y1 mod 16)=15
         If Y>=1
            If(C(X,Y)=13) or(C((X1+15)/16,Y)=13)
               JUMP1=17
            End If 
         End If 
      End If 
      If JUMP1<17
         If FASTY(1)=True
            Add Y1,-4
         Else 
            Add Y1,-2
         End If 
         ' Gauche 
         If(((MVT(1) and 4)=4) and INV(1)=False) or(((MVT(1) and 8)=8) and INV(1)=True)
            If SENS1=DROITE
               SENS1=GAUCHE
               J1_ANIM
            End If 
            If Y1>=0
               If X1>16
                  If X1 mod 16=0
                     If C(X-1,(Y1/16)+1)=0
                        If FASTX(1)=True
                           Add X1,-4
                        Else 
                           Add X1,-2
                        End If 
                     End If 
                  Else 
                     If FASTX(1)=True
                        Add X1,-4
                     Else 
                        Add X1,-2
                     End If 
                  End If 
               Else 
                  X1=16
               End If 
            End If 
         Else 
            ' Droite 
            If(((MVT(1) and 8)=8) and INV(1)=False) or(((MVT(1) and 4)=4) and INV(1)=True)
               If SENS1=GAUCHE
                  SENS1=DROITE
                  J1_ANIM
               End If 
               If Y1>=0
                  If X1<224
                     If C(X+1,(Y1/16)+1)=0
                        If FASTX(1)=True
                           Add X1,4
                        Else 
                           Add X1,2
                        End If 
                     End If 
                  Else 
                     X1=224
                  End If 
               End If 
            End If 
         End If 
      Else 
         If FASTY(1)=1
            FASTY(1)=True
         End If 
         If Y1<10
            STATE(1)=FALLING
            FALL1=0
            LONGTEMPS(1)=1
            J1_ANIM
         Else 
            ' En haut du saut: retomber ?
            If(C(X,Y+1)>0) or(C((X1+15)/16,Y+1)>0)
               STATE(1)=FALLING
               FALL1=0
               LONGTEMPS(1)=1
               J1_ANIM
            Else 
               If Y=13
                  STATE(1)=STANDING
                  J1_ANIM
               Else 
                  If(C(X,Y+2)>0) or(C((X1+15)/16,Y+2)>0)
                     STATE(1)=STANDING
                     J1_ANIM
                  Else 
                     STATE(1)=FALLING
                     FALL1=0
                     LONGTEMPS(1)=1
                     J1_ANIM
                  End If 
               End If 
            End If 
         End If 
      End If 
   Else 
      ' En train de tomber 
      If STATE(1)=FALLING
         Inc FALL1
         If FALL1<9
            If FALL1>1
               ' Gauche 
               If(((MVT(1) and 4)=4) and INV(1)=False) or(((MVT(1) and 8)=8) and INV(1)=True)
                  If SENS1=DROITE
                     SENS1=GAUCHE
                     Amreg(1,1)=SENS1
                  End If 
                  If Y1>=0
                     If X1>16
                        If X1 mod 16=0
                           If C(X-1,Y+1)=0
                              If FASTX(1)=True
                                 Add X1,-4
                              Else 
                                 Add X1,-2
                              End If 
                           End If 
                        Else 
                           If FASTX(1)=True
                              Add X1,-4
                           Else 
                              Add X1,-2
                           End If 
                        End If 
                     Else 
                        X1=16
                     End If 
                  End If 
               Else 
                  ' Droite 
                  If(((MVT(1) and 8)=8) and INV(1)=False) or(((MVT(1) and 4)=4) and INV(1)=True)
                     If SENS1=GAUCHE
                        SENS1=DROITE
                        Amreg(1,1)=SENS1
                     End If 
                     If Y1>=0
                        If X1<224
                           If C(X+1,Y+1)=0
                              If FASTX(1)=True
                                 Add X1,4
                              Else 
                                 Add X1,2
                              End If 
                           End If 
                        Else 
                           X1=224
                        End If 
                     End If 
                  End If 
               End If 
            End If 
            Add Y1,2
         Else 
            ' Redescendu d'une case: continuer à tomber ?
            If Y1<223
               If(C(X,Y+2)>0) or(C((X1+15)/16,Y+2)>0)
                  STATE(1)=STANDING
                  LONGTEMPS(1)=0
                  J1_ANIM
               Else 
                  FALL1=0
                  Inc LONGTEMPS(1)
               End If 
            Else 
               STATE(1)=STANDING
               LONGTEMPS(1)=0
               J1_ANIM
            End If 
         End If 
      End If 
   End If 
   ' Poum ! 
   If((MVT(1) and 16)=16) and(GLOUGLOU1=False)
      If Amreg(0)=0
         Amreg(0)=1
         Amreg(2)=X1
         Amreg(3)=Y1
         Amreg(4)=SENS1
         If STATE(1)<>JUMPING
            If STATE(1)<>FALLING
               If SENS1=DROITE
                  Amal 1,"Let A=188;"
               Else 
                  Amal 1,"Let A=189;"
               End If 
               Amal On 1
               POUM1=1
               PARALIZED1=180
               PANOU(1)=True
            End If 
         End If 
      End If 
   Else 
      If POUM1=1
         POUM1=0
         J1_ANIM
      End If 
   End If 
End If 
Return 

BUTE1:
MORT1=True
Sam Play VOIX1,4
J1_ANIM
Bob Off TIR(1)
If CARRY1<>0
   Bob TRESOR(CARRY1),X1-X1 mod 16,Y1,43
   TRESOR_TOMBE(CARRY1)=True
End If 
UPDSCORE[0,0]
Return 

BUTE2:
MORT2=True
Sam Play VOIX2,5
J2_ANIM
Bob Off TIR(2)
If CARRY2<>0
   Bob TRESOR(CARRY2),X2-X2 mod 16,Y2,43
   TRESOR_TOMBE(CARRY2)=True
End If 
UPDSCORE[0,0]
Return 

' *** Datas ***

SECRET1:
Data "1111","TWIN","ABCD","YEAH","GOOD","VUZZ","REED","MOVE","HARD"
SECRET2:
Data "2222","TOTO","RTEL","AMOS","WORK","CODE","STOP","FIRE","CHIP","FAST"

' Conserve 
DT:
Data "A0,(87,4)(86,4)(85,4)(84,4);","A1,(88,2)(89,2);FR0=1T4;NR0;"
Data "A0,(93,4)(92,4)(91,4)(90,4);","A1,(89,2)(88,2);FR0=1T4;NR0;"
' Robot
Data "A0,(100,8)(101,8)(102,8);","A1,(103,4)(104,4);FR0=1T8;NR0;"
Data "A0,(105,8)(106,8)(107,8);","A1,(104,4)(103,4);FR0=1T8;NR0;"
' PacMan 
Data "A0,(116,8)(117,8);"
Data "A0,(118,8)(119,8);"
' Serpent
Data "A0,(126,4)(127,4)(128,4);"
Data "A0,(129,4)(130,4)(131,4);"
' Octopus
Data "A0,(120,4)(121,4)(122,4);"
Data "A0,(123,4)(124,4)(125,4);"
' Fantôme
Data "A1,(146,1);","A1,(147,2)(148,2)(149,2)(150,2)(151,2)(152,2)(153,2)(154,2);FR0=1T17;NR0;"
Data "A1,(155,1);","A1,(154,2)(153,2)(152,2)(151,2)(150,2)(149,2)(148,2)(147,2);FR0=1T17;NR0;"
' Heaume 
Data "A0,(94,8)(95,8)(96,8);"
Data "A0,(97,8)(98,8)(99,8);"
' Punk 
Data "A0,(108,4)(109,4)(110,4);","A1,(111,4)(112,4);FR0=1T8;NR0;"
Data "A0,(113,4)(114,4)(115,4);","A1,(112,4)(111,4);FR0=1T8;NR0;"
' Koopa
Data "A0,(132,4)(133,4)(134,4);","A1,(135,4)(136,4);FR0=1T8;NR0;"
Data "A0,(137,4)(138,4)(139,4);","A1,(136,4)(135,4);FR0=1T8;NR0;"
' Koopa ailé 
Data "A0,(140,8)(141,8)(142,8);"
Data "A0,(143,8)(144,8)(145,8);"

BON:
Data 20,48,19,49,14,54,5,56,1,57,17,50,15,51,12,52,16,53,10,55,3,66,8,67
Data 5,68,1,69,1,70,5,71,6,73,6,74,8,75,7,76,2,79,8,77,3,78,6,72,2,60
Data 2,260,1,261,2,262
Data -1

'***************** PROCEDURES **************** 

Procedure INIT
   
   '   BANQUE     INTRO         PRES          OPTIONS            JEU  
   '
   '     1      Def-Sprites  Def-Sprites     OptSprites       Def-Sprites 
   '     2        Fonte         Fonte          Fonte            Fonte 
   '     3      Zik intro     Zik intro      Zik intro         Zik-Jeu
   '     4
   '     5      SplFirst1                                    SamplesJeu1
   '     6      SplFirst2                                   SamplesSpecial
   '     7      SplFirst3 
   '     8      SplFirst4 
   '     9      ImgIntro1a    ImgIntro2                        ImgBack
   '    10      ImgIntro1b    ImgIntro3                      Img Pub/Fin
   '    11      ImgIntro1c
   '    12      OptSprites    OptSprites    Def-Sprites        OptSprites 
   '    13       ImgOpta       ImgOpta        ImgOpta           ImgOpta 
   '    14       ImgOptb       ImgOptb        ImgOptb           ImgOptb 
   '    15       ImgOptc       ImgOptc        ImgOptc           ImgOptc 
   
   Shared ZIKPLAYING,QUELLEZIK,ZIKVOL
   
   A=Intcall(-78)
   If Prg State=True
      FAST=False
      Amos Lock 
      Break Off 
   Else 
      FAST=True
      Close Editor 
      While Screen>=0
         Screen Close Screen
      Wend 
      For I=1 To 16
         Erase I
      Next I
   End If 
   
   FAST=0
   
   Colour Back 0
   Auto View Off 
   Screen Open 3,640,200,2,Hires
   Screen Display 3,128,50,640,200
   Palette $0,$FFF
   Curs Off 
   Cls 0
   Hide On 
   Request Off 
   
   Get Fonts 
   N=0
   Do 
      Inc N
      F$=Font$(N)
      If F$=""
         Auto View On 
         Centre At(,14)+"Il me faut la fonte Ruby 15 !"
         View 
         Wait Vbl 
         Clear Key 
         Repeat 
         Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
         FIN
      Else 
         If Upper$(Left$(F$,5))="RUBY."
            N_FONTE=N
            Exit 
         End If 
      End If 
   Loop 
   Set Font N_FONTE
   
   FF=Fast Free
   CF=Chip Free
   TF=FF+CF
   If TF<500000
      Auto View On 
      CTXT["Désolé, 1 Mo de RAM nécessaire !",120]
      Clear Key 
      Repeat 
      Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
      FIN
   End If 
   
   CHARGE_PREFS
   If FAST=0
      Proc _COPYRIGHT
   End If 
   
   Screen 3
   Palette 0,0
   Auto View On 
   If TF<1000000
      If FF=0
         CTXT["1 Mo de Chip RAM détecté",100]
      Else 
         CTXT["1 Mo de RAM détecté",100]
      End If 
   Else 
      If TF<1500000
         CTXT["1,5 Mo de RAM détectés!",100]
      Else 
         If TF<2000000
            If FF=0
               CTXT["2 Mo de Chip RAM détectés!!",100]
            Else 
               CTXT["2 Mo de RAM détectés!",100]
            End If 
         Else 
            CTXT["Waouh! C'est plein de RAM ici!",100]
         End If 
      End If 
   End If 
   Fade 1,0,$FFF
   
   ' Charger la zik 
   _LOAD["Twin1:Zik-Intro.Abk",3]
   
   ' Transition 
   _LOAD["Twin1:Img-Intro0.Abk",9]
   Fade 1
   Wait 15
   Screen Hide 3
   
   ' Image groupe 
   Screen Open 1,320,8,2,0
   Screen Hide 1
   Unpack 9 To 0
   Screen 1
   Get Palette 0
   Screen 0
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
   Auto View On 
   Fade 1,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF
   For I=1 To 16
      Colour Back Colour(0)
      Wait Vbl 
   Next I
   Wait 20
   Fade 1 To 1
   For I=1 To 16
      Colour Back Colour(0)
      Wait Vbl 
   Next I
   Screen Close 1
   
   ' On charge et on prépare l'intro
   If FAST=0
      _LOAD["Twin1:Img-Intro1a.Abk",9]
      _LOAD["Twin1:Img-Intro1b.Abk",10]
      _LOAD["Twin1:Img-Intro1c.Abk",11]
   Else 
      Screen Close 3
   End If 
   Screen 0
   Fade 1
   Wait 15
   Screen Close 0
   Auto View Off 
   If FAST=0
      For S=0 To 2
         Unpack S+9 To S
         Erase S+9
         Screen S
         Screen Hide S
      Next S
      Screen 2
      For I=0 To 31
         Colour I,0
      Next I
      View 
      Auto View On 
      Reserve As Chip Work 5,36662
      Reserve As Chip Work 6,53496
      Reserve As Chip Work 7,39876
      Reserve As Chip Work 8,19578
      Bload "Twin1:Samples-First1",5
      Bload "Twin1:Samples-First2",6
      Bload "Twin1:Samples-First3",7
      Bload "Twin1:Samples-First4",8
      Volume 0
      Shoot 
      Wait 10
      Volume 63
      Led On 
      
      ' Petite intro 
      Screen 3
      Screen Show 3
      Palette $0,$FFF
      Cls 0
      Ink 1,0
      Draw 320,120 To 321,120
      Sam Raw 15,Start(5),Length(5),14000
      Wait 140
      Erase 5
      Sam Raw 15,Start(6),Length(6),14000
      Wait 60
      Ink 0,0
      Draw 320,120 To 321,120
      Ink 1,0
      Set Text 3
      Wait 5
      CTXT["POWERMOB PRODUCTIONS",60]
      Set Text 0
      Wait 125
      Erase 6
      Sam Raw 15,Start(7),Length(7),14000
      Wait 25
      CTXT["THEVENOT",100]
      Wait 15
      CTXT["H I L P I P R E",126]
      Wait 18
      CTXT["A   M   I   C   E   L",152]
      Wait 65
      Fade 1
      Wait 15
      Screen Close 3
      Wait 10
      Erase 7
      Wait Vbl 
      Sam Raw %1001,Start(8),Length(8),7000
      Wait 3
      Sam Raw %110,Start(8),Length(8),7000
      Wait Vbl 
      Screen Offset 0,320,0
      Screen Show 0
      For X=320 To 0 Step -8
         Screen Offset 0,X,0
         Wait Vbl 
      Next X
      Screen Show 1
      For X=0 To 320 Step 8
         Screen Offset 1,X,0
         Wait Vbl 
      Next X
      Wait 20
      Screen Show 2
      Fade 1,$0,$FFF,$1,$2,$3,$4,$5,$6,$7,$8,$9,$A,$B,$C,$D,$E,$F,$1F,$12F,$23F,$34F,$45F,$56F,$67F,$78F,$89F,$9AF,$ABF,$BCF,$CDF,$DEF,$EFF
      Wait 80
      Erase 8
   End If 
   Voice 15
   Mvolume ZIKVOL
   Led Off 
   Music 1
   Tempo 17
   ZIKPLAYING=True
   QUELLEZIK=1
   
   ' Pour les options 
   _LOAD["Twin1:Options.abk",-1]
   Bank Swap 1,12
   _LOAD["Twin1:Img-OptionsA.Abk",13]
   _LOAD["Twin1:Img-OptionsB.Abk",14]
   _LOAD["Twin1:Img-OptionsC.Abk",15]
   
   ' Pour la présentation 
   _LOAD["Twin1:Lettres.Abk",-1]
   Bank Swap 1,2
   _LOAD["Twin1:Def-Sprites.Abk",-1]
   CHARGE_SCORES
   _LOAD["Twin1:Img-Intro2.Abk",9]
   _LOAD["Twin1:Img-Intro3.Abk",10]
End Proc
Procedure CTXT[T$,Y]
   Text 320-((Text Length(T$))/2),Y,T$
End Proc
Procedure PRESENTATION
   Shared ZIKVOL,ZIKPLAYING,V$,CLI1,CLI2,T$
   If Length(9)=0
      _LOAD["Twin1:Img-Intro2.abk",9]
      _LOAD["Twin1:Img-Intro3.abk",10]
   End If 
   If Len(T$)=0
      CHECK[1]
      Open In 1,"Twin1:Scroll.txt"
      L=Lof(1)
      T$=Input$(1,L)
      Close 1
      T$=T$-Chr$(10)
   End If 
   Auto View Off 
   Screen 0
   Cls 0
   Screen Open 3,336,8,2,Lowres
   Screen Display 3,128,292,320,8
   Palette $0,$AAA
   Set Rainbow 0,1,16,"","",""
   Restore CLR
   For I=0 To 9
      Read COUCOU
      Rain(0,I)=COUCOU
   Next I
   Rainbow 0,0,291,11
   CLR:
   Data $444,$777,$AAA,$CCC,$FFF,$FFF,$CCC,$AAA,$777,$444
   Cls 0
   Screen 0
   CLI1=-1
   CLI2=-1
   HALL_OF_FAME
   Unpack 9 To 1
   Unpack 10 To 2
   For I=0 To 2
      Screen I
      Screen Display I,128,40,,
      Palette 0,0,0,0
      Screen Hide I
   Next I
   Screen To Front 3
   Auto View On 
   If ZIKPLAYING=False
      Proc MUSIQUE[1,ZIKVOL]
   End If 
   Wait Vbl 
   SPEED=2
   Screen 3
   Def Scroll 1,0,0 To 336,8,-SPEED,0
   Ink 1
   Timer=0
   PRES_IMG=1
   Screen Show 1
   Screen 1
   Fade 1,$0,$FFF,$AAA,$555
   Screen 3
   Do 
      For X=1 To Len(T$)
         A$=Inkey$
         If A$<>""
            Exit If A$=" ",2
            A=Asc(A$)
            If A>=48
               If A<=53
                  If A=48
                     X=0
                     Cls 0
                  Else 
                     Add A,-48
                     P=1
                     For CH=1 To A
                        P2=Instr(T$,"$*",P)
                        Exit If P2=0
                        P=P2+1
                     Next CH
                     If P2>0
                        X=P2
                        Cls 0
                     End If 
                  End If 
               End If 
            End If 
         End If 
         L$=Mid$(T$,X,1)
         If L$="$"
            Inc X
            L$=Mid$(T$,X,1)
            If L$="1"
               SPEED=1
            End If 
            If L$="2"
               SPEED=2
            End If 
            If L$="4"
               SPEED=4
            End If 
            If L$="8"
               SPEED=8
            End If 
            If L$="P"
               Wait 50
            End If 
            If L$="p"
               Wait 10
            End If 
            Def Scroll 1,0,0 To 336,8,-SPEED,0
         Else 
            Text 320,6,L$
            For Y=1 To 8/SPEED
               Scroll 1
               Wait Vbl 
               Exit If(Fire(1)) or(Fire(0)),3
            Next Y
         End If 
         If Timer>=500
            If Timer>=520
               Screen Hide PRES_IMG
               Add PRES_IMG,1,0 To 2
               Screen Show PRES_IMG
               Screen PRES_IMG
               Fade 1,0,$FFF,$AAA,$555
               Timer=0
            Else 
               Screen PRES_IMG
               Fade 1
            End If 
            Screen 3
         End If 
      Next X
   Loop 
   While Fire(1) or Fire(0)
      Multi Wait 
   Wend 
   Screen 3
   Cls 0
   Rainbow Del 
   Wait Vbl 
   Screen PRES_IMG
   Fade 1
   Wait 15
   Screen Close 3
   Screen Close 2
   Screen Close 1
   Screen 0
   Screen To Front 0
   Flash Off 
   Cls 0
End Proc
Procedure OPTIONS
   Shared ZIKVOL,SFXVOL,JEUXVOL,PUBON,NAME1$,NAME2$,C$
   Shared USER,PARTIE,CASE,J,SECRET1$(),SECRET2$(),DEPART,FLAGCODE
   
   ' On récupère ce qu'il nous faut 
   Bank Swap 1,12
   Make Mask 
   Screen Close 0
   Auto View Off 
   
   Unpack 13 To 0
   Unpack 14 To 1
   Unpack 15 To 2
   
   ' 3 icônes à droite
   Ink 0
   Paste Bob 163,7,9+PUBON
   Paste Bob 218,7,10-USER
   Paste Bob 272,7,12
   
   ' icônes volume
   Paste Bob 10,2,1
   Paste Bob 10,38,2
   Paste Bob 10,74,3
   
   ' barres de volume 
   Paste Bob 49,7,7
   Paste Bob 49,43,7
   Paste Bob 49,79,7
   Ink 9
   Bar 64,10 To 64+ZIKVOL,23
   Bar 64,46 To 64+SFXVOL,59
   Bar 64,82 To 64+JEUXVOL,95
   
   ' Codes
   BON=False
   For I=1 To 9
      If C$=SECRET1$(I)
         BON=True
         DEPART=I*5
         If(I=0) or((I>=4) and(USER=False))
            Inc DEPART
         End If 
         FLAGCODE=1
      End If 
   Next I
   For I=1 To 10
      If C$=SECRET2$(I)
         BON=True
         DEPART=I*5
         If(I=0) or((I>=4) and(USER=False))
            Inc DEPART
         End If 
         FLAGCODE=2
      End If 
   Next I
   If BON=False
      DEPART=21
      If C$<>"GAME"
         C$="0000"
      End If 
   End If 
   Paste Bob 179,67,14
   Ink 5,26
   Text 193,80,C$
   
   ' N° du niveau 
   D$=Str$(DEPART)-" "
   If Len(D$)=1
      D$="0"+D$
   End If 
   I1=Val(Left$(D$,1))+16
   I2=Val(Right$(D$,1))+16
   Paste Bob 249,59,15
   Paste Bob 253,63,I1
   Paste Bob 274,63,I2
   
   ' Noms des joueurs 
   Screen 1
   Colour 2,$492
   Colour 11,$492
   Ink 4,2
   Text 12,29,Left$(NAME1$,12)
   Ink 4,11
   Text 208,29,Left$(NAME2$,12)
   
   ' Joysticks
   Screen 0
   If PARTIE=1
      Paste Bob 16,2,28
      Paste Bob 240,2,27
   Else 
      Paste Bob 16,2,26
      Paste Bob 240,2,29
   End If 
   
   Wait Vbl 
   Auto View On 
   View 
   
   '--------------
   
   CASE=PARTIE
   FINISHED=False
   Repeat 
      J=Joy(1)
      If(Key State(76)=True) and(Key State(77)=False)
         J=1
      End If 
      If(Key State(77)=True) and(Key State(76)=False)
         J=2
      End If 
      If(Key State(79)=True) and(Key State(78)=False)
         J=4
      End If 
      If(Key State(78)=True) and(Key State(79)=False)
         J=8
      End If 
      If Key State(64)=True
         J=16
      End If 
      If J>0
         If J=16
            If CASE=1
               PARTIE=1
               FINISHED=True
            End If 
            If CASE=2
               PARTIE=2
               FINISHED=True
            End If 
            If CASE=3
               Clear Key 
               Screen 1
               Ink 4,2
               Text 12,29,Space$(12)
               NAME1$=""
               B$="_"
               Do 
                  A$=Inkey$
                  Exit If A$=Chr$(13)
                  If A$=Chr$(8)
                     NAME1$=Left$(NAME1$,Len(NAME1$)-1)
                  Else 
                     If Len(NAME1$)<12
                        NAME1$=NAME1$+A$
                     End If 
                  End If 
                  B$=NAME1$+"_ "
                  Text 12,29,Left$(B$,12)
               Loop 
               Text 12,29,Left$(NAME1$+" ",12)
            End If 
            If CASE=4
               Clear Key 
               Screen 1
               Ink 4,11
               Text 208,29,Space$(12)
               NAME2$=""
               B$="_"
               Do 
                  A$=Inkey$
                  Exit If A$=Chr$(13)
                  If A$=Chr$(8)
                     NAME2$=Left$(NAME2$,Len(NAME2$)-1)
                  Else 
                     If Len(NAME2$)<12
                        NAME2$=NAME2$+A$
                     End If 
                  End If 
                  B$=NAME2$+"_ "
                  Text 208,29,Left$(B$,12)
               Loop 
               Text 208,29,Left$(NAME2$+" ",12)
            End If 
            If CASE=5
               Screen 2
               While Fire(1)
                  If Jleft(1)
                     Gosub ZIKVM
                  End If 
                  If Jright(1)
                     Gosub ZIKVP
                  End If 
                  Wait Vbl 
               Wend 
            End If 
            If CASE=6
               Screen 2
               While Fire(1)
                  If Jleft(1)
                     Gosub SFXVM
                  End If 
                  If Jright(1)
                     Gosub SFXVP
                  End If 
                  Wait Vbl 
               Wend 
            End If 
            If CASE=7
               Screen 2
               While Fire(1)
                  If Jleft(1)
                     Gosub JEUXVM
                  End If 
                  If Jright(1)
                     Gosub JEUXVP
                  End If 
                  Wait Vbl 
               Wend 
            End If 
            If CASE=8
               PUBON= Not(PUBON)
               Screen 2
               Ink 0
               Wait Vbl 
               Bob Clear 
               Bar 163,7 To 202,46
               Paste Bob 163,7,9+PUBON
               Bob Draw 
               Wait Vbl 
            End If 
            If CASE=9
               USER= Not(USER)
               Screen 2
               Ink 0
               Wait Vbl 
               Bob Clear 
               Bar 218,7 To 257,46
               Paste Bob 218,7,10-USER
               Bob Draw 
               Wait Vbl 
               If(C$=SECRET1$(4)) or(C$=SECRET2$(4))
                  DEPART=21+USER
                  D$=Str$(DEPART)-" "
                  I1=Val(Left$(D$,1))+16
                  I2=Val(Right$(D$,1))+16
                  Wait Vbl 
                  Bob Clear 
                  Paste Bob 253,63,I1
                  Paste Bob 274,63,I2
                  Bob Draw 
                  Wait Vbl 
               End If 
            End If 
            If CASE=10
               Screen 2
               Ink 0
               Wait Vbl 
               Bar 272,7 To 311,46
               Paste Bob 272,7,13
               SAUVE_PREFS
               Wait Vbl 
               Bar 272,7 To 311,46
               Paste Bob 272,7,12
            End If 
            If CASE=11
               Screen 2
               Ink 26,26
               Wait Vbl 
               Bob Clear 
               Text 193,80,"    "
               Bob Draw 
               C$=""
               Ink 5,26
               Clear Key 
               For I=1 To 4
                  Repeat 
                     A$=Upper$(Inkey$)
                     A=Asc(A$)
                  Until((A>=48) and(A<=57)) or((A>=65) and(A<=90))
                  C$=C$+A$
                  Text 193,80,C$
               Next I
               BON=False
               For I=0 To 19
                  If C$=SECRET1$(I)
                     BON=True
                     DEPART=I*5
                     If(I=0) or((I=4) and(USER=False))
                        Inc DEPART
                     End If 
                     FLAGCODE=1
                     Screen 0
                     Paste Bob 16,2,28
                     Wait 20
                     Ink 0
                     Bar 16,2 To 80,66
                     Paste Bob 16,2,26
                     Screen 2
                     Exit 
                  Else 
                     If C$=SECRET2$(I)
                        BON=True
                        DEPART=I*5
                        If(I=0) or((I=4) and(USER=False))
                           Inc DEPART
                        End If 
                        FLAGCODE=2
                        Screen 0
                        Paste Bob 240,2,29
                        Wait 20
                        Ink 0
                        Bar 240,2 To 304,66
                        Paste Bob 240,2,27
                        Screen 2
                        Exit 
                     End If 
                  End If 
               Next I
               If BON=False
                  If C$<>"GAME"
                     C$="0000"
                  End If 
                  Wait Vbl 
                  DEPART=21
               End If 
               Ink 5,26
               Wait Vbl 
               Bob Clear 
               Text 193,80,C$
               Bob Draw 
               D$=Str$(DEPART)-" "
               If Len(D$)=1
                  D$="0"+D$
               End If 
               I1=Val(Left$(D$,1))+16
               I2=Val(Right$(D$,1))+16
               Bob Clear 
               Paste Bob 253,63,I1
               Paste Bob 274,63,I2
               Bob Draw 
            End If 
         Else 
            Proc NOUVELLE_CASE
         End If 
         Repeat 
            Wait Vbl 
            J=Joy(1)
            If(Key State(76)=True) and(Key State(77)=False)
               J=1
            End If 
            If(Key State(77)=True) and(Key State(76)=False)
               J=2
            End If 
            If(Key State(79)=True) and(Key State(78)=False)
               J=4
            End If 
            If(Key State(78)=True) and(Key State(79)=False)
               J=8
            End If 
            If Key State(64)=True
               J=16
            End If 
         Until J=0
      End If 
      KK$=Inkey$
      If KK$="+"
         If CASE=5
            Gosub ZIKVP
         End If 
         If CASE=6
            Gosub SFXVP
         End If 
         If CASE=7
            Gosub JEUXVP
         End If 
      End If 
      If KK$="-"
         If CASE=5
            Gosub ZIKVM
         End If 
         If CASE=6
            Gosub SFXVM
         End If 
         If CASE=7
            Gosub JEUXVM
         End If 
      End If 
   Until FINISHED
   '--------------
   For I=ZIKVOL To 0 Step -1
      Volume I
      Wait Vbl 
   Next I
   MUSIQUE_OFF
   Erase 3
   Auto View Off 
   Bob Off 
   
   Bank Swap 1,12
   
   Screen Close 2
   Screen Close 1
   Screen Close 0
   Screen Open 0,320,256,32,0
   Screen Display 0,128,40,320,256
   Flash Off 
   Curs Off 
   Hide On 
   Get Sprite Palette 
   Cls 0
   Double Buffer 
   Autoback 1
   Wait Vbl 
   Auto View On 
   View 
   Pop Proc
   '
   ZIKVM:
   If ZIKVOL>0
      Dec ZIKVOL
      Volume ZIKVOL
      Ink 5
      Draw 65+ZIKVOL,10 To 65+ZIKVOL,23
   End If 
   Return 
   ZIKVP:
   If ZIKVOL<63
      Inc ZIKVOL
      Volume ZIKVOL
      Ink 9
      Draw 64+ZIKVOL,10 To 64+ZIKVOL,23
   End If 
   Return 
   SFXVM:
   If SFXVOL>0
      Dec SFXVOL
      Ink 5
      Draw 65+SFXVOL,46 To 65+SFXVOL,59
   End If 
   Return 
   SFXVP:
   If SFXVOL<63
      Inc SFXVOL
      Ink 9
      Draw 64+SFXVOL,46 To 64+SFXVOL,59
   End If 
   Return 
   JEUXVM:
   If JEUXVOL>0
      Dec JEUXVOL
      Ink 5
      Draw 65+JEUXVOL,82 To 65+JEUXVOL,95
   End If 
   Return 
   JEUXVP:
   If JEUXVOL<63
      Inc JEUXVOL
      Ink 9
      Draw 64+JEUXVOL,82 To 64+JEUXVOL,95
   End If 
   Return 
End Proc
Procedure HALL_OF_FAME
   Shared HISCORE(),HISCORE$(),HIMODE(),MSG_SCORES,CLI1,CLI2
   Autoback 0
   Flash Off 
   Palette 0,0,0,0,0
   Cls 0
   _MESSAGE[MSG_SCORES,0]
   Ink 1,0
   For I=1 To 10
      H$=Str$(HISCORE(I))-" "
      S$=Right$(Str$(I),2)
      If I=1
         S$=S$+"ST"
      Else 
         If I=2
            S$=S$+"ND"
         Else 
            If I=3
               S$=S$+"RD"
            Else 
               S$=S$+"TH"
            End If 
         End If 
      End If 
      If HIMODE(I)=False
         S$=S$+" A "
      Else 
         S$=S$+" B "
      End If 
      S$=S$+String$("0",6-Len(H$))+H$+"  "+HISCORE$(I)
      If(I=CLI1) or(I=CLI2)
         Ink 4
      Else 
         Ink 1
      End If 
      Text 16,12*I+80,S$
   Next I
   Screen Copy Logic(0) To Physic(0)
   Autoback 2
End Proc
Procedure FIN
   Erase 2
   Music Off 
   Erase 3
   Erase 5
   Erase 9
   Erase 10
   Amal Off 
   Bob Off 
   Shift Off 
   Erase 1
   Request On 
   Amos Unlock 
   End 
End Proc
Procedure WELLDONE
   Shared USER
   If USER
      USER_WELLDONE
   End If 
End Proc
Procedure USER_WELLDONE
   Fade 1
   Wait 15
   Cls 0
   Paper 0
   Pen 1
   Locate 0,5
   Centre "IL N'Y A PLUS DE TABLEAUX" : Print 
   Centre "EN MODE UTILISATEUR !" : Print 
   Locate 0,10
   Centre "Si vous voulez en ajouter, alors" : Print 
   Centre "utilisez le Super-Editeur-De-Tableaux !" : Print 
   Locate 0,15
   Centre "Vous trouverez le mode d'emploi de" : Print 
   Centre "celui-ci dans la documentation."
   Locate 0,26
   Centre "- Appuyez sur Fire -"
   Fade 1,$0,$FFF
   Wait 15
   Clear Key 
   Repeat 
      Multi Wait 
   Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
   Fade 1
   Wait 15
   Cls 0
End Proc
Procedure _COPYRIGHT
   _LOAD["Twin1:Img-Copyright.Abk",10]
   YDISPLAY=75
   Unpack 10 To 7
   For Y=2 To Screen Height/2 Step 4
      Screen Display 7,,YDISPLAY+Screen Height/2-Y,,Y*2
      Screen Offset 7,,Screen Height/2-Y
      View 
      Wait Vbl 
   Next Y
   T=Timer
   Clear Key 
   Repeat 
      Multi Wait 
   Until(Len(Inkey$)>0) or(Fire(1)) or(Fire(0)) or(Timer-T>200)
   For Y=Screen Height/2 To 0 Step -4
      Screen Display 7,,YDISPLAY+Screen Height/2-Y,,Y*2
      Screen Offset 7,,Screen Height/2-Y
      View 
      Wait Vbl 
   Next Y
   Screen Close 7
   Erase 10
End Proc
Procedure INIT_TABLEAU
   Shared LEVEL,VICT(),CREDITS,ZIKVOL,SFXVOL
   Shared JOUEUR(),TIR(),MORT1,MORT2,INV(),SUPER()
   Shared XD1,YD1,XD2,YD2,PARTIE,BONUS,CURBONUS
   Shared TEMPS(),MXTEMPS(),MEMETEMPS,MXTEMPSTOTAL
   Shared ENNEMI(),DANSLESPOMMES(),NBMONSTRES
   Shared TRESOR(),NBTRESORS,TRESOR_TOMBE()
   Shared YAITEM,ITEM,ITEMX,ITEMY
   
   Auto View Off 
   Screen Open 0,320,256,32,Lowres
   Screen Hide 0
   Curs Off 
   Flash Off 
   Hide On 
   Wait Vbl 
   Cls 0
   Unpack 9 To 1
   Screen 0
   Get Palette 1
   Wait Vbl 
   Screen Copy 1 To 0
   Wait Vbl 
   Screen Close 1
   Screen Display 0,128,40,320,256
   Ink 9,0
   Text 268,185,"LEVEL"
   Text 260,208,"CREDITS"
   Text 268,231,"VICT."
   Ink 10,0
   L$=Str$(LEVEL)-" "
   If Len(L$)=1
      L$="0"+L$
   End If 
   Text 280,195,L$
   L$=Str$(CREDITS)-" "
   If Len(L$)=1
      L$="0"+L$
   End If 
   Text 280,218,L$
   L$=(Str$(VICT(1))-" ")+" /"+Str$(VICT(2))
   If Len(Str$(VICT(1)))+Len(Str$(VICT(2)))=4
      L$=" "+L$
   End If 
   Text 260,241,L$
   
   TEMPS(1)=MXTEMPS(1)
   If PARTIE=2
      If MEMETEMPS
         MXTEMPS(2)=MXTEMPS(1)
      End If 
      TEMPS(2)=MXTEMPS(2)
      Ink 4
      Bar 241,208-TEMPS(2) To 254,207
   Else 
      Ink 8
      T=208-(MXTEMPSTOTAL/78)
      Bar 241,T To 254,207
      Ink 4
   End If 
   Bar 1,208-TEMPS(1) To 14,207
   Proc UPDSCORE[0,0]
   
   Double Buffer 
   Autoback 1
   Priority Reverse On 
   
   NBTRESORS=0
   For X=1 To 14
      For Y=1 To 14
         C(X,Y)=C2(X,Y)
         If C(X,Y)>0
            If C(X,Y)=43
               C(X,Y)=0
               If NBTRESORS<5
                  Inc NBTRESORS
                  Bob TRESOR(NBTRESORS),X*16,Y*16-1,43
               End If 
            Else 
               Paste Bob X*16,Y*16-16,C(X,Y)
            End If 
         End If 
      Next Y
   Next X
   For I=1 To NBTRESORS
      TRESOR_TOMBE(I)=0
   Next I
   
   X=XD1*16
   Y=YD1*16-1
   Bob JOUEUR(1),X,Y,178
   Channel 1 To Bob JOUEUR(1)
   Channel 10 To Bob JOUEUR(1)
   Amal 10,"Anim 0,(251,4)(252,4)(253,4);"
   If PARTIE=2
      X=XD2*16
      Y=YD2*16-1
      Bob JOUEUR(2),X,Y,177
      Channel 2 To Bob JOUEUR(2)
      Channel 11 To Bob JOUEUR(2)
      Amal 11,"Anim 0,(248,4)(249,4)(250,4);"
   End If 
   Limit Bob 16,0 To 240,224
   
   A$="      Let RA=0;"
   A$=A$+"Loop:"
   A$=A$+"   If RA=0 then Jump Loop;"
   A$=A$+"   Let X=RC; Let Y=RD;"
   A$=A$+"   If RE=1 then Jump M;"
   A$=A$+"   Let A=45;"
   A$=A$+"   Move -48,0,12;"
   A$=A$+"   Jump N;"
   A$=A$+"M: Let A=44"
   A$=A$+"   Move 48,0,12;"
   A$=A$+"N: Let Y=320;"
   A$=A$+"   Let RA=0"
   A$=A$+"   Jump Loop;"
   Bob TIR(1),10,320,44
   Limit Bob TIR(1),16,0 To 240,224
   Channel 3 To Bob TIR(1)
   Amal 3,A$
   
   If PARTIE=2
      A$="      Let RF=0;"
      A$=A$+"Loop:"
      A$=A$+"   If RF=0 then Jump Loop;"
      A$=A$+"   Let X=RH; Let Y=RI;"
      A$=A$+"   If RJ=1 then Jump M;"
      A$=A$+"   Let A=45;"
      A$=A$+"   Move -48,0,12;"
      A$=A$+"   Jump N;"
      A$=A$+"M: Let A=44;"
      A$=A$+"   Move 48,0,12;"
      A$=A$+"N: Let Y=320;"
      A$=A$+"   Let RF=0"
      A$=A$+"   Jump Loop;"
      Bob TIR(2),30,320,45
      Limit Bob TIR(2),16,0 To 240,224
      Channel 4 To Bob TIR(2)
      Amal 4,A$
   End If 
   
   Bob 16,0,208,46
   Bob 17,240,208,47
   Channel 12 To Bob 16
   Channel 13 To Bob 17
   Channel BONUS To Bob BONUS
   
   FOUTRE_MONSTRES
   For I=1 To NBMONSTRES
      DANSLESPOMMES(I)=0
   Next I
   
   If YAITEM
      A$=""
      If ITEM=79
         A$="A0,(79,20)(80,20);"
      Else 
         If B=57
            A$="A0,(57,2)(58,2)(59,2);"
         Else 
            If B=60
               A$="A0,(60,1)(61,1)(62,1)(63,1)(64,1)(65,1);"
            End If 
         End If 
      End If 
      Bob BONUS,ITEMX*16,(ITEMY-1)*16,ITEM
      Amal BONUS,A$
      Amal On BONUS
      CURBONUS=ITEM
   End If 
   
   Clear Key 
   Auto View On 
   Screen Show 0
   Volume SFXVOL
   Mvolume 0
   MUSIQUE[2,ZIKVOL]
   Wait Vbl 
End Proc
Procedure EFFET_BONUS[N]
   Shared CURBONUS,CREDITS,PARTIE,ZIKVOL
   Shared MORT1,MORT2,PARALIZED1,PARALIZED2,PANOU(),FBALL()
   Shared TEMPS(),MXTEMPS(),MEMETEMPS
   Shared FASTX(),FASTY(),INV(),SUPER(),SCORE(),QB()
   Shared X1,Y1,TRESOR(),TRESOR_TOMBE(),TIR(),CARRY1,X2,Y2,CARRY2
   Shared STATE(),JUMPING
   A=CURBONUS
   If N=1
      VOIX=%1
   Else 
      VOIX=%10
   End If 
   '---------------- ?
   If A=72
      Repeat 
         A=Rnd(200)
         A=QB(A)
      Until(A>59) and(A<>72)
      If PARTIE=1
         If B=69
            Inc B
         End If 
      Else 
         If B=70
            Dec B
         End If 
      End If 
   End If 
   ' ------------------- Bonus
   L$=("B"+Str$(A))-" "
   Gosub L$
   Pop Proc
   ' ---- Fraise
   B48:
   Sam Play VOIX,1
   UPDSCORE[N,100]
   Return 
   ' ---- Citron
   B49:
   Sam Play VOIX,1
   UPDSCORE[N,150]
   Return 
   ' ---- Poire 
   B50:
   Sam Play VOIX,1
   UPDSCORE[N,200]
   Return 
   ' ---- Pomme 
   B51:
   Sam Play VOIX,1
   UPDSCORE[N,250]
   Return 
   ' ---- Pamplemousse
   B54:
   Sam Play VOIX,1
   UPDSCORE[N,300]
   Return 
   ' ---- Banane
   B52:
   Sam Play VOIX,1
   UPDSCORE[N,350]
   Return 
   ' ---- Mutant
   B53:
   Sam Play VOIX,7
   UPDSCORE[N,-500]
   Return 
   ' ---- Hamburger 
   B55:
   Sam Play VOIX,1
   UPDSCORE[N,500]
   Return 
   ' ---- Jewel 
   B56:
   Sam Play VOIX,1
   UPDSCORE[N,5000]
   Return 
   ' ---- Diamant 
   B57:
   Sam Play VOIX,8
   UPDSCORE[N,25000]
   Return 
   ' ------------------- Items
   ' ---- Poison
   B66:
   If N=1
      MORT1=True
      Sam Play VOIX,4
      J1_ANIM
      Bob Off TIR(1)
      If CARRY1<>0
         Bob TRESOR(CARRY1),X1-X1 mod 16,Y1,43
         TRESOR_TOMBE(CARRY1)=True
      End If 
      UPDSCORE[0,0]
   Else 
      MORT2=True
      Sam Play VOIX,5
      J2_ANIM
      Bob Off TIR(2)
      If CARRY2<>0
         Bob TRESOR(CARRY2),X2-X2 mod 16,Y2,43
         TRESOR_TOMBE(CARRY2)=True
      End If 
      UPDSCORE[0,0]
   End If 
   Return 
   ' ---- Gant de boxe
   B67:
   If PARTIE=2
      B=Rnd(3)
      If B>0
         Add N,1,1 To 2
      End If 
      If MORT1
         N=2
      End If 
      If MORT2
         N=1
      End If 
   End If 
   If N=1
      Gosub PAR1
   Else 
      Gosub PAR2
   End If 
   Return 
   ' ---- Shaker
   B68:
   Sam Play VOIX,7
   If PARTIE=2
      Swap SCORE(1),SCORE(2)
   Else 
      SCORE(1)=(SCORE(1)/2)+Rnd(SCORE(1)/2)
      SCORE(1)=SCORE(1)-(SCORE(1) mod 10)
   End If 
   UPDSCORE[0,0]
   Return 
   ' ---- 1UP ou Coeur
   B69:
   B70:
   Sam Play VOIX,2
   CREDITS=Min(99,CREDITS+1)
   Gosub WCRED
   Return 
   ' ---- Skate 
   B71:
   Sam Play VOIX,8
   FASTX(N)=True
   If(STATE(N)=JUMPING) and(FASTY(N)=0)
      FASTY(N)=1
   Else 
      FASTY(N)=True
   End If 
   If N=1
      X1=X1-X1 mod 4
      Bob 1,X1,,
   Else 
      X2=X2-X2 mod 4
      Bob 2,X2,,
   End If 
   Return 
   ' ---- Roller
   B73:
   Sam Play VOIX,8
   FASTX(N)=True
   If N=1
      X1=X1-X1 mod 4
      Bob 1,X1,,
   Else 
      X2=X2-X2 mod 4
      Bob 2,X2,,
   End If 
   Return 
   ' ---- Ressort 
   B74:
   Sam Play VOIX,8
   If(STATE(N)=JUMPING) and(FASTY(N)=0)
      FASTY(N)=1
   Else 
      FASTY(N)=True
   End If 
   Return 
   ' ---- Joystick
   B75:
   Sam Play VOIX,2
   UPDSCORE[N,500]
   If PARTIE=2
      If MORT1
         N=2
      End If 
      If MORT2
         N=1
      End If 
   End If 
   If(PARTIE=1) or(N=2)
      INV(1)= Not(INV(1))
   Else 
      INV(2)= Not(INV(2))
   End If 
   Return 
   ' ---- Thermo
   B76:
   If PARTIE=2
      B=Rnd(3)
      If B=0
         Add N,1,1 To 2
      End If 
      If MORT1
         N=2
      End If 
      If MORT2
         N=1
      End If 
   End If 
   If N=1
      Gosub PAR1
   Else 
      Gosub PAR2
   End If 
   Return 
   ' ---- Guru
   B79:
   Sam Play VOIX,7
   For I=1 To 3
      Wait 25
      Led On 
      Wait 25
      Led Off 
   Next I
   Volume 0
   Screen Hide 0
   Wait 10
   Auto View Off 
   Screen Open 5,640,48,4,Hires
   Palette 0,$F00
   Flash Off 
   Flash 3,"(f00,30)(000,30)"
   Cls 3
   Ink 0
   Bar 6,3 To 632,44
   Ink 1,0
   Text 16,20,"Le programmeur vous prie d'excuser cette interruption momentanée de l'image."
   Text 24,34,"     Guru Coucou  -  Pressez Fire  -  Attention psychédélisme en vue ! "
   Auto View On 
   _PERMIT
   Clear Key 
   Repeat 
   Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
   _FORBID
   Screen Close 5
   Screen Show 0
   Volume ZIKVOL
   Tempo 30
   Shift Up 5,1,31,1
   Return 
   ' ---- Verre 
   B77:
   Sam Play VOIX,6
   Ink 4
   If(N=2) and(MEMETEMPS=False)
      TEMPS(2)=MXTEMPS(2)
      Bar 241,208-TEMPS(2) To 254,207
   Else 
      TEMPS(1)=MXTEMPS(1)
      Bar 1,208-TEMPS(1) To 14,207
      If MEMETEMPS
         Bar 241,208-TEMPS(1) To 254,207
      End If 
   End If 
   Return 
   ' ---- Marteau 
   B78:
   Sam Play VOIX,1
   Return 
   ' ---- Etoile
   B60:
   Sam Play VOIX,8
   SUPER(N)= Not(SUPER(N))
   UPDSCORE[0,0]
   Return 
   '
   '  <<<< NOUVEAUTES >>>>
   '
   ' ---- Eclair
   B260:
   Sam Play VOIX,8
   FBALL(N)= Not(FBALL(N))
   Return 
   ' ---- Super-Mec 
   B261:
   Gosub B73
   Gosub B60
   Return 
   ' ---- Coeur brisé 
   B262:
   Dec CREDITS
   If CREDITS<1
      CREDITS=1
   End If 
   Gosub WCRED
   Return 
   '
   '
   ' ---- Paraliser 1 
   PAR1:
   If PARALIZED1=0
      Sam Play VOIX,4
      PARALIZED1=1
      PANOU(1)=False
      Amal Freeze 1
      Amal On 10
      UPDSCORE[2,100]
   End If 
   Return 
   ' ---- Paraliser 2 
   PAR2:
   If PARALIZED2=0
      Sam Play VOIX,5
      PARALIZED2=1
      PANOU(2)=False
      Amal Freeze 2
      Amal On 11
      UPDSCORE[1,100]
   End If 
   Return 
   ' ---- Afficher crédits
   WCRED:
   L$=Str$(CREDITS)-" "
   If Len(L$)=1
      L$="0"+L$
   End If 
   Ink 10,0
   Text 280,218,L$
   Return 
End Proc
Procedure SELECT
   Shared MSG_SELECT
   Cls 0
   _MESSAGE[MSG_SELECT,0]
   R=1
   DRSEL[R]
   Fade 1,$0,$FFF,$AAA,$555
   Flash 4,"(FFF,5)(000,5)"
   Repeat 
      If(Jup(1)) or(Key State(76))
         Add R,-1,1 To 3
         DRSEL[R]
         While(Jup(1)) or(Key State(76))
         Wend 
      End If 
      If(Jdown(1)) or(Key State(77))
         Add R,1,1 To 3
         DRSEL[R]
         While(Jdown(1)) or(Key State(77))
         Wend 
      End If 
   Until(Fire(1)) or(Key State(64))
   Flash Off 
   Fade 1
   Wait 15
   Cls 0
End Proc[R]
Procedure DRSEL[N]
   Ink 1+(N=1)*(-3),0
   Text 80,120,"REFAIRE UNE PARTIE"
   Ink 1+(N=2)*(-3),0
   Text 80,140,"RETOUR AUX OPTIONS"
   Ink 1+(N=3)*(-3),0
   Text 88,160,"RETOUR A L'INTRO"
End Proc
Procedure _MESSAGE[N,W]
   Shared LEVEL,TEMPSTOTAL,MXTEMPSTOTAL,SECRET1$(),SECRET2$(),TBLB,PARTIE
   Bank Swap 1,2
   L=Len(Str$(LEVEL)-" ")
   If L=1
      L1=28
      L2=LEVEL+28
   Else 
      L1=(LEVEL/10)+28
      L2=(LEVEL mod 10)+28
   End If 
   Cls 0
   Palette 0,0,0,0
   Restore "M"+Str$(N)-" "
   Read NB
   For I=1 To NB
      Read X,Y,A
      If Y=0
         Y=80
      End If 
      If N=3
         If I=6 and A=29
            Add X,10
         End If 
      End If 
      Paste Bob X,Y,A
   Next I
   If(N=4) or(N=7)
      Locate 0,25
      Paper 0
      Pen 1
      If TBLB
         Centre "BONUS 10.000 pts"
      Else 
         Centre "TIME BONUS ="+Str$(Max(0,(MXTEMPSTOTAL-TEMPSTOTAL)/178*100))
         If(((LEVEL mod 5)=4) and(LEVEL<21))
            Locate 0,27
            If PARTIE=1
               Centre "CODE SECRET MAGIQUE : "+SECRET1$((LEVEL+1)/5)
            Else 
               Centre "CODE SECRET MAGIQUE : "+SECRET2$((LEVEL+1)/5)
            End If 
         End If 
         If(((LEVEL mod 5)=0) and(LEVEL>21))
            Locate 0,27
            If PARTIE=1
               Centre "CODE SECRET MAGIQUE : "+SECRET1$((LEVEL)/5)
            Else 
               Centre "CODE SECRET MAGIQUE : "+SECRET2$((LEVEL)/5)
            End If 
         End If 
      End If 
   End If 
   If N<8
      Fade 1,0,$FFF,$AAA,$555
      Wait 15
      If N<>3
         While Fire(1) or Fire(0)
            Multi Wait 
         Wend 
         Clear Key 
         Timer=0
         Repeat 
            Multi Wait 
         Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0) or(Timer>=400)
         Fade 1
         Wait 15
         Cls 0
      End If 
   End If 
   Bank Swap 1,2
   M1: Data 5,66,,15,103,,8,152,,14,186,,15,232,,38
   M2: Data 8,30,,7,62,,1,98,,13,130,,5,170,,15,202,,22,244,,5,270,,18
   M3: Data 15,45,50,12,73,50,5,97,50,22,139,50,5,163,50,12,205,50,L1,235-(L2=29)*4,50,L2
   Data 35,100,7,69,100,5,93,100,20,137,100,18,165,100,5,187,100,1,225,100,4,250,100,25
   M4: Data 18,20,70,20,50,70,8,80,70,5,124,70,23,158,70,9,180,70,14,214,70,14,247,70,5,271,70,18
   Data 20,110,9,42,110,19,87,110,16,116,110,12,144,110,1,176,110,25,206,110,5
   Data 232,110,18,272-(W=1)*8,110,W+28
   M5: Data 7,54,77,27,80,,7,114,,1,154,,12,184,,9,206,,20,236,77,27
   M6: Data 10,78,60,2,108,60,15,145,60,14,180,60,21,211,60,19
   Data 82,110,19,112,110,20,136,110,1,174,110,7,210,110,5
   M7: Data 7,38,,7,72,,15,106,,15,140,,4,188,,10,216,,15,250,,2
   M8: Data 6,70,40,19,102,40,5,130,40,12,162,40,5,188,40,3,222,40,20
   M9: Data 6,70,26,19,98,26,3,131,26,15,164,26,18,192,26,5,216,26,19
End Proc
Procedure PUB
   S=Screen
   Screen Hide S
   _LOAD["Twin2:Img-Publogo.Abk",10]
   Unpack 10 To 4
   Erase 10
   N=0
   Repeat 
      Inc N
      F$=("Twin2:Img-Pub"+Str$(N)+".Abk")-" "
   Until Exist(F$)=False
   Add N,-2
   N=Rnd(N)+1
   F$=("Twin2:Img-Pub"+Str$(N)+".Abk")-" "
   _LOAD[F$,10]
   Wait 150
   Unpack 10 To 4
   Erase 10
   Clear Key 
   Repeat 
      Multi Wait 
   Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
   Fade 1
   Screen Close 4
   Screen S
   Screen Show S
   Wait 15
End Proc
Procedure GAME
   Shared MSG_SELECT
   Cls 0
   Palette 0,0,0,0,0
   _MESSAGE[MSG_SELECT,0]
   R=1
   DRSEL2[R]
   Fade 1,0,$FFF,$AAA,$555,$FFF
   Wait 15
   Flash 4,"(FFF,5)(000,5)"
   Repeat 
      If(Jup(1)) or(Key State(76))
         Add R,-1,1 To 7
         DRSEL2[R]
         While(Jup(1)) or(Key State(76))
         Wend 
      End If 
      If(Jdown(1)) or(Key State(77))
         Add R,1,1 To 7
         DRSEL2[R]
         While(Jdown(1)) or(Key State(77))
         Wend 
      End If 
   Until(Fire(1)) or(Key State(64))
   Flash Off 
   Fade 1
   Wait 15
   Cls 0
   On R Proc JEU4,JEU3,JEU2,JEU1,JEU6,JEU7,JEU5
End Proc
Procedure DRSEL2[N]
   Ink 1+(N=1)*(-3),0
   Text 124,100,"PING-PONG"
   Ink 1+(N=2)*(-3),0
   Text 136,120,"TUTURE"
   Ink 1+(N=3)*(-3),0
   Text 116,140,"SECOUEZ-MOI"
   Ink 1+(N=4)*(-3),0
   Text 136,160,"T.L.C."
   Ink 1+(N=5)*(-3),0
   Text 132,180,"PAK MAN"
   Ink 1+(N=6)*(-3),0
   Text 100,200,"LEMMINGSATOR II"
   Ink 1+(N=7)*(-3),0
   Text 92,220,"STRIP FIGHTER III"
End Proc
Procedure JEU[N]
   If N<=4
      On N Proc JEU1,JEU3,JEU2,JEU4
   Else 
      N=(N mod 5)+1
      On N Proc JEU4,JEU7,JEU6,JEU5,JEU3
   End If 
End Proc
Procedure JEU1
   ' Clone de Tron light cycles 
   Shared MSG_EGALITE,MSG_WINNER,SCORE(),JEUXVOL,TBLB
   Volume JEUXVOL
   Palette 0,$F,$F00,$FFF
   Paper 0
   Pen 3
   Cls 0
   Centre At(,0)+"EVITEZ LES COLLISIONS !"
   Centre At(,2)+"BONUS 10.000 Pts"
   Autoback 1
   Bob Update Off 
   Ink 3,0
   Box 0,32 To 319,255
   X1=32
   Y1=64
   S1=8
   P1=0
   X2=280
   Y2=200
   S2=4
   P2=0
   Repeat 
      If Jup(1) and S1<>2
         S1=1
      End If 
      If Jdown(1) and S1<>1
         S1=2
      End If 
      If Jleft(1) and S1<>8
         S1=4
      End If 
      If Jright(1) and S1<>4
         S1=8
      End If 
      If S1=1
         Dec Y1
      End If 
      If S1=2
         Inc Y1
      End If 
      If S1=4
         Dec X1
      End If 
      If S1=8
         Inc X1
      End If 
      If Point(X1,Y1)>0
         FIN=True
         P1=True
      End If 
      If((Jup(0)=True) or(Key State(76)=True)) and(S2<>2)
         S2=1
      End If 
      If((Jdown(0)=True) or(Key State(77)=True)) and(S2<>1)
         S2=2
      End If 
      If((Jleft(0)=True) or(Key State(79)=True)) and(S2<>8)
         S2=4
      End If 
      If((Jright(0)=True) or(Key State(78)=True)) and(S2<>4)
         S2=8
      End If 
      If S2=1
         Dec Y2
      End If 
      If S2=2
         Inc Y2
      End If 
      If S2=4
         Dec X2
      End If 
      If S2=8
         Inc X2
      End If 
      If Point(X2,Y2)>0
         FIN=True
         P2=True
      End If 
      Plot X1,Y1,1
      Plot X2,Y2,2
      Wait Vbl 
   Until FIN
   Boom 
   Bob Update On 
   Fade 1
   Wait 15
   Cls 0
   SPEND
   SP[2]
   If(P1=True) and(P2=True)
      _MESSAGE[MSG_EGALITE,0]
      Add SCORE(1),5000
      Add SCORE(2),5000
   Else 
      TBLB=True
      If P2=True
         _MESSAGE[MSG_WINNER,1]
         Add SCORE(1),10000
      Else 
         _MESSAGE[MSG_WINNER,2]
         Add SCORE(2),10000
      End If 
   End If 
   TBLB=False
   Volume 0
End Proc
Procedure JEU2
   ' Le jeu le plus con: Secouez-moi
   Shared MSG_EGALITE,MSG_WINNER,SCORE(),JEUXVOL,TBLB
   Volume JEUXVOL
   Palette 0,$F,$F00,$FFF
   Paper 0
   Pen 3
   Autoback 1
   Centre At(,3)+"SECOUEZ-MOI DE GAUCHE A DROITE !"
   Centre At(,5)+"BONUS 10.000 Pts"
   Ink 3,0
   Bar 160,96 To 161,130
   T=499
   J1=8
   J2=8
   G=0
   Repeat 
      J=Joy(1)
      If((J=4) and(J1=8)) or((J=8) and(J1=4))
         J1=J
         G=Min(128,G+2)
      End If 
      J=Joy(0)
      If(Key State(79)=True) and(Key State(78)=False)
         J=4
      End If 
      If(Key State(78)=True) and(Key State(79)=False)
         J=8
      End If 
      If((J=4) and(J2=8)) or((J=8) and(J2=4))
         J2=J
         G=Max(-128,G-2)
      End If 
      Ink 1,0
      Bar 30,100 To 160+G,126
      Ink 2,0
      Bar 160+G+1,100 To 290,126
      Ink 3,0
      If(T mod 50)=0
         Text 120,180,"TEMPS ="+Str$(T/50-1)+" "
         Bell T/25+10
      End If 
      Wait Vbl 
      Dec T
   Until T=0
   Fade 1
   Wait 16
   Cls 0
   SPEND
   SP[4]
   TBLB=True
   If G=0
      _MESSAGE[MSG_EGALITE,0]
      Add SCORE(1),5000
      Add SCORE(2),5000
   Else 
      If G>0
         _MESSAGE[MSG_WINNER,1]
         Add SCORE(1),10000
      Else 
         _MESSAGE[MSG_WINNER,2]
         Add SCORE(2),10000
      End If 
   End If 
   TBLB=False
   Volume 0
End Proc
Procedure JEU3
   ' Jeu de tuture pour TB ( Eric vs Boisroux II )  
   Shared MSG_EGALITE,MSG_WINNER,SCORE(),JEUXVOL,TBLB
   Dim P(31)
   For I=0 To 31
      P(I)=Colour(I)
   Next I
   L1=Length(1)
   _LOAD["Twin2:Sprites-Tuture.Abk",1]
   Get Sprite Palette 
   Priority Reverse On 
   C=0
   For I=19 To 23
      Colour I,$FFF
   Next I
   Colour 16,$555
   Colour 17,$555
   Colour 18,$555
   '
   _LOAD["Twin2:Samples-Tuture.Abk",6]
   Sam Bank 6
   Volume JEUXVOL
   Sam Play 2
   '
   Amal Off 
   Bob Off 
   Bob Clear 
   Wait Vbl 
   Cls 0
   Screen Swap 
   Bob Clear 
   Wait Vbl 
   Cls 0
   Ink 16
   Bar 40,0 To 280,256
   For Y=0 To 256 Step 4
      Add C,1,17 To 23
      Ink C
      Bar 150,Y To 158,Y+3
   Next Y
   Ink 1,16
   Text 48,7,"PLAYER 1 = 0"
   Text 170,7,"PLAYER 2 = 0"
   Shift Up 2,17,23,1
   '
   Autoback 1
   Synchro On 
   '
   Dim X(1),Y(1)
   X(1)=60
   Y(1)=160
   X(0)=220
   Y(0)=160
   BOISROUX=0
   SPLATCH1=0
   SPLATCH2=0
   GAGNE=False
   Randomize Timer
   Repeat 
      If BOISROUX=0
         Bob 3,Rnd(200)+48,0,Vrev(L1+3)
         Channel 1 To Bob 3
         Amal 3,("Anim0,("+Str$(Vrev(L1+3))+",10)("+Str$(Vrev(L1+4))+",10);")-" "
         Amal On 3
         EU=False
      End If 
      If BOISROUX>=256
         BOISROUX=-3
      End If 
      Add BOISROUX,3
      C=Bob Col(1,2 To 2)
      If EU=False
         BX=Bob Col(3,1 To 2)
         If BX=True
            Sam Play 1
            Amal Freeze 
            Bob 3,,,Vrev(L1+5)
            EU=True
            If Col(1)=True
               Inc SPLATCH1
               If SPLATCH1=8
                  GAGNE=1
               End If 
            Else 
               Inc SPLATCH2
               If SPLATCH2=8
                  GAGNE=2
               End If 
            End If 
            Text 48,7,"PLAYER 1 ="+Str$(SPLATCH1)
            Text 170,7,"PLAYER 2 ="+Str$(SPLATCH2)
         End If 
      End If 
      If C
         If X(1)<X(0)
            CX=1
         Else 
            CX=0
         End If 
         If Y(1)<Y(0)
            CY=1
         Else 
            CY=0
         End If 
      End If 
      For I=0 To 1
         If((Jleft(I)=True) or((Key State(79)=True) and(I=0))) and(X(I)>44)
            If(C=False) or((C=True) and(CX=I))
               Add X(I),-4
            End If 
         End If 
         If((Jright(I)=True) or((Key State(78)=True) and(I=0))) and(X(I)<246)
            If(C=False) or((C=True) and(CX<>I))
               Add X(I),4
            End If 
         End If 
         If((Jup(I)=True) or((Key State(76)=True) and(I=0))) and(Y(I)>100)
            If(C=False) or((C=True) and(CY=I))
               Add Y(I),-2
            End If 
         End If 
         If((Jdown(I)=True) or((Key State(77)=True) and(I=0))) and(Y(I)<210)
            If(C=False) or((C=True) and(CY<>I))
               Add Y(I),2
            End If 
         End If 
      Next I
      Bob 1,X(1),Y(1),L1+1
      Bob 2,X(0),Y(0),L1+2
      Bob 3,,BOISROUX,
      Wait Vbl 
   Until GAGNE>0
   Sam Play 2
   Shift Off 
   Amal Off 
   A$="Move 0,-280,70;"
   For I=1 To 2
      Channel I To Bob I
      Amal I,A$
   Next I
   Amal On 
   Wait 40
   Fade 1
   Bob Clear 
   Amal Off 
   Bob Off 
   Wait Vbl 
   Cls 0
   Screen Swap 
   Cls 0
   Del Sprite L1+1 To Length(1)
   Volume 0
   Erase 6
   Sam Bank 5
   SP[4]
   TBLB=True
   If GAGNE=1
      _MESSAGE[MSG_WINNER,1]
      Add SCORE(1),10000
   Else 
      _MESSAGE[MSG_WINNER,2]
      Add SCORE(2),10000
   End If 
   TBLB=False
   Wait 20
   Volume 0
   Synchro Off 
End Proc
Procedure JEU4
   ' Super-Tennis 1982
   Shared MSG_EGALITE,MSG_WINNER,SCORE(),JEUXVOL,TBLB
   
   Dim XR(1),YR(1)
   
   _LOAD["Twin2:Samples-PingPong.Abk",6]
   Sam Bank 6
   Volume JEUXVOL
   
   Palette 0,$FFF
   Paper 0
   Pen 1
   
   SC1=0
   SC2=0
   
   JEU=0
   Do 
      Inc JEU
      
      Cls 0
      Centre At(,1)+"SUPER TENNIS 1982"
      Print 
      Print "JOUEUR 1 =";SC1;At(28,);"JOUEUR 2 =";SC2
      Ink 1,0
      Box 0,24 To 319,255
      
      Exit If JEU=6
      
      XR(1)=1
      XR(0)=38
      YR(1)=14
      YR(0)=14
      BX=10+Rnd(16)
      BY=6+Rnd(16)
      VX=Rnd(1)*2-1
      VY=Rnd(1)*2-1
      BOUM=False
      
      Bar XR(1)*8,YR(1)*8 To XR(1)*8+7,(YR(1)+5)*8
      Bar XR(0)*8,YR(0)*8 To XR(0)*8+7,(YR(0)+5)*8
      Bar BX*8,BY*8 To BX*8+7,BY*8+7
      
      Wait 40
      Sam Play 2
      Wait 60
      
      REBOND=0
      TMPO=4
      
      Repeat 
         
         ' Raquettes
         For I=0 To 1
            If((Jup(I)) or((Key State(76)=True) and(I=0))) and(YR(I)>4)
               Ink 0,0
               Bar XR(I)*8,YR(I)*8 To XR(I)*8+7,(YR(I)+5)*8
               Dec YR(I)
            End If 
            If((Jdown(I)) or((Key State(77)=True) and(I=0))) and(YR(I)<26)
               Ink 0,0
               Bar XR(I)*8,YR(I)*8 To XR(I)*8+7,(YR(I)+5)*8
               Inc YR(I)
            End If 
            Ink 1,0
            Bar XR(I)*8,YR(I)*8 To XR(I)*8+7,(YR(I)+5)*8
         Next I
         
         ' Baballe
         Ink 0,0
         Bar BX*8,BY*8 To BX*8+7,BY*8+7
         Add BX,VX
         Add BY,VY
         If(BY=4) or(BY=30)
            VY=-VY
            Sam Play 1
         End If 
         If BX<=2
            If(BY>=(YR(1)-1)) and(BY<=YR(1)+5)
               VX=-VX
               Sam Play 1
               Inc REBOND
            Else 
               BOUM=True
               Inc SC2
            End If 
         End If 
         If BX>=37
            If(BY>=YR(0)-1) and(BY<=YR(0)+5)
               VX=-VX
               Sam Play 1
               Inc REBOND
            Else 
               BOUM=True
               Inc SC1
            End If 
         End If 
         Ink 1,0
         Bar BX*8,BY*8 To BX*8+7,BY*8+7
         If REBOND=4
            REBOND=0
            Dec TMPO
            If TMPO=0
               TMPO=1
            End If 
         End If 
         
         ' 120 MIPS 
         Wait TMPO
         
      Until BOUM
      
      Sam Play 3
      Wait 100
      
   Loop 
   
   Wait 20
   Fade 1
   Wait 15
   Cls 0
   Erase 6
   Sam Bank 5
   SP[2]
   TBLB=True
   If SC1>SC2
      _MESSAGE[MSG_WINNER,1]
      Add SCORE(1),10000
   Else 
      _MESSAGE[MSG_WINNER,2]
      Add SCORE(2),10000
   End If 
   TBLB=False
   Volume 0
End Proc
Procedure JEU5
   ' Strip Fighter III
   Shared MSG_EGALITE,MSG_WINNER,SCORE(),JEUXVOL,TBLB
   
   WINNER=1
   
   Load "Twin2:Img-SF3_A.Abk",10
   Unpack 10 To 1
   Load "Twin2:Img-SF3_B.Abk",10

   Clear Key 
   Repeat 
   Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
   Fade 1
   Wait 15
   Screen Close 1
   Unpack 10 To 1
   Erase 10

   Clear Key 
   Repeat 
   Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
   For I=0 To 128
      Screen Display 1,128,40+I,320,256-I-I
      Screen Offset 1,0,I
      Wait Vbl 
   Next I
   Screen Close 1
   
   Wait 20
   SPEND
   SP[2]
   TBLB=True
   If WINNER=1
      _MESSAGE[MSG_WINNER,1]
      Add SCORE(1),10000
   Else 
      _MESSAGE[MSG_WINNER,2]
      Add SCORE(2),10000
   End If 
   TBLB=False
   Volume 0
End Proc
Procedure JEU6
   ' Pak Man... 
   Shared MSG_EGALITE,MSG_WINNER,SCORE(),JEUXVOL,TBLB
   Volume JEUXVOL
   
   Dim CA(20,16)
   Dim X(1),Y(1),INV(1),SC(1),F(1),FX(1),FY(1)
   Dim M$(1,8)
   
   ' On mémorise l'état précédent 
   Dim P(31)
   For I=0 To 31
      P(I)=Colour(I)
   Next I
   Bank Swap 1,4
   
   ' On s'installe
   _LOAD["Twin2:Samples-PakMan.Abk",6]
   Sam Bank 6
   _LOAD["Twin2:Sprites-PakMan.Abk",-1]
   Screen Open 0,320,256,8,Lowres
   Screen Display 0,128,40,320,256
   Palette 0,0,0,0,0,0,0,0
   Curs Off 
   Flash Off 
   Priority Reverse On 
   '
   Amal Off 
   Bob Off 
   Bob Clear 
   Wait Vbl 
   Cls 0
   '
   Autoback 1
   Synchro On 
   
   ' Le terrain 
   NBPAS=0
   BOUBOUF=0
   Restore DT
   For Y=0 To 15
      For X=0 To 19
         Read CA(X,Y)
         X2=X*16
         Y2=Y*16
         If CA(X,Y)=1
            Ink 1
            Bar X2,Y2 To X2+15,Y2+15
         Else 
            Ink 7
            If CA(X,Y)=0
               Draw X2+7,Y2+6 To X2+7,Y2+8
               Draw X2+6,Y2+7 To X2+8,Y2+7
               Inc NBPAS
            Else 
               If CA(X,Y)=3
                  Circle X2+7,Y2+7,3
                  Paint X2+7,Y2+7
               End If 
            End If 
         End If 
      Next X
   Next Y
   Ink 7,1
   Text 246,18,"TWIN PAK"
   
   ' Zou! 
   Get Sprite Palette 
   Colour 7,$EF0
   View 
   Wait Vbl 
   
   ' P'tit'zinits 
   X(1)=5
   Y(1)=14
   X(0)=11
   Y(0)=14
   SC(0)=0
   SC(1)=0
   FX(0)=1
   FY(0)=1
   FX(1)=18
   FY(1)=2
   Bob 1,X(0)*16,Y(0)*16,7
   Bob 2,X(1)*16,Y(1)*16,1
   Bob 3,FX(0)*16,FY(0)*16,5
   Bob 4,FX(1)*16,FY(1)*16,6
   For I=1 To 4
      Channel I To Bob I
   Next I
   M$(1,1)="LA=3;M0,-16,4;"
   M$(1,2)="LA=4;M0,16,4;"
   M$(1,4)="LA=2;M-16,0,4;"
   M$(1,8)="LA=1;M16,0,4;"
   M$(0,1)="LA=9;M0,-16,4;"
   M$(0,2)="LA=10;M0,16,4;"
   M$(0,4)="LA=8;M-16,0,4;"
   M$(0,8)="LA=7;M16,0,4;"
   
   ' Ze boucle
   OVER=False
   Repeat 
      
      ' Ze players 
      For I=0 To 1
         If F(I)=False
            NX=X(I)
            NY=Y(I)
            J=Joy(I)
            If I=0
               If(Key State(76)=True) and(Key State(77)=False)
                  J=1
               End If 
               If(Key State(77)=True) and(Key State(76)=False)
                  J=2
               End If 
               If(Key State(79)=True) and(Key State(78)=False)
                  J=4
               End If 
               If(Key State(78)=True) and(Key State(79)=False)
                  J=8
               End If 
            End If 
            If J=1
               Dec NY
            End If 
            If J=2
               Inc NY
            End If 
            If J=4
               Dec NX
            End If 
            If J=8
               Inc NX
            End If 
            If(NX<>X(I)) or(NY<>Y(I))
               ' Pas mur ?
               If CA(NX,NY)<>1
                  X(I)=NX
                  Y(I)=NY
                  ' Pas vide ? 
                  If CA(NX,NY)<>2
                     Add SC(I),50
                     Bob Clear 
                     Ink 0
                     Bar NX*16+4,NY*16+4 To NX*16+10,NY*16+10
                     Bob Draw 
                     If CA(NX,NY)=3
                        ' Pac-gum
                        Sam Play %11,1
                        If I=1
                           Flash 2,"(FF0,10)(F00,10)"
                        Else 
                           Flash 6,"(FA0,10)(F00,10)"
                        End If 
                        INV(I)=70
                     Else 
                        ' Pastille 
                        Sam Play %1100,3
                        Inc BOUBOUF
                        If BOUBOUF=NBPAS
                           OVER=True
                        End If 
                     End If 
                     CA(NX,NY)=2
                  End If 
                  Amal I+1,M$(I,J)
                  Amal On I+1
               End If 
            End If 
         End If 
      Next I
      
      ' Ze ghosts
      For ZZ=0 To 1
         FX=FX(ZZ)
         FY=FY(ZZ)
         D0=(FX-X(0))*(FX-X(0))+(FY-Y(0))*(FY-Y(0))
         D1=(FX-X(1))*(FX-X(1))+(FY-Y(1))*(FY-Y(1))
         If D0<=D1
            PP=0
         Else 
            PP=1
         End If 
         If F(0)=True
            PP=1
         End If 
         If F(1)=True
            PP=0
         End If 
         BLK=0
         Repeat 
            Inc BLK
            If BLK>4
               RX=Rnd(2)-1
               If RX=0
                  RY=Rnd(1)*2-1
               Else 
                  RY=0
               End If 
               NX=FX+RX
               NY=FY+RY
            Else 
               NX=FX
               NY=FY
               R=Rnd(1)
               MOINS=-1
               PLUS=1
               If INV(PP)>0
                  Swap MOINS,PLUS
               End If 
               If(R=0) and(X(PP)<>FX)
                  If X(PP)<FX
                     NX=FX+MOINS
                  Else 
                     NX=FX+PLUS
                  End If 
               Else 
                  If Y(PP)<FY
                     NY=FY+MOINS
                  Else 
                     NY=FY+PLUS
                  End If 
               End If 
            End If 
         Until(CA(NX,NY)<>1)
         LVX=NX-FX
         LVY=NY-FY
         FX=NX
         FY=NY
         Amal 3+ZZ,"M"+Str$(LVX*16)+","+Str$(LVY*16)+",4;"
         Amal On 3+ZZ
         FX(ZZ)=FX
         FY(ZZ)=FY
      Next ZZ
      
      ' Touché un fantôme ?
      For J=0 To 1
         For I=0 To 1
            If(FX(J)=X(I)) and(FY(J)=Y(I)) and(INV(I)=0)
               Bob Off I+1
               F(I)=True
               If F(0)=F(1)
                  OVER=True
               End If 
            End If 
         Next I
      Next J
      
      ' Bouffe l'autre 
      If(X(0)=X(1)) and(Y(0)=Y(1))
         If(INV(1)>0) and(F(0)=False) and(INV(0)=0)
            Bob Off 1
            F(0)=True
            Sam Play %11,2
         End If 
         If(INV(0)>0) and(F(1)=False) and(INV(1)=0)
            Bob Off 2
            F(1)=True
            Sam Play %11,2
         End If 
      End If 
      
      ' Tempo
      Wait 4
      For I=0 To 1
         If INV(I)>0
            Dec INV(I)
            If INV(I)=0
               Flash Off 
               Colour 2,$FF0
               Colour 6,$FA0
               If INV(0)>0
                  Flash 6,"(FA0,10)(F00,10)"
               Else 
                  If INV(1)>0
                     Flash 2,"(FF0,10)(F00,10)"
                  End If 
               End If 
            End If 
         End If 
      Next I
      
   Until OVER
   
   Bob Update On 
   Flash Off 
   Fade 1
   Wait 15
   Cls 0
   Erase 6
   Sam Bank 5
   SP[2]
   TBLB=True
   Add SCORE(1),SC(1)
   Add SCORE(2),SC(0)
   If SC(1)>SC(0)
      _MESSAGE[MSG_WINNER,1]
      Add SCORE(1),10000
   Else 
      _MESSAGE[MSG_WINNER,2]
      Add SCORE(2),10000
   End If 
   TBLB=False
   Volume 0
   Bank Swap 1,4
   Erase 4
   
   DT:
   Data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
   Data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1
   Data 1,0,1,0,1,0,1,0,1,1,0,1,1,1,0,0,0,0,0,1
   Data 1,3,0,0,0,0,1,0,0,0,0,0,0,0,0,1,1,1,0,1
   Data 1,0,1,1,1,0,1,0,1,1,1,1,1,1,0,1,0,0,0,1
   Data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,3,1,1,1
   Data 1,0,1,1,1,1,1,1,1,0,0,1,1,1,0,1,0,0,0,1
   Data 1,0,1,0,0,0,1,0,0,0,0,0,0,1,0,1,1,1,0,1
   Data 1,0,1,0,1,0,1,0,3,0,0,3,0,1,0,1,0,0,0,1
   Data 1,0,0,0,1,0,1,0,0,0,0,0,0,1,0,0,0,1,1,1
   Data 1,1,1,1,1,0,1,1,1,1,1,1,1,1,0,1,0,0,0,1
   Data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,1,1,0,1
   Data 1,0,1,1,0,1,1,1,0,1,1,1,0,1,1,1,0,0,0,1
   Data 1,0,1,1,0,1,1,1,0,1,1,1,0,0,0,0,0,1,0,1
   Data 1,0,0,0,0,2,0,0,0,0,0,2,0,1,1,1,0,0,0,1
   Data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
End Proc
Procedure JEU7
   ' Jeu de butage/butation de Lemmings pour TB 
   Shared MSG_EGALITE,MSG_WINNER,SCORE(),JEUXVOL,SFXVOL,TBLB
   
   ' On mémorise l'état précédent 
   Dim P(31)
   For I=0 To 31
      P(I)=Colour(I)
   Next I
   Bank Swap 1,4
   
   ' On s'installe
   _LOAD["Twin2:Samples-Lemmings.Abk",6]
   Sam Bank 6
   _LOAD["Twin2:Sprites-Lemmings.Abk",-1]
   Screen Open 0,320,256,8,Lowres
   Screen Display 0,128,40,320,256
   Curs Off 
   Flash Off 
   Cls 0
   Double Buffer 
   Get Sprite Palette 
   Priority Reverse On 
   Volume SFXVOL
   '
   Amal Off 
   Bob Off 
   Autoback 1
   Synchro Off 
   '
   Bob Clear 
   Wait Vbl 
   Cls 0
   Screen Swap 
   Bob Clear 
   Wait Vbl 
   Cls 0
   Ink 1,0
   Text 40,7," PLAYER 1 = 0"
   Text 162,7," PLAYER 2 = 0"
   '
   Dim X(1),Y(1),BUTOS(1),F(1)
   '
   X(1)=50
   Y(1)=100
   X(0)=260
   Y(0)=100
   BUTOS(0)=0
   BUTOS(1)=0
   '
   ' Viseurs
   Bob 1,X(1),Y(1),1
   Bob 2,X(0),Y(0),3
   Channel 1 To Bob 1
   Channel 2 To Bob 2
   Amal 1,"Loop: Pause; If BC(1,3,10) then Jump Coll; Let A=1; Jump Loop; Coll: Let A=2; Jump Loop;"
   Amal 2,"Loop: Pause; If BC(2,3,10) then Jump Coll; Let A=3; Jump Loop; Coll: Let A=4; Jump Loop;"
   '
   ' Lemmings 
   NBLEM=8
   For BITOS=3 To 2+NBLEM
      Bob BITOS,Rnd(32)*10,10,5
      Channel BITOS To Bob BITOS
      Channel BITOS+NBLEM To Bob BITOS
      Amal BITOS,"Anim 0,(5,5)(6,5)(7,5)(6,5);"
      V=(Rnd(1)+1)*2
      Amal BITOS+NBLEM,"Move 0,256,"+Str$(256/V)+";"
   Next BITOS
   '
   Amal On 
   Timer=0
   '
   Repeat 
      For I=0 To 1
         If(Jleft(I)) or((I=0) and(Key State(79)))
            Add X(I),-2,0 To 304
         End If 
         If(Jright(I)) or((I=0) and(Key State(78)))
            Add X(I),2,0 To 304
         End If 
         If(Jup(I)) or((I=0) and(Key State(76)))
            Add Y(I),-2,0 To 240
         End If 
         If(Jdown(I)) or((I=0) and(Key State(77)))
            Add Y(I),2,0 To 240
         End If 
         If(Fire(I)) or((I=0) and(Key State(64)))
            If F(I)=False
               Sam Play 4*(I+1),1
               If Bob Col(-I+2,3 To 2+NBLEM)
                  For ZOB=3 To 2+NBLEM
                     If Col(ZOB)
                        LEM=ZOB
                     End If 
                  Next ZOB
                  If I Bob(LEM)<>8
                     Sam Play 3,2
                     Inc BUTOS(I)
                     Amal Freeze LEM
                     Bob LEM,,,8
                     Text 40,7," PLAYER 1 ="+Str$(BUTOS(1))+" "
                     Text 162,7," PLAYER 2 ="+Str$(BUTOS(0))+" "
                  End If 
               End If 
               F(I)=True
            End If 
         Else 
            F(I)=False
         End If 
      Next I
      '
      For BITOS=3 To 2+NBLEM
         If Chanmv(BITOS+NBLEM)=False
            Bob BITOS,Rnd(32)*10,10,5
            V=(Rnd(1)+1)*2
            Amal BITOS+NBLEM,"Move 0,256,"+Str$(256/V)+";"
            Amal On BITOS
            Amal On BITOS+NBLEM
         End If 
      Next BITOS
      '
      Bob 1,X(1),Y(1),
      Bob 2,X(0),Y(0),
      Synchro 
      Wait Vbl 
      '
   Until Timer>=1100
   '
   If BUTOS(1)>BUTOS(0)
      GAGNE=1
   Else 
      If BUTOS(1)<BUTOS(0)
         GAGNE=2
      Else 
         GAGNE=0
      End If 
   End If 
   '
   Wait 40
   Fade 1
   Bob Clear 
   Amal Off 
   Bob Off 
   Wait Vbl 
   Cls 0
   Screen Swap 
   Cls 0
   
   Bank Swap 1,4
   Erase 4
   
   Erase 6
   Sam Bank 5
   
   SP[4]
   If GAGNE=0
      _MESSAGE[MSG_EGALITE,0]
      Add SCORE(1),5000
      Add SCORE(2),5000
   Else 
      TBLB=True
      If GAGNE=1
         _MESSAGE[MSG_WINNER,1]
         Add SCORE(1),10000
      Else 
         _MESSAGE[MSG_WINNER,2]
         Add SCORE(2),10000
      End If 
   End If 
   TBLB=False
   Wait 20
   Volume 0
   Synchro Off 
End Proc
Procedure J1_ANIM
   Shared STATE(),SENS1,STANDING,WALKING,JUMPING,FALLING,DROITE,GAUCHE
   Shared GLOUGLOU1,MORT1,LONGTEMPS()
   If MORT1=True
      A$="Let A=238; Move 0,300,75;"
   Else 
      If STATE(1)=STANDING
         If SENS1=DROITE
            A$="Let A=178;"
         Else 
            A$="Let A=199;"
         End If 
      End If 
      If STATE(1)=WALKING
         If SENS1=DROITE
            A$="Anim 0,(179,2)(180,2)(181,2)(182,2)(181,2)(180,2);"
         Else 
            A$="Anim 0,(198,2)(197,2)(196,2)(195,2)(196,2)(197,2);"
         End If 
      End If 
      If STATE(1)=JUMPING
         If SENS1=DROITE
            A$="Let A=232;"
         Else 
            A$="Let A=241;"
         End If 
      End If 
      If STATE(1)=FALLING
         A$="      For R0=0 To 7;"
         A$=A$+"   If R1=-1 the Jump A;"
         A$=A$+"   Let A=233; Jump B;"
         A$=A$+"A: Let A=242;"
         A$=A$+"B: Next R0;"
         A$=A$+"   Let R2=-1*R1;"
         A$=A$+"   For R0=0 To 15;"
         A$=A$+"   If R1<>R2 then Jump C;"
         A$=A$+"D: Next R0; Jump J;"
         A$=A$+"C: If R1=-1 the Jump I;"
         A$=A$+"   Anim 0,(234,2)(235,2); Let R2=R1; Jump D;"
         A$=A$+"I: Anim 0,(243,2)(244,2); Let R2=R1; Jump D;"
         A$=A$+"J: If R1=-1 then Jump E;"
         A$=A$+"   Anim 1,(236,1); Jump F;"
         A$=A$+"E: Anim 1,(245,1);"
         A$=A$+"F: Pause;"
         A$=A$+"G: Pause;"
         A$=A$+"   If R1=-1 the Jump H;"
         A$=A$+"   Anim 1,(237,2); Jump G;"
         A$=A$+"H: Anim 1,(246,2); Jump G;"
      End If 
   End If 
   Limit Bob 1,16,0 To 240,224
   Amal 1,A$
   Amal On 1
   Amreg(1,1)=SENS1
   GLOUGLOU1=0
   Amal Off 12
   Bob 16,0,,
End Proc
Procedure J2_ANIM
   Shared STATE(),SENS2,STANDING,WALKING,JUMPING,FALLING,DROITE,GAUCHE
   Shared GLOUGLOU2,MORT2,LONGTEMPS()
   If MORT2=True
      A$="Let A=220; Move 0,300,75;"
   Else 
      If STATE(2)=STANDING
         If SENS2=DROITE
            A$="Let A=156;"
         Else 
            A$="Let A=177;"
         End If 
      End If 
      If STATE(2)=WALKING
         If SENS2=DROITE
            A$="Anim 0,(157,2)(158,2)(159,2)(160,2)(159,2)(158,2);"
         Else 
            A$="Anim 0,(176,2)(175,2)(174,2)(173,2)(174,2)(175,2);"
         End If 
      End If 
      If STATE(2)=JUMPING
         If SENS2=DROITE
            A$="Let A=214;"
         Else 
            A$="Let A=223;"
         End If 
      End If 
      If STATE(2)=FALLING
         A$="      For R0=0 To 7;"
         A$=A$+"   If R1=-1 the Jump A;"
         A$=A$+"   Let A=215; Jump B;"
         A$=A$+"A: Let A=224;"
         A$=A$+"B: Next R0;"
         A$=A$+"   Let R2=-1*R1;"
         A$=A$+"   For R0=0 To 15;"
         A$=A$+"   If R1<>R2 then Jump C;"
         A$=A$+"D: Next R0; Jump J;"
         A$=A$+"C: If R1=-1 the Jump I;"
         A$=A$+"   Anim 0,(216,2)(217,2); Let R2=R1; Jump D;"
         A$=A$+"I: Anim 0,(225,2)(226,2); Let R2=R1; Jump D;"
         A$=A$+"J: If R1=-1 then Jump E;"
         A$=A$+"   Anim 1,(218,1); Jump F;"
         A$=A$+"E: Anim 1,(227,1);"
         A$=A$+"F: Pause;"
         A$=A$+"G: Pause;"
         A$=A$+"   If R1=-1 the Jump H;"
         A$=A$+"   Anim 1,(219,2); Jump G;"
         A$=A$+"H: Anim 1,(228,2); Jump G;"
      End If 
   End If 
   Limit Bob 2,16,0 To 240,224
   Amal 2,A$
   Amal On 2
   Amreg(2,1)=SENS2
   GLOUGLOU2=0
   Amal Off 13
   Bob 17,240,,
End Proc
Procedure BONUS
   Shared BONUS,CURBONUS,QB(),PARTIE
   Do 
      X=Rnd(13)+1
      Y=Rnd(13)+1
      If C(X,Y)=0
         If Y=14
            Exit 
         Else 
            If C(X,Y+1)>0
               Exit 
            End If 
         End If 
      End If 
   Loop 
   '
   B=Rnd(205)
   B=QB(B)
   If PARTIE=1
      If B=69
         Inc B
      End If 
   Else 
      If B=70
         Dec B
      End If 
   End If 
   '
   If B=79
      A$="A0,(79,20)(80,20);"
   Else 
      If B=57
         A$="A0,(57,2)(58,2)(59,2);"
      Else 
         If B=60
            A$="A0,(60,1)(61,1)(62,1)(63,1)(64,1)(65,1);"
         End If 
      End If 
   End If 
   Bob BONUS,X*16,Y*16-16,B
   Amal BONUS,A$
   Amal On BONUS
   CURBONUS=B
End Proc
Procedure MUSIQUE[N,V]
   Shared ZIKPLAYING,QUELLEZIK
   Mvolume 0
   If(QUELLEZIK<>N) or(Length(3)=0)
      Erase 3
      Erase 5
      If N=1
         _LOAD["Twin1:Zik-Intro.Abk",3]
      Else 
         _LOAD["Twin2:Zik-Jeu.Abk",3]
      End If 
   End If 
   QUELLEZIK=N
   Led Off 
   Music 1
   Tempo 17
   Mvolume V
   Wait Vbl 
   ZIKPLAYING=True
End Proc
Procedure MUSIQUE_OFF
   Shared ZIKPLAYING
   Music Off 
   ZIKPLAYING=False
End Proc
Procedure UPDSCORE[JOUEUR,PLUS]
   Shared SCORE(),MORT1,MORT2,PARALIZED1,PARALIZED2,NAME1$,NAME2$
   Shared HURRY,PARTIE,POUM1,POUM2,SUPER(),PANOU(),CREDITS
   If PLUS<>0
      S=SCORE(JOUEUR)
      Add SCORE(JOUEUR),PLUS
      SCORE(JOUEUR)=Max(0,SCORE(JOUEUR))
      R1=S-S mod 50000
      R2=SCORE(JOUEUR)-SCORE(JOUEUR) mod 50000
      If R2>R1
         Sam Play VOIX,2
         CREDITS=Min(99,CREDITS+1)
         L$=Str$(CREDITS)-" "
         If Len(L$)=1
            L$="0"+L$
         End If 
         Ink 10,0
         Text 280,218,L$
      End If 
   End If 
   If HURRY=True
      Ink 8,0
      Text 4,242,"  HURRY UP !!  "
      If PARTIE=2
         Text 132,242,"  HURRY UP !!  "
      End If 
   Else 
      If SUPER(1)
         Ink 10,0
      Else 
         Ink 11,0
      End If 
      If MORT1=False
         If(PARALIZED1>0) and(PANOU(1)=False)
            Text 8,242," Oh my head ! "
         Else 
            Text 8,242,"SCORE"+Space$(8-Len(Str$(SCORE(1))))+Str$(SCORE(1))
         End If 
      Else 
         Text 8,242,"    OH NO !   "
      End If 
      Ink 11,0
      If PARTIE=2
         If MORT2=False
            If SUPER(2)
               Ink 10,0
            End If 
            If(PARALIZED2>0) and(PANOU(2)=False)
               Text 136,242," Oh my head ! "
            Else 
               Text 136,242,"SCORE"+Space$(8-Len(Str$(SCORE(2))))+Str$(SCORE(2))
            End If 
         Else 
            Text 136,242,"    OH NO !   "
         End If 
      Else 
         Text 136,242," ©92 POWERMOB "
      End If 
   End If 
End Proc
Procedure _FORBID
   A=Execall(-132)
End Proc
Procedure _PERMIT
   A=Execall(-138)
End Proc
Procedure DESSINER
   S=Screen
   Screen 0
   Cls 0,16,0 To 240,224
   For X=1 To 14
      For Y=1 To 14
         If C(X,Y)>0
            Paste Bob X*16,(Y-1)*16,C(X,Y)
         End If 
      Next Y
   Next X
   Screen S
End Proc
Procedure FOUTRE_MONSTRES
   Shared NBMONSTRES,NBSQ(),MX(),MY(),MA(),MH(),MV(),MT(),SQ$()
   If NBMONSTRES>0
      For M=5 To NBMONSTRES+4
         I=M-4
         Bob M,MX(I),MY(I),84
         Channel M To Bob M
         A$="L:"
         For J=1 To NBSQ(I)
            A$=A$+SQ$(MA(I,J))
            A$=A$+"M"+Str$(MH(I,J))+","+Str$(MV(I,J))+","+Str$(MT(I,J))+";"
         Next J
         A$=A$-" "
         Amal M,A$+"JL;"
      Next M
   End If 
End Proc
Procedure NOUVELLE_CASE
   Shared CASE,J
   OLD=CASE
   L=4
   R=8
   U=1
   D=2
   If CASE=1
      If J=D
         CASE=3
      Else 
         If J=R
            CASE=2
         End If 
      End If 
   Else 
      If CASE=2
         If J=L
            CASE=1
         Else 
            If J=D
               CASE=4
            End If 
         End If 
      Else 
         If CASE=3
            If J=U
               CASE=1
            Else 
               If J=R
                  CASE=4
               Else 
                  If J=D
                     CASE=5
                  End If 
               End If 
            End If 
         Else 
            If CASE=4
               If J=L
                  CASE=3
               Else 
                  If J=U
                     CASE=2
                  Else 
                     If J=D
                        CASE=10
                     End If 
                  End If 
               End If 
            Else 
               If CASE=5
                  If J=U
                     CASE=3
                  Else 
                     If J=D
                        CASE=6
                     Else 
                        If J=R
                           CASE=8
                        End If 
                     End If 
                  End If 
               Else 
                  If CASE=6
                     If J=U
                        CASE=5
                     Else 
                        If J=D
                           CASE=7
                        Else 
                           If J=R
                              CASE=8
                           End If 
                        End If 
                     End If 
                  Else 
                     If CASE=7
                        If J=U
                           CASE=6
                        Else 
                           If J=R
                              CASE=11
                           End If 
                        End If 
                     Else 
                        If CASE=8
                           If J=U
                              CASE=4
                           Else 
                              If J=D
                                 CASE=11
                              Else 
                                 If J=R
                                    CASE=9
                                 Else 
                                    If J=L
                                       CASE=5
                                    End If 
                                 End If 
                              End If 
                           End If 
                        Else 
                           If CASE=9
                              If J=U
                                 CASE=4
                              Else 
                                 If J=D
                                    CASE=11
                                 Else 
                                    If J=R
                                       CASE=10
                                    Else 
                                       If J=L
                                          CASE=8
                                       End If 
                                    End If 
                                 End If 
                              End If 
                           Else 
                              If CASE=10
                                 If J=U
                                    CASE=4
                                 Else 
                                    If J=D
                                       CASE=11
                                    Else 
                                       If J=L
                                          CASE=9
                                       End If 
                                    End If 
                                 End If 
                              Else 
                                 If CASE=11
                                    If J=U
                                       CASE=8
                                    Else 
                                       If J=L
                                          CASE=7
                                       End If 
                                    End If 
                                 End If 
                              End If 
                           End If 
                        End If 
                     End If 
                  End If 
               End If 
            End If 
         End If 
      End If 
   End If 
   If OLD<>CASE
      If OLD=1
         Screen 0
         Ink 0
         Bar 16,2 To 80,66
         Paste Bob 16,2,26
      Else 
         If OLD=2
            Screen 0
            Ink 0
            Bar 240,2 To 304,66
            Paste Bob 240,2,27
         Else 
            If OLD=3
               Screen 1
               Colour 2,$492
            Else 
               If OLD=4
                  Screen 1
                  Colour 11,$492
               Else 
                  If OLD=5
                     Screen 2
                     Paste Bob 10,2,1
                  Else 
                     If OLD=6
                        Screen 2
                        Paste Bob 10,38,2
                     Else 
                        If OLD=7
                           Screen 2
                           Paste Bob 10,74,3
                        Else 
                           If(OLD>=8) and(OLD<=11)
                              Screen 2
                              Bob Off 
                              Wait Vbl 
                           End If 
                        End If 
                     End If 
                  End If 
               End If 
            End If 
         End If 
      End If 
      If CASE=1
         Screen 0
         Paste Bob 16,2,28
      Else 
         If CASE=2
            Screen 0
            Paste Bob 240,2,29
         Else 
            If CASE=3
               Screen 1
               Colour 2,$4F2
            Else 
               If CASE=4
                  Screen 1
                  Colour 11,$4F2
               Else 
                  If CASE=5
                     Screen 2
                     Paste Bob 10,2,4
                  Else 
                     If CASE=6
                        Screen 2
                        Paste Bob 10,38,5
                     Else 
                        If CASE=7
                           Screen 2
                           Paste Bob 10,74,6
                        Else 
                           If CASE=8
                              Screen 2
                              Bob 1,159,3,30
                           Else 
                              If CASE=9
                                 Screen 2
                                 Bob 1,214,3,30
                              Else 
                                 If CASE=10
                                    Screen 2
                                    Bob 1,268,3,30
                                 Else 
                                    If CASE=11
                                       Screen 2
                                       Bob 1,175,63,31
                                    End If 
                                 End If 
                              End If 
                           End If 
                        End If 
                     End If 
                  End If 
               End If 
            End If 
         End If 
      End If 
   End If 
End Proc
Procedure VERIF[LEVEL]
   Shared PARTIE,USER
   CHECK[2]
   If USER=True
      L$="User"
   Else 
      L$="Levels"
   End If 
   If PARTIE=2
      L$=L$+"2"
   End If 
   L$=("Twin2:"+L$+"/L"+Str$(LEVEL))-" "
End Proc[Exist(L$)]
Procedure CH61[LEVEL]
   Shared PARTIE,USER
   Shared COM$,IMGBACK,NBTRESORS
   Shared MEMETEMPS,MXTEMPS(),MXTEMPSTOTAL,XD1,YD1,XD2,YD2
   Shared NBMONSTRES,MX(),MY(),NBSQ(),MA(),MH(),MV(),MT()
   Shared BONUSDELAI,BONUSRESTE,ITEM,ITEMX,ITEMY,YAITEM
   '
   Paper 0
   Pen 1
   Locate 0,25
   CHECK[2]
   If USER=True
      L$="User"
   Else 
      L$="Levels"
   End If 
   If PARTIE=2
      L$=L$+"2"
   End If 
   L$=("Twin2:"+L$+"/L"+Str$(LEVEL))-" "
   
   If Exist(L$)
      Open In 1,L$
      Input #1,ID
      If((USER=False) and(ID<>1993)) or((USER=True) and(ID<>3991))
         'FIN 
      End If 
      '
      Input #1,PARTIE2
      If PARTIE<>PARTIE2
         'FIN 
      End If 
      
      Input #1,L
      B$=Input$(1,L)
      
      X=1
      Y=1
      For I=1 To L
         C=Asc(Mid$(B$,I))
         If C=255
            C2(X,Y)=0
            Inc I
            Z=Asc(Mid$(B$,I))
            For J=1 To Z
               Inc X
               If X=15
                  X=1
                  Inc Y
                  Exit If Y=15,2
               End If 
               C2(X,Y)=0
            Next J
         Else 
            C2(X,Y)=C
            If C=43
               Inc NBTRESORS
            End If 
            Inc X
            If X=15
               X=1
               Inc Y
            End If 
         End If 
      Next I
      Input #1,DUMMY
      
      Input #1,LEVEL2
      ' Remettre sécurité avant de diffuser
      LEVEL2=LEVEL
      If LEVEL2<>LEVEL
         FIN
      End If 
      
      Input #1,YAITEM
      If YAITEM
         Input #1,ITEM
         Input #1,ITEMX
         Input #1,ITEMY
      End If 
      If PARTIE=1
         Input #1,MXTEMPS(1)
         Input #1,MXTEMPSTOTAL
         Input #1,NBMONSTRES
         Input #1,COM$
         Centre COM$
         Input #1,XD1
         Input #1,YD1
         Input #1,IMGBACK
      Else 
         Input #1,MXTEMPS(1)
         Input #1,MXTEMPS(2)
         Input #1,MEMETEMPS
         Input #1,MXTEMPSTOTAL
         Input #1,NBMONSTRES
         Input #1,COM$
         Centre COM$
         Input #1,XD1
         Input #1,YD1
         Input #1,XD2
         Input #1,YD2
         Input #1,IMGBACK
      End If 
      Input #1,BONUSDELAI
      Input #1,BONUSRESTE
      If NBMONSTRES>0
         For I=1 To NBMONSTRES
            Input #1,MX(I)
            Input #1,MY(I)
            Input #1,NBSQ(I)
            If NBSQ(I)>0
               For J=1 To NBSQ(I)
                  Input #1,MA(I,J)
                  Input #1,MH(I,J)
                  Input #1,MV(I,J)
                  Input #1,MT(I,J)
               Next J
            End If 
         Next I
      End If 
      ' Bonusmachin
   Else 
      Centre "Plus de tableaux !!"
      FIN
   End If 
   Close 1
   MXTEMPSTOTAL=MXTEMPSTOTAL*50
End Proc
Procedure CHARGE_SCORES
   Shared HISCORE$(),HISCORE(),HIMODE()
   CHECK[1]
   Open In 1,"Twin1:High-Scores"
   For I=1 To 10
      Input #1,HISCORE$(I)
      Input #1,HISCORE(I)
      'Input #1,HIMODE(I)
   Next I
   Close 1
End Proc
Procedure SAUVE_SCORES
   Shared HISCORE$(),HISCORE(),HIMODE()
   On Error Proc WPRO
   Resume Label FIN
   Open Out 1,"Twin1:High-Scores"
   For I=1 To 10
      Print #1,HISCORE$(I)
      Print #1,HISCORE(I)
      Print #1,HIMODE(I)
   Next I
   Close 1
   FIN:
   On Error 
End Proc
Procedure CHARGE_PREFS
   Shared ZIKVOL,SFXVOL,JEUXVOL,PUBON,NAME1$,NAME2$,PARTIE,USER
   CHECK[1]
   If Exist("Twin1:Prefs")
      Open In 1,"Twin1:Prefs"
      Input #1,USER
      Input #1,ZIKVOL
      Input #1,JEUXVOL
      Input #1,SFXVOL
      Input #1,PUBON
      Input #1,NAME1$
      Input #1,NAME2$
      Input #1,PARTIE
      Close 1
   Else 
      ZIKVOL=50
      JEUXVOL=35
      SFXVOL=60
      PUBON=True
      NAME1$="Bilbo"
      NAME2$="Gollum"
      PARTIE=2
      USER=False
   End If 
End Proc
Procedure SAUVE_PREFS
   Shared ZIKVOL,JEUXVOL,SFXVOL,PUBON,NAME1$,NAME2$,PARTIE,USER
   CHECK[1]
   On Error Proc WPRO
   Resume Label FIN
   Open Out 1,"Twin1:Prefs"
   Print #1,USER
   Print #1,ZIKVOL
   Print #1,JEUXVOL
   Print #1,SFXVOL
   Print #1,PUBON
   Print #1,NAME1$
   Print #1,NAME2$
   Print #1,PARTIE
   Close 1
   FIN:
   On Error 
End Proc
Procedure WPRO
   Resume Label 
End Proc
Procedure _LOAD[F$,BANK]
   On Error Goto _ASK
   If BANK=-1
      Load F$
   Else 
      Load F$,BANK
   End If 
   On Error 
   Pop Proc
   _ASK:
   If Errn=94
      Screen Open 0,320,256,2,0
      Screen Display 0,128,40,,
      Palette 0,0
      Curs Off 
      Cls 0
      Centre At(,8)+"ERREUR DE DISQUE !"
      Centre At(,10)+"PP PATCHER EST-IL BIEN INSTALLE ?"
      Centre At(,16)+"Désolé, mais je quitte!"
      Fade 1,0,$FFF
      View 
      Clear Key 
      Repeat 
      Until(Fire(0)) or(Fire(1)) or(Len(Inkey$)>0)
      Fade 1
      Wait 15
      FIN
   End If 
   P=Instr(F$,":")
   N=Val(Mid$(F$,P-1,1))
   DISK[N]
   Resume 
End Proc
Procedure CHECK[N]
   On Error Goto _ASK
   F$=("Twin"+Str$(N)+":Disk.info")-" "
   Open In 1,F$
   Close 1
   On Error 
   Pop Proc
   _ASK:
   DISK[N]
   Resume 
End Proc
Procedure DISK[N]
   Auto View Off 
   S=Screen
   Screen Hide S
   Screen Open 7,320,16,2,Lowres
   Screen Display 7,128,142,320,16
   Palette 0,0
   Curs Off 
   Cls 0
   Centre "INSEREZ LE DISQUE N°"+Str$(N)-" "
   Print 
   Centre "PUIS APPUYEZ SUR FIRE"
   Auto View On 
   Fade 1,0,4095
   Wait 15
   Clear Key 
   Repeat 
   Until(Fire(1)) or(Fire(0)) or(Len(Inkey$)>0)
   Fade 1
   Wait 15
   Screen Close 7
   Screen Show S
End Proc
Procedure SP[N]
   Shared SPZ,SFXVOL
   Volume SFXVOL
   If Length(6)=0
      _LOAD[("Twin2:Samples-Special"+Str$(N)+".Abk")-" ",6]
      Sam Bank 6
      Sam Play 1
      SPZ=True
   Else 
      Sam Bank 6
      Sam Play N
      SPZ=False
   End If 
End Proc
Procedure SPEND
   Shared SPZ
   If SPZ=True
      Erase 6
   End If 
End Proc