build.gradle

buildscript {
    ext.kotlin_version = '1.3.61'
    ext.dokka_version = '0.10.0'

    repositories {
        mavenCentral()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        jcenter()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:$dokka_version"
        classpath 'info.solidsoft.gradle.pitest:gradle-pitest-plugin:1.4.6'
    }
}

plugins {
    id 'com.github.ben-manes.versions' version '0.27.0'
}

group 'com.github.sanity'
version '1.4.15'

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'maven'
apply plugin: 'org.jetbrains.dokka'
apply plugin: "info.solidsoft.pitest"

sourceCompatibility = 1.6

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
   // compile group: 'org.jetbrains.kotlin', name: 'kotlin-reflect', version: "$kotlin_version"

    // testCompile group: 'junit', name: 'junit', version: '4.11'
    testCompile 'io.kotlintest:kotlintest:2.0.7'
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task dokkaJavadoc(type: org.jetbrains.dokka.gradle.DokkaTask) {
    outputFormat = 'html'
    outputDirectory = javadoc.destinationDir
    inputs.dir 'src/main/kotlin'
}

task javadocJar(type: Jar, dependsOn: dokkaJavadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

pitest {
    targetClasses = ['com.github.sanity.pav.*']  //by default "${project.group}.*"
    threads = 8
    outputFormats = ['HTML', 'XML']
    jvmArgs = ['-Xmx1024m']
}

artifacts {
    //archives javadocJar
}