-
Notifications
You must be signed in to change notification settings - Fork 10
/
lisql2sparql.ml
1448 lines (1386 loc) · 53.4 KB
/
lisql2sparql.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Copyright 2013 Sébastien Ferré, IRISA, Université de Rennes 1, ferre@irisa.fr
This file is part of Sparklis.
Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at
http://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*)
open Jsutils
open Lisql
open Lisql_annot
(* configs *)
let config_fulltext_search = new Config.select_input ~key:"fulltext_search" ~select_selector:"#input-fulltext-search-select" ~default:"regex" ()
(* translation from LISQL elts to SPARQL queries *)
(* SPARQL variable generator *)
class genvar =
object
val h_varprefix_cpt : (string, int ref) Hashtbl.t = Hashtbl.create 7
method new_var (prefix : string) : string =
let cpt =
try Hashtbl.find h_varprefix_cpt prefix
with Not_found ->
let cpt = ref 0 in
Hashtbl.add h_varprefix_cpt prefix cpt;
cpt in
incr cpt;
prefix ^ string_of_int !cpt
end
(* SPARQL generation state *)
class state (id_labelling : Lisql2nl.id_labelling) =
object (self)
method id_labelling = id_labelling
val mutable vars : Rdf.var list = []
method add_var v = if not (List.mem v vars) then vars <- v::vars
method vars = List.rev vars
val h_var_aggreg : (Rdf.var, Rdf.var * aggreg * Sparql.formula) Hashtbl.t = Hashtbl.create 3
method set_aggreg v aggreg : unit =
Hashtbl.add h_var_aggreg v aggreg
method aggreg v =
try Some (Hashtbl.find h_var_aggreg v)
with _ -> None
val h_var_modif : (Rdf.var, modif_s2) Hashtbl.t = Hashtbl.create 13
method set_modif (v : Rdf.var) (modif : modif_s2) : unit =
Hashtbl.add h_var_modif v modif
method modif (v : Rdf.var) =
try Hashtbl.find h_var_modif v
with _ -> (Select, Unordered)
method project (v : Rdf.var) = fst (self#modif v)
method order (v : Rdf.var) = snd (self#modif v)
val mutable geolocs : (Sparql.term * (Rdf.var * Rdf.var)) list = []
method add_geoloc (t : Sparql.term) (v_lat : Rdf.var) (v_long : Rdf.var) : unit =
geolocs <- (t,(v_lat,v_long))::geolocs
method geolocs = geolocs
val gv = new genvar
method genvar = gv
end
(* assuming only few variables are created with same prefix in a given query *)
(*let random_sparql_var prefix : Sparql.var = Sparql.var (prefix ^ string_of_int (Random.int 1000))*)
let sparql_converter (conv_opt : num_conv option) : Sparql.converter =
match conv_opt with
| None -> (fun e -> e)
| Some (conv,b) ->
let func_conv =
match conv with
| IntegerConv -> "xsd:integer"
| DecimalConv -> "xsd:decimal"
| DoubleConv -> "xsd:double" in
(fun e ->
Sparql.expr_func func_conv
[ if b
then Sparql.expr_func "str" [e]
else e ])
let sparql_aggreg = function
| NumberOf -> Sparql.DistinctCOUNT
| ListOf -> Sparql.DistinctCONCAT
| Sample -> Sparql.SAMPLE
| Total conv_opt -> Sparql.SUM (sparql_converter conv_opt)
| Average conv_opt -> Sparql.AVG (sparql_converter conv_opt)
| Maximum conv_opt -> Sparql.MAX (sparql_converter conv_opt)
| Minimum conv_opt -> Sparql.MIN (sparql_converter conv_opt)
let sparql_order = function
| Unordered -> None
| Lowest conv_opt -> Some (Sparql.ASC (sparql_converter conv_opt))
| Highest conv_opt -> Some (Sparql.DESC (sparql_converter conv_opt))
type filter_context = [`Properties|`Terms] * Lisql.filter_type * [`Bind|`Filter]
let filter_kwds_gen (ctx : filter_context) (gv : genvar) ~(label_properties_langs : string list * string list) (t : _ Sparql.any_term) ~(op : [`All|`Any|`Exact|`Start|`End]) ~(kwds : string list) : Sparql.formula =
let label_props, label_langs = label_properties_langs in
let kwd = match kwds with kwd::_ -> kwd | _ -> assert false in
let make_filter (e : Sparql.expr) : Sparql.formula =
match op with
| (`All | `Any as op) ->
let log_op =
match op with
| `All -> Sparql.log_and
| `Any -> Sparql.log_or in
Sparql.Filter
(log_op
(List.map
(fun pat -> Sparql.expr_regex (Sparql.expr_func "str" [e]) pat)
kwds))
| `Exact -> Sparql.(Filter (expr_comp "=" (Sparql.expr_func "str" [e]) (string kwd)))
| `Start -> Sparql.(Filter (expr_func "strstarts" [e; (string kwd :> Sparql.expr)]))
| `End -> Sparql.(Filter (expr_func "strends" [e; (string kwd :> Sparql.expr)]))
in
let str_filter =
make_filter (t :> Sparql.expr) in
let label_filter_opt =
if label_props = []
then `Undefined
else
let open Sparql in
let term_l = (var (gv#new_var "constr_label") :> Sparql.term) in
`Filter (formula_and_list
[ Pattern (triple t (path_alt (List.map path_uri label_props :> pred list)) term_l);
(if label_langs = []
then True
else Filter (expr_in (expr_func "lang" [term_l]) (List.map string label_langs)));
make_filter (term_l :> Sparql.expr) ]) in
let label_filter_opt =
match op, config_fulltext_search#value, ctx with
| (`All | `Any as op), "text:query", _ ->
let lucene_query = Jsutils.lucene_query_of_kwds ~op kwds in
if lucene_query = ""
then `NoFilter
else `Filter (Sparql.Pattern (Sparql.text_query t lucene_query))
| (`All | `Any as op), "bif:contains", (`Terms,OnlyIRIs,`Bind) -> (* only efficient in this context; TODO: check *)
if label_props = []
then `Undefined
else
let terms =
Common.mapfilter
(fun kwd ->
let n = String.length kwd in
if n < 4 then Some ("'" ^ kwd ^ "'") (* wildcard must be at least 4 chars long in Virtuoso *)
else Some ("'" ^ kwd ^ "*'"))
kwds in
let sql_query =
let sep = match op with `All -> " AND " | `Any -> " OR " in
match terms with
| [] -> ""
| [term] -> term
| _ -> String.concat sep terms in
let _ = firebug ("SQL full-text query: " ^ sql_query) in
if sql_query = ""
then `NoFilter
else
let open Sparql in
let term_l = var (gv#new_var "constr_label") in
`Filter (formula_and_list
[ Pattern (triple t (path_alt (List.map path_uri label_props :> pred list)) term_l);
Pattern (bif_contains term_l sql_query);
(if label_langs = []
then True
else Filter (expr_in (expr_func "lang" [term_l]) (List.map string label_langs))) ])
| _ -> label_filter_opt (* using REGEX *)
in
let f =
match label_filter_opt with
| `Undefined -> str_filter
| `NoFilter -> Sparql.True (* kwds not specific enough *)
| `Filter label_filter ->
( match ctx with
| _, OnlyIRIs, _ -> label_filter
| _, OnlyLiterals, _ -> str_filter
| _, Mixed, _ -> Sparql.formula_or_list [str_filter; label_filter] ) in
f
let filter_constr_gen (ctx : filter_context) (gv : genvar) ~(label_properties_langs : string list * string list) (t : _ Sparql.any_term) (c : constr) : Sparql.formula =
(* both [label_properties] and [label_langs] may be the empty list, meaning undefined *)
match c with
| True -> Sparql.True
| MatchesAll [] -> Sparql.True
| MatchesAll lpat ->
filter_kwds_gen ctx gv ~label_properties_langs t ~op:`All ~kwds:lpat
| MatchesAny [] -> Sparql.True
| MatchesAny lpat ->
filter_kwds_gen ctx gv ~label_properties_langs t ~op:`Any ~kwds:lpat
| IsExactly "" -> Sparql.True
| IsExactly pat ->
filter_kwds_gen ctx gv ~label_properties_langs t ~op:`Exact ~kwds:[pat]
| StartsWith "" -> Sparql.True
| StartsWith pat ->
filter_kwds_gen ctx gv ~label_properties_langs t ~op:`Start ~kwds:[pat]
| EndsWith "" -> Sparql.True
| EndsWith pat ->
filter_kwds_gen ctx gv ~label_properties_langs t ~op:`End ~kwds:[pat]
| After pat ->
Sparql.Filter (Sparql.expr_comp ">=" (Sparql.expr_func "str" [t]) (Sparql.string pat))
| Before pat ->
Sparql.Filter (Sparql.expr_comp "<=" (Sparql.expr_func "str" [t]) (Sparql.string pat))
| FromTo (pat1,pat2) ->
Sparql.Filter
(Sparql.log_and
[Sparql.expr_comp ">=" (Sparql.expr_func "str" [t]) (Sparql.string pat1);
Sparql.expr_comp "<=" (Sparql.expr_func "str" [t]) (Sparql.string pat2)])
| HigherThan pat ->
Sparql.Filter (Sparql.expr_comp ">=" (Sparql.conv_numeric t) (Sparql.sparql pat))
| LowerThan pat ->
Sparql.Filter (Sparql.expr_comp "<=" (Sparql.conv_numeric t) (Sparql.sparql pat))
| Between (pat1,pat2) ->
Sparql.Filter
(Sparql.log_and
[Sparql.expr_comp ">=" (Sparql.conv_numeric t) (Sparql.sparql pat1);
Sparql.expr_comp "<=" (Sparql.conv_numeric t) (Sparql.sparql pat2)])
| HasLang pat ->
Sparql.Filter
(Sparql.log_and
[Sparql.expr_func "isLiteral" [t];
Sparql.expr_regex (Sparql.expr_func "lang" [t]) pat])
| HasDatatype pat ->
Sparql.Filter
(Sparql.log_and
[Sparql.expr_func "isLiteral" [t];
Sparql.expr_regex (Sparql.expr_func "str" [Sparql.expr_func "datatype" [t]]) pat])
| ExternalSearch (_, None) -> Sparql.True
| ExternalSearch (_, Some lt) ->
Sparql.formula_term_in_term_list t (List.map Sparql.term lt)
let filter_constr_entity gv t c (ft : Lisql.filter_type) =
let c =
if Rdf.config_wikidata_mode#value
then
Lisql.filter_external_search
(fun uri -> Common.has_prefix uri Rdf.wikidata_entity_base)
c
else c in
filter_constr_gen (`Terms,ft,`Filter) gv ~label_properties_langs:Lexicon.config_entity_lexicon#properties_langs t c
let filter_constr_class gv t c =
let c =
if Rdf.config_wikidata_mode#value
then
Lisql.filter_external_search
(fun uri -> Common.has_prefix uri Rdf.wikidata_entity_base)
c
else c in
filter_constr_gen (`Properties,OnlyIRIs,`Filter) gv ~label_properties_langs:Lexicon.config_concept_lexicon#properties_langs t c
let filter_constr_property gv t c =
let c =
if Rdf.config_wikidata_mode#value
then
Lisql.filter_external_search
(fun uri -> not (Common.has_prefix uri Rdf.wikidata_entity_base))
c
else c in
filter_constr_gen (`Properties,OnlyIRIs,`Filter) gv ~label_properties_langs:Lexicon.config_concept_lexicon#properties_langs t c
let search_constr_entity (gv : genvar) (t : _ Sparql.any_term) (c : constr) (ft : Lisql.filter_type) : Sparql.formula =
let label_properties_langs = Lexicon.config_entity_lexicon#properties_langs in
let f = filter_constr_gen (`Terms,ft,`Bind) gv
~label_properties_langs
t c in
let open Sparql in
let binding_pat =
match ft with
| OnlyIRIs -> something t
| OnlyLiterals -> triple (bnode "") (var (gv#new_var "p")) t
| Mixed -> union [something t;
triple (bnode "") (var (gv#new_var "p")) t] in
match f with
| Pattern _ -> f
| Subquery _ -> f
| Filter expr -> Pattern (join [binding_pat; filter expr])
| True -> Pattern binding_pat
| False -> False
| Or (pat,expr) -> Pattern (union [pat; join [binding_pat; filter expr]])
let triple_arg arg x y z =
Sparql.Pattern
( match arg with
| S -> Sparql.triple x y z
| P -> Sparql.triple y x z
| O -> Sparql.triple y z x
| Q _ -> assert false)
let rec expr_apply func args =
match func with
| Add -> Sparql.expr_infix "+" args
| Sub -> Sparql.expr_infix "-" args
| Mul -> Sparql.expr_infix "*" args
| Div -> Sparql.expr_infix "/" args
| Random2 ->
( match args with
| [arg1; arg2] ->
Sparql.expr_infix "+"
[arg1;
Sparql.expr_infix "*"
[Sparql.expr_func "RAND" [];
Sparql.expr_infix "-" [arg2; arg1]]]
| _ -> assert false )
| TODAY ->
( match args with
| [] -> Sparql.expr_func "xsd:date" [Sparql.expr_func "NOW" []]
| _ -> assert false )
| And -> Sparql.expr_infix "&&" args
| Or -> Sparql.expr_infix "||" args
| EQ -> Sparql.expr_infix "=" args
| NEQ -> Sparql.expr_infix "!=" args
| GT -> Sparql.expr_infix ">" args
| GEQ -> Sparql.expr_infix ">=" args
| LT -> Sparql.expr_infix "<" args
| LEQ -> Sparql.expr_infix "<=" args
| STRDT | STRLANG | Integer | Decimal | Double ->
( match args with
| arg::other_args -> Sparql.expr_func (name_func func) (Sparql.expr_func "str" [arg] :: other_args)
| [] -> assert false )
| REGEX_i -> Sparql.expr_func (name_func func) (args @ [(Sparql.string "i" :> Sparql.expr)])
| func -> Sparql.expr_func (name_func func) args
and name_func = function
| Str -> "str"
| Lang -> "lang"
| Datatype -> "datatype"
| IRI -> "IRI"
| STRDT -> "STRDT"
| STRLANG -> "STRLANG"
| Strlen -> "strlen"
| Substr2 -> "substr"
| Substr3 -> "substr"
| Strbefore -> "strbefore"
| Strafter -> "strafter"
| Concat -> "concat"
| UCase -> "ucase"
| LCase -> "lcase"
| Encode_for_URI -> "encode_for_uri"
| Replace -> "replace"
| Integer -> "xsd:integer"
| Decimal -> "xsd:decimal"
| Double -> "xsd:double"
| Indicator -> "xsd:integer"
| Add | Sub | Mul | Div -> invalid_arg "Lisql2sparql.name_func"
| Neg -> "-"
| Abs -> "abs"
| Round -> "round"
| Ceil -> "ceil"
| Floor -> "floor"
| Random2 -> invalid_arg "Lisql2sparql.name_func: Random2"
| Date -> "xsd:date"
| Time -> "xsd:time"
| Year -> "year"
| Month -> "month"
| Day -> "day"
| Hours -> "hours"
| Minutes -> "minutes"
| Seconds -> "seconds"
| TODAY -> invalid_arg "Lisql2sparql.name_func: TODAY"
| NOW -> "NOW"
| Not -> "!"
| And | Or
| EQ | NEQ | GT | GEQ | LT | LEQ -> invalid_arg "Lisql2sparql.name_func"
| BOUND -> "BOUND"
| IF -> "IF"
| IsIRI -> "IsIRI"
| IsBlank -> "IsBlank"
| IsLiteral -> "IsLiteral"
| IsNumeric -> "IsNumeric"
| StrStarts -> "strstarts"
| StrEnds -> "strends"
| Contains -> "contains"
| REGEX | REGEX_i -> "REGEX"
| LangMatches -> "langMatches"
type deps = Rdf.term list list (* each dependency corresponds to a hyper-edge over a list of vars *)
type deps_p1 = Rdf.term -> deps
type deps_pn = Rdf.term list -> deps
type deps_s1 = deps_p1 -> deps
type deps_s2 = deps_p1 -> deps_p1 -> deps
type deps_sn = deps_pn -> deps
let string_of_deps deps =
String.concat ""
(List.map
(fun dep ->
"("
^ String.concat " "
(List.map Rdf.string_of_term dep)
^ ")")
deps)
type sparql_p1 = Sparql.term -> Sparql.formula
type sparql_p2 = Sparql.term -> Sparql.term -> Sparql.formula
type sparql_pn = (arg * Sparql.term) list -> Sparql.formula
type sparql_s1 = sparql_p1 -> Sparql.formula
type sparql_s2 = sparql_p1 -> sparql_p1 -> Sparql.formula
type sparql_sn = sparql_pn -> Sparql.formula
type sparql_b1 = sparql_p2 -> Sparql.formula
type sparql_s = Sparql.formula
type 'a formula_hook = 'a -> Sparql.formula -> Sparql.formula
let make_pat ?(hook : string formula_hook option) (v : string) (pat : Sparql.pattern) : Sparql.pattern =
match hook with
| None -> pat
| Some h ->
if pat = Sparql.empty
then pat (* nothing to hook *)
else
Sparql.pattern_of_formula
(h v (Sparql.Pattern pat))
(* definitions to retrieve classes from focus *)
module WhichClass =
struct
let pattern_vars = ["c"]
let intent_pattern ?(hook : string formula_hook option) () =
make_pat ?hook "c"
Sparql.(union
[ rdf_type (var "c") (term_uri Rdf.rdfs_Class);
rdf_type (var "c") (term_uri Rdf.owl_Class) ])
let pattern_of_term ?(hook : string formula_hook option) (t_opt : Rdf.term option) : Sparql.pattern (* maybe mepty *) =
let init, t =
match t_opt with
| None -> true, Rdf.Bnode ""
| Some t -> false, t in
if Rdf.term_can_be_subject t
then make_pat ?hook "c" Sparql.(rdf_type (term t) (var "c"))
else Sparql.empty
let increments_of_terms ~(init : bool) (lt : Rdf.term option list) : Lisql.increment list =
(* ~init: for initial focus *)
match lt with
| [Some (Rdf.URI c)] -> [Lisql.IncrType c]
| _ -> []
end
(* definitions to retrieve properties from focus *)
module WhichProp =
struct
let pattern_vars = ["p";"ip"] (* property, inverse property *)
let filter_wikidata vp =
Sparql.(filter (expr_func
"strstarts"
[expr_func "str" [var vp];
(string "http://www.wikidata.org/prop/direct/P" :> expr)]))
let intent_pattern ?(hook : string formula_hook option) () =
make_pat ?hook "p"
Sparql.(union
[ rdf_type (var "p") (term_uri Rdf.rdf_Property);
rdf_type (var "p") (term_uri Rdf.owl_ObjectProperty);
rdf_type (var "p") (term_uri Rdf.owl_DatatypeProperty) ])
let pattern_of_term ?(hook : string formula_hook option) (t_opt : Rdf.term option) : Sparql.pattern (* maybe empty *) =
let init, t =
match t_opt with
| None -> true, Rdf.Bnode ""
| Some t -> false, t in
let make_pat vp pat =
let pat =
if Rdf.config_wikidata_mode#value
then Sparql.(join [pat; filter_wikidata vp])
else pat in
make_pat ?hook vp pat in
Sparql.(union
[ if Rdf.term_can_be_subject t
then make_pat "p" (triple (term t) (var "p") (bnode ""))
else empty;
if init
then empty
else make_pat "ip" (triple (bnode "") (var "ip") (term t)) ])
let increments_of_terms ~(init : bool) (lt : Rdf.term option list) : Lisql.increment list =
match lt with
| [Some (Rdf.URI p); None] ->
if init
then [Lisql.IncrRel (p,Fwd); Lisql.IncrRel (p,Bwd)]
else [Lisql.IncrRel (p,Fwd)]
| [None; Some (Rdf.URI ip)] ->
[Lisql.IncrRel (ip,Bwd)]
| _ -> []
end
(* definitions to retrieve predicates from focus *)
module WhichPred =
struct
let pattern_vars : Rdf.var list = ["pe"; "ps"; "po"; "pq"]
(* pattern_X defined as functions because [uri] has a side effect in Sparql.prologue *)
let pattern_SO ps po =
Sparql.(triple
(var ps)
(path_uri Rdf.nary_subjectObject)
(var po))
let pattern_EO pe po =
Sparql.(triple
(var pe)
(path_uri Rdf.nary_eventObject)
(var po))
let filter_wikidata pe po =
Sparql.(join
[ filter (expr_func "strstarts" [expr_func "str" [var pe]; (string "http://www.wikidata.org/prop/P" :> expr)]);
filter (expr_func "strstarts" [expr_func "str" [var po]; (string "http://www.wikidata.org/prop/statement/P" :> expr)]) ])
let pattern_wikidata pe po =
Sparql.(bnode_triples_as_pattern
[ (path_uri Rdf.wikibase_claim :> pred), var pe;
(path_uri Rdf.wikibase_statementProperty :> pred), var po ])
let intent_pattern ?(hook : string formula_hook option) () : Sparql.pattern =
if Rdf.config_wikidata_mode#value
then make_pat ?hook "pe" (pattern_wikidata "pe" "po")
else Sparql.(union [ make_pat ?hook "po" (pattern_SO "ps" "po");
make_pat ?hook "pe" (pattern_EO "pe" "po") ])
let pattern_of_term ?(hook : string formula_hook option) (t_opt : Rdf.term option) : Sparql.pattern (* maybe empty *) =
let init, t =
match t_opt with
| None -> true, Rdf.Bnode ""
| Some t -> false, t in
if Rdf.config_wikidata_mode#value
then
let pat_wikidata p1 p2 pat =
Sparql.join [pat; filter_wikidata p1 p2] in
let pat =
Sparql.(union
[ if Rdf.term_can_be_subject t
then pat_wikidata "pe" "po"
(triple (* forward: pe, po *)
(term t)
(var "pe")
(bnode_triples
[ var "po", bnode "" ]))
else empty;
if init
then empty
else pat_wikidata "pe" "ps"
(triple (* backward: pe, ps, po *)
(bnode "")
(var "pe")
(bnode_triples
[ var "ps", term t ])) ]) in (* binding 'ps' to distinguish orientation *)
make_pat ?hook "pe" pat
else
let pat_SO =
Sparql.(join
[ make_pat ?hook "po" (pattern_SO "ps" "po");
filter
(exists (
union
[ bnode_triples_as_pattern (* relation: ps, po *)
[ var "ps", term t;
var "po", bnode "" ];
(*join (* qualifier: ps, po, pq *)
[ bnode_triples_as_pattern
[ var "ps", bnode "";
var "po", bnode "";
var "pq", term t ];
filter
(log_and
[ expr_infix "!=" [var "pq"; var "ps"];
expr_infix "!=" [var "pq"; var "po"] ])
]*)
]))
]) in
let pat_EO =
Sparql.(union
[ if Rdf.term_can_be_subject t
then join
[ make_pat ?hook "pe" (pattern_EO "pe" "po");
filter (exists (
triple (* forward: pe, po *)
(term t)
(var "pe")
(bnode_triples
[ var "po", bnode "" ]))) ]
else empty;
if init
then empty
else join (* backward: pe, ps, po *)
[ make_pat ?hook "pe" (pattern_EO "pe" "ps");
filter
(exists (
triple
(bnode "")
(var "pe")
(bnode_triples
[ var "ps", term t ]))) (* binding 'ps' to distinguish orientation *)
];
(*join (* qualifier: pe, po, pq *)
[ triple
(bnode "")
(var "pe")
(bnode_triples
[ var "po", bnode "";
var "pq", term t ]);
filter
(expr_infix "!=" [var "pq"; var "po"])
]*)
]) in
Sparql.(union [pat_SO; pat_EO])
let increments_of_terms ~(init : bool) (lt : Rdf.term option list) : Lisql.increment list =
(* ~init: for initial focus, remind to generate increments in all relevant directions S/P/O *)
assert (List.length lt = List.length pattern_vars);
match lt with
| [None; Some (Rdf.URI ps); Some (Rdf.URI po); None] ->
[Lisql.IncrPred (S, SO (ps,po))]
| [None; Some (Rdf.URI ps); Some (Rdf.URI po); Some (Rdf.URI pq)] ->
[Lisql.IncrPred (Q pq, SO (ps,po))]
| [Some (Rdf.URI pe); None; Some (Rdf.URI po); None] ->
if init
then [Lisql.IncrPred (S, EO (pe,po)); Lisql.IncrPred (O, EO (pe,po))]
else [Lisql.IncrPred (S, EO (pe,po))]
| [Some (Rdf.URI pe); Some (Rdf.URI ps); None; None] ->
[Lisql.IncrPred (O, EO (pe,ps))]
| [Some (Rdf.URI pe); None; Some (Rdf.URI po); Some (Rdf.URI pq)] ->
[Lisql.IncrPred (Q pq, EO (pe,po))]
| _ -> []
let increments_hidden_by_increment ~(init : bool) (incr : increment) : increment list =
let open Lisql in
if init
then
let lp =
match incr with
| IncrPred (_, SO (ps,po)) -> [ps; po]
| IncrPred (_, EO (pe,po)) -> [pe; po]
| _ -> [] in
List.fold_right
(fun p res -> IncrRel (p,Fwd) :: IncrRel (p,Bwd) :: res)
lp []
else
match incr with
| IncrPred (S, SO (ps,po)) -> [IncrRel (ps,Bwd)]
| IncrPred (O, SO (ps,po)) -> [IncrRel (po,Bwd)]
| IncrPred (S, EO (pe,po)) -> [IncrRel (pe,Fwd)]
| IncrPred (O, EO (pe,po)) -> [IncrRel (po,Bwd)]
| _ -> []
end
let pattern_pred_args (pred : pred) (args : (arg * _ Sparql.any_term) list) (var_args : (string * _ Sparql.any_term) list) : Sparql.pattern =
let bnode = Sparql.bnode "" in
let tS, args = try List.assoc S args, args with Not_found -> bnode, (S,bnode)::args in
let tO, args = try List.assoc O args, args with Not_found -> bnode, (O,bnode)::args in
match pred with
| Class c -> Sparql.(rdf_type tS (term_uri c))
| Prop p -> Sparql.(triple tS (path_uri p) tO)
| SO (ps,po) ->
let lpo = [] in
let lpo =
List.fold_right
(fun (v,t) lpo -> Sparql.(((var v :> pred), t) :: lpo))
var_args lpo in
let lpo =
List.fold_right
(fun (arg,t) lpo ->
match arg with
| S -> Sparql.(((path_uri ps :> pred), t) :: lpo)
| O -> Sparql.(((path_uri po :> pred), t) :: lpo)
| P -> lpo
| Q q -> Sparql.(((path_uri q :> pred), t) :: lpo))
args lpo in
Sparql.bnode_triples_as_pattern lpo
| EO (pe,po) ->
let lpo = [] in
let lpo =
List.fold_right
(fun (v,t) lpo -> Sparql.(((var v :> pred), t) :: lpo))
var_args lpo in
let lpo =
List.fold_right
(fun (arg,t) lpo ->
match arg with
| S -> lpo
| O -> Sparql.(((path_uri po :> pred), t) :: lpo)
| P -> lpo
| Q q -> Sparql.(((path_uri q :> pred), t) :: lpo))
args lpo in
Sparql.(triple
tS
(path_uri pe)
(bnode_triples lpo))
module WhichArg =
struct
let pattern_vars = ["pq"]
let pattern_of_pred_args ?(hook : string formula_hook option) (pred : Lisql.pred) (args : (Lisql.arg * Rdf.term) list) : Sparql.pattern (* maybe empty *) =
let filter_qualifier =
match pred with
| Class _ -> Sparql.empty
| Prop _ -> Sparql.empty
| SO (ps,po) -> Sparql.(filter (expr_not_in (var "pq") [term_uri Rdf.rdf_type; term_uri ps; term_uri po]))
| EO (pe,po) ->
if Rdf.config_wikidata_mode#value
then Sparql.(filter (expr_func "strstarts" [expr_func "str" [var "pq"]; (string "http://www.wikidata.org/prop/qualifier/P" :> expr)]))
else Sparql.(filter (expr_not_in (var "pq") [term_uri Rdf.rdf_type; term_uri po])) in
let valid_term_for_triple_subjects =
match pred with
| Class _ | Prop _ | EO _ ->
( match List.assoc_opt S args with
| None -> true (* a blank node will be used *)
| Some t -> Rdf.term_can_be_subject t )
| SO _ -> true in
if valid_term_for_triple_subjects
then
let pat =
pattern_pred_args
pred
(List.map (fun (arg,t) -> (arg, Sparql.term t)) args)
["pq", Sparql.bnode ""] in
Sparql.(join
[ make_pat ?hook "pq"
(Sparql.join [ pat; filter_qualifier ]) ])
else Sparql.empty
let increments_of_terms (lt : Rdf.term option list) : Lisql.increment list =
match lt with
| [Some (Rdf.URI pq)] -> [Lisql.IncrArg pq]
| _ -> []
end
let path_pred_args_argo ?(transitive = false) pred args argo =
let path_transitive_opt path =
if transitive
then Sparql.path_transitive path
else path in
let uri_transitive_opt uri =
if transitive
then
match Ontology.config_transitive_closure#value#info uri with
| uri_star::_ -> Sparql.path_uri uri_star
| _ -> Sparql.path_transitive (Sparql.path_uri uri)
else Sparql.path_uri uri in
let open Sparql in
match pred, args, argo with
| Prop p, S, O -> (uri_transitive_opt p :> pred)
| Prop p, O, S -> path_inverse (uri_transitive_opt p)
| SO (ps,po), S, O -> path_transitive_opt (path_seq (path_inverse (path_uri ps)) (path_uri po))
| SO (po,ps), O, S -> path_transitive_opt (path_seq (path_inverse (path_uri po)) (path_uri ps))
| EO (pe,po), S, O -> path_transitive_opt (path_seq (path_uri pe) (path_uri po))
| EO (pe,po), O, S -> path_inverse (path_transitive_opt (path_seq (path_uri pe) (path_uri po)))
| _ -> assert false (* from Lisql.toggle_hierarchy *)
let form_pred state (pred : pred) : sparql_pn =
(fun l -> Sparql.Pattern (pattern_pred_args pred l []))
let form_sim state pred args argo rank : sparql_p2 =
let open Sparql in
let path = path_pred_args_argo pred args argo in
let interv_path = path_interv path 0 rank in
(fun x y -> Pattern (triple x interv_path y))
let rec form_p1 state : annot elt_p1 -> deps_p1 * sparql_p1 = function
| Is (annot,np) -> form_s1_as_p1 state np
| Pred (annot,arg,pred,cp) ->
let pred = form_pred state pred in
let cp_deps, cp = form_sn state cp in
(fun x -> cp_deps (fun l -> [x::l])),
(fun x -> cp (fun l -> pred ((arg,x)::l)))
| Type (annot,c) ->
(fun x -> []),
(fun x -> Sparql.Pattern (Sparql.rdf_type x (Sparql.term_uri c)))
| Rel (annot,prop,ori,np) ->
let p = Sparql.path_uri prop in
let rel =
match ori with
| Fwd -> (fun x y -> Sparql.Pattern (Sparql.triple x p y))
| Bwd -> (fun x y -> Sparql.Pattern (Sparql.triple y p x)) in
let q_np_deps, q_np = form_s1 state np in
(fun x -> q_np_deps (fun y -> [[x;y]])),
(fun x -> q_np (fun y -> rel x y))
| Hier (annot,id,pred,args,argo,np) ->
let vy = state#id_labelling#get_id_var id in
state#set_modif vy (Lisql.Unselect,Lisql.Unordered);
let y = (Sparql.var vy :> Sparql.term) in
let hier =
let open Sparql in
let trans_path = path_pred_args_argo ~transitive:true pred args argo in
(fun x y -> Pattern (triple x trans_path y)) in
let q_np_deps, q_np = form_s1 ~ignore_top:true state np in
(fun x -> q_np_deps (fun z -> [[x;z]]) @ [[x; Rdf.Var vy]]),
(fun x ->
state#add_var vy;
Sparql.formula_and_list [q_np (fun z -> hier x z); hier x y])
| Sim (annot,np,pred,args,argo,rank) ->
let q_deps, q = form_s1 state np in
let sim = form_sim state pred args argo rank in
(fun x -> q_deps (fun y -> [[y; x]])),
(fun x -> q (fun y -> sim y x))
| LatLong (annot,ll,id1,id2) ->
let v1 = state#id_labelling#get_id_var id1 in
let v2 = state#id_labelling#get_id_var id2 in
let lat, long = Sparql.var v1, Sparql.var v2 in
let f_ll = form_latlong ll in
(fun x -> [[x; Rdf.Var v1; Rdf.Var v2]]),
(fun x ->
state#add_geoloc x v1 v2;
f_ll x lat long)
| Triple (annot,arg,np1,np2) ->
let q_np1_deps, q_np1 = form_s1 state np1 in
let q_np2_deps, q_np2 = form_s1 state np2 in
(fun x -> q_np1_deps (fun y -> q_np2_deps (fun z -> [[x;y;z]]))),
(fun x -> q_np1 (fun y -> q_np2 (fun z -> triple_arg arg x y z)))
| Search (annot,c) ->
(fun x -> []),
(fun x -> search_constr_entity state#genvar x c OnlyIRIs)
| Filter (annot,c,ft) ->
(fun x -> []),
(fun x -> filter_constr_entity state#genvar x c ft)
| And (annot,lr) ->
let lr_d_deps, lr_d = List.split (List.map (fun elt -> form_p1 state elt) lr) in
(fun x -> List.concat (List.map (fun d_deps -> d_deps x) lr_d_deps)),
(fun x -> Sparql.formula_and_list (List.map (fun d -> d x) lr_d))
| Or (annot,lr) ->
( match annot#get_susp_focus_index with
| Some i -> form_p1 state (List.nth lr i)
| None ->
let lr_d_deps, lr_d = List.split (List.map (fun elt -> form_p1 state elt) lr) in
(fun x -> List.concat (List.map (fun d_deps -> d_deps x) lr_d_deps)),
(fun x -> Sparql.formula_or_list (List.map (fun d -> d x) lr_d)) )
| Maybe (annot,f) ->
if annot#is_susp_focus
then form_p1 state f
else
let d_deps, d = form_p1 state f in
(fun x -> d_deps x),
(fun x -> Sparql.formula_optional (d x))
| Not (annot,f) ->
if annot#is_susp_focus
then form_p1 state f
else
let d_deps, d = form_p1 (Oo.copy state) f in
(fun x -> d_deps x),
(fun x -> Sparql.formula_not (d x))
| In (annot,npg,f) ->
let q_deps, q = form_s1 state npg in
let d_deps, d = form_p1 state f in
(fun x -> q_deps (fun g -> d_deps x |> List.map (fun dep -> g::dep))),
(fun x -> q (fun g -> Sparql.formula_graph state#genvar#new_var g (d x)))
| InWhichThereIs (annot,np) ->
let q_deps, q = form_s1 state np in
(fun g -> q_deps (fun x -> []) |> List.map (fun dep -> g::dep)),
(fun g -> Sparql.formula_graph state#genvar#new_var g (q (fun x -> Sparql.True)))
| IsThere annot ->
(fun x -> []),
(fun x -> Sparql.True)
and form_latlong = function
| CustomLatLong (plat,plong) ->
(fun x lat long ->
Sparql.(formula_and
(Pattern (triple x (path_uri plat) lat))
(Pattern (triple x (path_uri plong) long))))
| WikidataLatLong ->
(fun x lat long -> Sparql.Pattern (Sparql.wikidata_lat_long x lat long))
and form_p1_opt state = function
| None -> (fun x -> []), (fun x -> Sparql.True)
| Some rel -> form_p1 state rel
and form_s1_as_p1 state : annot elt_s1 -> deps_p1 * sparql_p1 = function
| Det (annot,det,rel_opt) ->
let d1 = form_s2_as_p1 state det in
let d2_deps, d2 = form_p1_opt state rel_opt in
(fun x -> d2_deps x),
(fun x -> Sparql.formula_and (d1 x) (d2 x))
| AnAggreg (annot,idg,modifg,g,relg_opt,np) ->
if annot#is_susp_focus
then form_s1_as_p1 state np
else
( match np with
| Det (_, An (id, _, _), _)
| AnAggreg (_, id, _, _, _, _) ->
let _d_deps, d = form_p1_opt state relg_opt in
form_aggreg_op state idg modifg g d id;
form_s1_as_p1 state np
| _ -> assert false )
| NAnd (annot,lr) ->
let lr_d_deps, lr_d = List.split (List.map (fun elt -> form_s1_as_p1 state elt) lr) in
(fun x -> List.concat (List.map (fun d_deps -> d_deps x) lr_d_deps)),
(fun x -> Sparql.formula_and_list (List.map (fun d -> d x) lr_d))
| NOr (annot,lr) ->
( match annot#get_susp_focus_index with
| Some i -> form_s1_as_p1 state (List.nth lr i)
| None ->
let lr_d_deps, lr_d = List.split (List.map (fun elt -> form_s1_as_p1 state elt) lr) in
(fun x -> List.concat (List.map (fun d_deps -> d_deps x) lr_d_deps)),
(fun x -> Sparql.formula_or_list (List.map (fun d -> d x) lr_d)) )
| NMaybe (annot,f) ->
if annot#is_susp_focus
then form_s1_as_p1 state f
else
let d_deps, d = form_s1_as_p1 state f in
(fun x -> d_deps x),
(fun x -> Sparql.formula_optional (d x))
| NNot (annot,f) ->
if annot#is_susp_focus
then form_s1_as_p1 state f
else
let d_deps, d = form_s1_as_p1 (Oo.copy state) f in
(fun x -> d_deps x),
(fun x -> Sparql.formula_not (d x))
and form_s2_as_p1 state : elt_s2 -> sparql_p1 = function
| Term t ->
(fun x -> Sparql.(Filter (expr_comp "=" x (term t))))
(* (fun x -> "BIND (" ^ Sparql.term t ^ " AS " ^ Sparql.term x ^ ")") *)
| An (_id, _modif,head) -> form_head_as_p1 state head
| The id ->
(fun x ->
let v = state#id_labelling#get_id_var id in
let t = Rdf.Var v in
Sparql.(Filter (expr_comp "=" x (term t))))
and form_head_as_p1 state : elt_head -> sparql_p1 = function
| Thing -> (fun x -> Sparql.True)
| Class c -> (fun x -> Sparql.(Pattern (rdf_type x (term_uri c))))
and form_sn state : annot elt_sn -> deps_sn * sparql_sn = function
| CNil annot ->
(fun p -> p []),
(fun p -> p [])
| CCons (annot,arg,np,cp) ->
let np_deps, np = form_s1 state np in
let cp_deps, cp = form_sn state cp in
(fun p -> np_deps (fun x -> cp_deps (fun l -> p (x::l)))),
(fun p -> np (fun x -> cp (fun l -> p ((arg,x)::l))))
| CAnd (annot,lr) ->
let lr_q_deps, lr_q = List.split (List.map (fun elt -> form_sn state elt) lr) in
(fun p -> List.concat (List.map (fun q_deps -> q_deps p) lr_q_deps)),
(fun p -> Sparql.formula_and_list (List.map (fun q -> q p) lr_q))
| COr (annot,lr) ->
( match annot#get_susp_focus_index with
| Some i -> form_sn state (List.nth lr i)
| None ->
let lr_q_deps, lr_q = List.split (List.map (fun elt -> form_sn state elt) lr) in
(fun p -> List.concat (List.map (fun q_deps -> q_deps p) lr_q_deps)),
(fun p -> Sparql.formula_or_list (List.map (fun q -> q p) lr_q)) )
| CMaybe (annot,f) ->
if annot#is_susp_focus
then form_sn state f
else
let q_deps, q = form_sn state f in
(fun p -> q_deps p),
(fun p -> Sparql.formula_optional (q p))
| CNot (annot,f) ->
if annot#is_susp_focus
then form_sn state f
else
let q_deps, q = form_sn (Oo.copy state) f in
(fun p -> q_deps p),
(fun p -> Sparql.formula_not (q p))
and form_s1 ?(ignore_top = false) state : annot elt_s1 -> deps_s1 * sparql_s1 = function
| Det (annot,det,rel_opt) ->
let qu_deps, qu = form_s2 state det in
let d1_deps, d1 = form_p1_opt state rel_opt in
(fun d -> qu_deps d1_deps d),
(if ignore_top && is_top_s2 det && is_top_p1_opt rel_opt
then (fun d -> Sparql.True)
else (fun d -> qu d1 d))
| AnAggreg (annot,idg,modifg,g,relg_opt,np) ->
if annot#is_susp_focus
then form_s1 state np
else
( match np with
| Det (_, An (id, _, _), _)
| AnAggreg (_, id, _, _, _, _) ->
let _d_deps, d = form_p1_opt state relg_opt in
form_aggreg_op state idg modifg g d id;
form_s1 state np
| _ -> assert false )
| NAnd (annot,lr) ->
let lr_q_deps, lr_q = List.split (List.map (fun elt -> form_s1 ~ignore_top state elt) lr) in
(fun d -> List.concat (List.map (fun q_deps -> q_deps d) lr_q_deps)),
(fun d -> Sparql.formula_and_list (List.map (fun q -> q d) lr_q))
| NOr (annot,lr) ->
( match annot#get_susp_focus_index with
| Some i -> form_s1 ~ignore_top state (List.nth lr i)
| None ->
let lr_q_deps, lr_q = List.split (List.map (fun elt -> form_s1 ~ignore_top state elt) lr) in
(fun d -> List.concat (List.map (fun q_deps -> q_deps d) lr_q_deps)),
(fun d -> Sparql.formula_or_list (List.map (fun q -> q d) lr_q)) )
| NMaybe (annot,f) ->
if annot#is_susp_focus
then form_s1 ~ignore_top state f
else
let q_deps, q = form_s1 ~ignore_top state f in
(fun d -> q_deps d),
(fun d -> Sparql.formula_optional (q d))