isotropic behaviour with a multi-linear isotropic hardening

[pierreguy]

Dear Thomas,

Here is a part of the mfront file I use for describing a simple isotropic behaviour with a multi-linear isotropic hardening (elasto plastic with J2 plasticity).
I have 3 questions on it:
1- If I want to use this script under finite strain, is it ok if I simply add the following keyword in the file:
@StrainMeasure Hencky;

2- If, in addition to finite strain, I want to compute the elastic and plastic energies, is it ok if I add the following lines in the script:

@InternalEnergy{
        Psi_s = sig|eel/2.;
}

@DissipatedEnergy{
        Psi_d += (sig)|(deto-deel);
}

3- I have the flow curve in terms of "equivalent stress" - "logarithmic plastic strain".
In your opinion, should I use it directly as it is in the mfront file (inside the @FlowRule {…}),
or should I convert the strains using a relation of the type:
\epsilon_{log} = \ln ( 1 + \epsilon_{engineering} )
to convert the given logarithmic plastic strains into engineering plastic strains?
What do you think?

Thanks a lot.
Pierre-Guy

@DSL IsotropicPlasticMisesFlow;
@Behaviour Plasticity;
@Author Thomas Helfer;
@Date 03 / 06 / 2021;
@Description {
  "A simple isotropic behaviour with a multi-linear isotropic hardening"
}
 
@StrainMeasure Hencky;
 
@ElasticMaterialProperties{…};

@FlowRule {
  // experimental data and interpolation
  ....
  // hardening slope and current yield stress
  const auto r = interpolate(p);
  const auto H = r.first;
  const auto R = r.second;
  // σₑ is the current estimate of the von Mises stress at t+θ⋅Δt
  f = σₑ - R;
  ∂f∕∂σₑ = 1;
  ∂f∕∂p = -H;
}
 
@InternalEnergy{
        Psi_s = sig|eel/2.;
};
 
@DissipatedEnergy{
        Psi_d += (sig)|(deto-deel);
}

[thelfer]

@pierreguy

Thanks for your interest for MFront

1- If I want to use this script under finite strain, is it ok if I simply add the following keyword in the file:
@StrainMeasure Hencky;

If you know what you are doing, yes !

More precisely, the logarithmic strain framework, described in [Miehe' paper] (https://www.researchgate.net/publication/250692910_Anisotropic_additive_plasticity_in_the_logarithmic_strain_space_Modular_kinematic_formulation_and_implementation_based_on_incremental_minimization_principles_for_standard_materials), preserves:

1. the link between the change of volume and the trace of the deformation. In your case, the elastic part is generally negligible compared to the plastic part, the finite strain behaviour will be almost incompressible.
2. the fact that the stress is the dual of the logarithmic strain. sig|deto gives the increment of mechanical work in the reference configuration. This helps for your second question
3. the classical interpretation of the stress/strain in uniaxial tensile test. In this case, the dual of the logarithmic strain is the Kirchhoff stress which is almost the Cauchy stress for incompressible flows. This answers your third question.

[thelfer]

2- If, in addition to finite strain, I want to compute the elastic and plastic energies, is it ok if I add the following lines in the script:
@InternalEnergy{
Psi_s = sig|eel/2.;
};
@DissipatedEnergy{
Psi_d += (sig)|(deto-deel);
}

They mostly are ! Note that the energy density are expressed in the reference configuration, i.e. you must integrate them in the reference configuration to get the values of the stored and dissipated.

"Mostly" refers to the fact that you would have a better approximation (second order) of the dissipated energy as follows:

@LocalVariable StressStensor sig0;

@InitLocalVariables{
  sig0 = sig;
}

@FlowRule {
....
}

@InternalEnergy {
  Psi_s = sig | eel / 2;
}

@DissipatedEnergy {
  Psi_d += ((sig + sig0) | (deto - deel)) / 2;
}

[pierreguy]

Thank you, Thomas!

So, if I correctly understand:
-for question#1. Adding the keyword "@StrainMeasure Hencky;" in the mfront file, will simply allow a computation in finite strains (with the features you mention).
-for question#2. A better approximation of the dissipated energy can be obtained.
-for question#3. I can directly use the flow curve in terms of ("equivalent stress" - "logarithmic plastic strain") in the mfront file (inside the @FlowRule {…}) without any conversion.
True?

To the end, my script should be:

@Dsl IsotropicPlasticMisesFlow;
@Behaviour Plasticity;
@Author Thomas Helfer;
@Date 03 / 06 / 2021;
@description {
"A simple isotropic behaviour with a multi-linear isotropic hardening"
}

@StrainMeasure Hencky;

@ElasticMaterialProperties{…};

@LocalVariable StressStensor sig0;

@InitLocalVariables{
  sig0 = sig;
}

@FlowRule {
// experimental data and interpolation
....
// hardening slope and current yield stress
const auto r = interpolate(p);
const auto H = r.first;
const auto R = r.second;
// σₑ is the current estimate of the von Mises stress at t+θ⋅Δt
f = σₑ - R;
∂f∕∂σₑ = 1;
∂f∕∂p = -H;
}

@InternalEnergy {
  Psi_s = sig | eel / 2;
}

@DissipatedEnergy {
  Psi_d += ((sig + sig0) | (deto - deel)) / 2;
}

Thanks!

[thelfer]

-for question#1. Adding the keyword "@StrainMeasure Hencky;" in the mfront file, will simply allow a computation in finite strains (with the features you mention).

Yes

-for question#2. A better approximation of the dissipated energy can be obtained.

Yes

-for question#3. I can directly use the flow curve in terms of ("equivalent stress" - "logarithmic plastic strain") in the mfront file (inside the @FlowRule {…}) without any conversion. True?

Yes

To the end, my script should be:

And final, yes !

[pierreguy]

Thank you very much!