-
Notifications
You must be signed in to change notification settings - Fork 0
/
index.scm
135 lines (127 loc) · 4.81 KB
/
index.scm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
(import (scheme base) (scheme file) (scheme write))
(import (reader))
(define (map/odd f xs)
(let loop ((acc '()) (xs xs) (odd? #f))
(if (null? xs) (reverse acc)
(loop (cons (f (car xs) odd?) acc) (cdr xs) (not odd?)))))
(define (superscripts s)
(let ((n (string-length s)))
(let loop ((a 0) (b 0) (acc '()))
(cond ((= n b a)
(reverse acc))
((= n b)
(loop b b (cons (substring s a b) acc)))
((char=? #\^ (string-ref s b))
(loop (+ b 2) (+ b 2)
(append `((sup ,(string (string-ref s (+ b 1))))
,(substring s a b))
acc)))
(else (loop a (+ b 1) acc))))))
(define (display-sxml x)
(define (display* . xs) (for-each display xs))
(define (display-char char)
(let* ((cc (char->integer char))
(ok? (case char ((#\& #\< #\> #\") #f) (else (<= #x20 cc #x7e)))))
(if ok? (display char) (display* "&#" cc ";"))))
(define (display-attribute attribute)
(display* " " (car attribute) "=\"")
(string-for-each display-char (cadr attribute))
(display "\""))
(cond ((pair? x)
(display* "<" (car x))
(let ((body (cond ((and (pair? (cdr x))
(pair? (cadr x))
(eq? '@ (car (cadr x))))
(for-each display-attribute (cdr (cadr x)))
(cddr x))
(else (cdr x)))))
(display ">")
(for-each display-sxml body)
(unless (memq (car x) '(br meta))
(display* "</" (car x) ">"))))
((string? x)
(string-for-each display-char x))
(else (error "Bad:" x))))
(define (menu-sxml items)
`(header
(ul (@ (class "menu"))
,@(map (lambda (i) `(li (a (@ (href ,(cadr i))) ,(car i))))
items))))
(define (about-section)
`(section
(h2 "About files.scheme.org")
(div (@ (id "schemeorg-contributing")
(class "round-box green-box"))
(p (kbd "files.scheme.org")
" is a community subdomain of "
(kbd "scheme.org") ".")
(ul
(li "Source code: "
(a (@ (href
"https://github.com/schemeorg/files.scheme.org"))
(kbd (@ (class "github-repo"))
"schemeorg/files.scheme.org"))
" repository on GitHub.")
(li "Discussion: "
(code (@ (class "mailing-list"))
"schemeorg")
" mailing list ("
(a (@ (href
"https://srfi-email.schemers.org/schemeorg/"))
"archives")
", "
(a (@ (href
,(string-append
"https://srfi.schemers.org/"
"srfi-list-subscribe.html#schemeorg")))
"subscribe")
").")))))
(define (display-page files)
(display-sxml
(let ((title "Scheme Files")
(description
(string-append
"Download archive of Scheme programming implementations,"
" libraries, documents and other files.")))
`(html
(@ (lang "en"))
(head
(meta (@ (charset "UTF-8")))
(title ,title)
(link (@ (rel "stylesheet") (href "/schemeorg.css")))
(link (@ (rel "stylesheet") (href "/files.css")))
(meta (@ (name "viewport")
(content "width=device-width, initial-scale=1")))
(meta (@ (name "description")
(content ,description))))
(body
,(menu-sxml
'(("Home" "//www.scheme.org/")
("Docs" "//docs.scheme.org/")
("Community" "//community.scheme.org/")
("Standards" "//standards.scheme.org/")
("Implementations" "//get.scheme.org/")))
(h1 (@ (id "logo"))
,title)
(table
(@ (class "files no-border"))
,@(map/odd
(lambda (file odd?)
(let ((name (get-string 'name file)))
`(tr (@ (class ,(if odd? "odd" "even")))
(td (kbd (a (@ (href ,name)) ,name)))
(td ,@(superscripts (get-string 'title file))
,@(let ((note (get-string-optional 'note file)))
(if (not note) '()
`((br)
(span (@ (class "note"))
"("
,@(superscripts note)
")"))))))))
files))
,(about-section))))))
(define (main)
(let ((files (with-input-from-file "files.scm" read-files)))
(with-output-to-file "www/index.html"
(lambda () (display-page files)))))
(main)